Skimmer not coming back on after feed mode

Do you have a question on how to do something.
Ask in here.
Post Reply
89delta
Posts: 163
Joined: Mon Oct 15, 2012 7:21 pm
Location: Leesburg, GA

Skimmer not coming back on after feed mode

Post by 89delta »

So I snagged a bit of code from Paulturner911 to include a delay after feed mode is triggered while the WP's are in NTM. After 15min the skimmer is supposed to turn back on but doesn't.I have marked the section in red.Any ideas?
Sorry would have used the code tag but doesnt allow color in the font.

static int rmode;
static boolean changeMode=true;

// Add Else Mode definition..
const int Else=16;

// These are the modes we can cycle through. You can add more and even repeat...
byte modes[] = { Lagoon, Else, ReefCrest, TidalSwell, ShortPulse, LongPulse, NutrientTransport };

if (now()%SECS_PER_DAY==0 || changeMode==true) { // Change at midnight or if controller rebooted
rmode=random(100)%sizeof(modes); // Change the mode once per day to pick from our array
changeMode=false;
}

// Set timer when in feeding mode
static unsigned long feeding;
if (ReefAngel.DisplayedMenu==FEEDING_MODE) feeding=now();

if (now()-feeding<900) {
// First 15 minutes after feeding mode stops. Skimmer is off
ReefAngel.Relay.Off(Port3);

// First 15 minutes after feeding mode stops. Smart_NTM
ReefAngel.DCPump.UseMemory=false;
ReefAngel.DCPump.Mode=NutrientTransport;
} else if (now()-feeding<4500) { // 15 minutes plus 1 hour
// Continue NTM for the next 60 minutes (75 minutes total)
ReefAngel.DCPump.UseMemory=false;
ReefAngel.DCPump.Mode=NutrientTransport;
} else if (now()%SECS_PER_DAY<30600 || now()%SECS_PER_DAY>=81000) { // 8:30am / 10:30pm
// Night mode (go to 30%)
ReefAngel.DCPump.UseMemory=false;
ReefAngel.DCPump.Mode=Constant;
ReefAngel.DCPump.Speed=30;
} else if (InternalMemory.DCPumpMode_read()==11) {
// Custom Mode and nothing else going on
ReefAngel.DCPump.UseMemory=false;
ReefAngel.DCPump.Duration=InternalMemory.DCPumpDuration_read();
if (modes[rmode]==Else) {
ReefAngel.DCPump.UseMemory=false;
ReefAngel.DCPump.Mode=Constant;
ReefAngel.DCPump.Speed=ElseMode(InternalMemory.DCPumpSpeed_read(),25,true ); // ElseMode on sync mode, Portal Speed Setting +/- 25%
} else {
ReefAngel.DCPump.Mode=modes[rmode]; // Put the mode to the random mode :)
ReefAngel.DCPump.Speed=InternalMemory.DCPumpSpeed_read(); // Set speed from portal
}
} else {
ReefAngel.DCPump.UseMemory=true; // Will reset all values from memory
}
User avatar
lnevo
Posts: 5430
Joined: Fri Jul 20, 2012 9:42 am

Re: Skimmer not coming back on after feed mode

Post by lnevo »

Can you post your full code (with the code tags?) need to see how your turning the port on in normal mode...
89delta
Posts: 163
Joined: Mon Oct 15, 2012 7:21 pm
Location: Leesburg, GA

Re: Skimmer not coming back on after feed mode

Post by 89delta »

Thanks Lnevo....here is the current code i am using.

Code: Select all

#include <ReefAngel_Features.h>
#include <Globals.h>
#include <RA_Wifi.h>
#include <Wire.h>
#include <OneWire.h>
#include <Time.h>
#include <DS1307RTC.h>
#include <InternalEEPROM.h>
#include <RA_NokiaLCD.h>
#include <RA_ATO.h>
#include <RA_Joystick.h>
#include <LED.h>
#include <RA_TempSensor.h>
#include <Relay.h>
#include <RA_PWM.h>
#include <Timer.h>
#include <Memory.h>
#include <InternalEEPROM.h>
#include <RA_Colors.h>
#include <RA_CustomColors.h>
#include <Salinity.h>
#include <RF.h>
#include <IO.h>
#include <ORP.h>
#include <AI.h>
#include <PH.h>
#include <WaterLevel.h>
#include <Humidity.h>
#include <DCPump.h>
#include <ReefAngel.h>
//#include <WiFiAlert.h>
//#include <RA_PCA9685.h>
#include <SunLocation.h>
#define NUMBERS_8x16
#define I2CPWM_PCA9685      0x40

////// Place global variable code below here


SunLocation sl;


byte ActinicPWMValue=0;
byte DaylightPWMValue=0;

////// Memory Locations used by all formulas
#define Mem_B_AcclDay  100 
// Note - 100 represents the hard coded Memory location used for this variable 
// not the value for the variable.
// This variable represents the current day in Acclimation Cycle. Set this value to the same 
// number of days as your AcclDuration to begin the acclimation cycle or set it to 0 to use 
// your normal dimming end% values.
#define Mem_B_AcclDuration  101 // Set this value to how many days you want your acclimation cycle to take.
#define Mem_B_SlopeStart  102 // Set this to your desired starting acclimation end%.

/////// Memory Locations used by Blue Formula
#define Mem_B_AcclStartEndBlue  105    // Acclimation starting Slope end%
#define Mem_B_SlopeEndBlue  106    // slope End%
////// Memory Locations used by White Formula
#define Mem_B_AcclStartEndWhite  110 // Acclimation starting Slope end%
#define Mem_B_SlopeEndWhite  111    // Slope End%

// Define Portal Variables
#define Var_AcclDay      0
//#define Var_DPump1       1
//#define Var_DPump2       2
//#define Var_Tide         3
//#define Var_TideMode     4
//#define Var_LogATO       5
//#define Var_WCVol        6
#define Var_weekday        7



void DrawCustomMain() {  //5,14
  char buf[16];
  byte acclDay = InternalMemory.read(Mem_B_AcclDay);
  
  ReefAngel.LCD.DrawLargeText(COLOR_BLACK, COLOR_WHITE, 6, 4, " Martin's BC29");
  ReefAngel.LCD.DrawDate(6, 118);
  
  // Temp and PH
  ReefAngel.LCD.DrawText(COLOR_BLACK,DefaultBGColor,10,14,"Temp:");
  ReefAngel.LCD.DrawText(COLOR_BLACK,DefaultBGColor,85, 14, "PH:");
  ConvertNumToString(buf, ReefAngel.Params.Temp[T1_PROBE], 10);
  ReefAngel.LCD.DrawText(T2TempColor, DefaultBGColor, 48, 16, buf); 
  ConvertNumToString(buf, ReefAngel.Params.Temp[T2_PROBE], 10);
  ReefAngel.LCD.DrawLargeText(T1TempColor, DefaultBGColor, 10, 22, buf, Num8x16);
  ConvertNumToString(buf, ReefAngel.Params.PH, 100);
  ReefAngel.LCD.DrawLargeText(PHColor, DefaultBGColor, 85, 22, buf, Num8x16);
  ConvertNumToString(buf, ReefAngel.Params.Temp[T3_PROBE], 10);
  ReefAngel.LCD.DrawText(T3TempColor, DefaultBGColor, 48, 25, buf);

  //ATO  
  ReefAngel.LCD.DrawLargeText(COLOR_INDIGO,DefaultBGColor,15,40,"High",Font8x16);
  ReefAngel.LCD.DrawLargeText(COLOR_INDIGO,DefaultBGColor,85,40,"Low",Font8x16);  
  if (ReefAngel.HighATO.IsActive()) {
    ReefAngel.LCD.FillCircle(55,43,5,COLOR_GREEN);
  } else {
    ReefAngel.LCD.FillCircle(55,43,5,COLOR_RED);
  }  
  if (ReefAngel.LowATO.IsActive()) {
    ReefAngel.LCD.FillCircle(70,43,5,COLOR_GREEN);
  } else {
    ReefAngel.LCD.FillCircle(70,43,5,COLOR_RED);
  }
  
  //Sunrise/Sunset Times
  ReefAngel.LCD.DrawText(0,255,5,52,"Rise:");
  ReefAngel.LCD.DrawText(0,255,38,52,(sl.GetRiseHour()));
  ReefAngel.LCD.DrawText(0,255,43,52,":");
  ReefAngel.LCD.DrawText(0,255,48,52,(sl.GetRiseMinute()));
  ReefAngel.LCD.DrawText(0,255,65,52,"Set:");
  ReefAngel.LCD.DrawText(0,255,88,52,(sl.GetSetHour()));
  ReefAngel.LCD.DrawText(0,255,100,52,":");
  ReefAngel.LCD.DrawText(0,255,105,52,(sl.GetSetMinute()));
  
  //Cloud Start and Lightning Start
    //ReefAngel.LCD.DrawText(0,255,5,62,"C");
    //ReefAngel.LCD.DrawText(0,255,11,62,"00:00");
    //ReefAngel.LCD.DrawText(0,255,45,62,"L");
    //ReefAngel.LCD.DrawText(0,255,51,62,"00:00");
  
  //Moon Phase
  ReefAngel.LCD.DrawText(0,255,5,72,"Moon:");
  ReefAngel.LCD.DrawText(0,255,35,72,MoonPhaseLabel());
  
  // Display Acclimation timer
  ReefAngel.LCD.DrawText(0,255,5,82,"Acclimation Day:");
  ReefAngel.LCD.DrawText(0,255,105,82,acclDay);
  
  // Display LED %
  ReefAngel.LCD.DrawText(0,255,12,92, "CW:");  
  ReefAngel.LCD.DrawText(197,255,32,92, ReefAngel.PWM.GetDaylightValue()); 
  ReefAngel.LCD.DrawText(0,255,72,92, "RB:");   
  ReefAngel.LCD.DrawText(3,255,92,92, ReefAngel.PWM.GetActinicValue());    
  
  // Display Relays  
  byte TempRelay = ReefAngel.Relay.RelayData;
  TempRelay &= ReefAngel.Relay.RelayMaskOff;
  TempRelay |= ReefAngel.Relay.RelayMaskOn;
  ReefAngel.LCD.DrawOutletBox(12, 102, TempRelay);
  
  
  
  
}
void DrawCustomGraph()
{
}

////// Place global variable code above here


void setup()
{
    // This must be the first line
    ReefAngel.Init();  //Initialize controller
    //ReefAngel.Use2014Screen();  // Let's use 2014 Screen 
    // Ports toggled in Feeding Mode
    ReefAngel.FeedingModePorts = Port1Bit | Port3Bit | Port6Bit | Port7Bit;
    // Ports toggled in Water Change Mode
    ReefAngel.WaterChangePorts = Port1Bit | Port2Bit | Port3Bit | Port4Bit | Port5Bit | Port6Bit | Port7Bit;
    // Ports toggled when Lights On / Off menu entry selected
    ReefAngel.LightsOnPorts = 0;
    // Ports turned off when Overheat temperature exceeded
    ReefAngel.OverheatShutoffPorts = Port2Bit;
    // Use T1 probe as temperature and overheat functions
    ReefAngel.TempProbe = T2_PROBE;
    ReefAngel.OverheatProbe = T2_PROBE;

    // Feeeding and Water Change mode speed
    ReefAngel.DCPump.FeedingSpeed=0;
    ReefAngel.DCPump.WaterChangeSpeed=0;

    // Ports that are always on
    ReefAngel.Relay.On( Port1 );
    ReefAngel.Relay.On( Port3 );
    ReefAngel.Relay.On( Port7 );
    ReefAngel.Relay.On( Port8 );

    ////// Place additional initialization code below here
    
  sl.Init(-21.285833, 150.999722); // In decimal numbers (i.e. -18.285833, 147.699722)
  sl.SetOffset(11,0,11,0); // rise_hour, rise_seconds, set_hour, set_seconds
  
  randomSeed(now()/SECS_PER_DAY);
    
  //if (InternalMemory.read(Mem_B_ResetMemory)) 
    //init_memory();    
    ////// Place additional initialization code above here
}

void loop()
{
  

    //ReefAngel.Relay.Set(Port1,weekday()==1 && hour()==8 && minute()==0&&second()<5);
    //ReefAngel.Relay.Set(Port1,weekday()==1 && hour()==8 && minute()==0&&second()<5);
    byte weekday();
    ReefAngel.CustomVar[Var_weekday]=weekday();
    
    ReefAngel.StandardHeater( Port2,779,790 );
    ReefAngel.StandardFan( Port7,779,790 );
    ReefAngel.DosingPumpRepeat1( Port4 );
    ReefAngel.DosingPumpRepeat2( Port5 );
    ReefAngel.StandardATO( Port6 );
    ReefAngel.PWM.SetChannel( 0, MoonPhase()/3 );
    ReefAngel.PWM.SetChannel( 1, MoonPhase()/3 );
    //ReefAngel.DCPump.UseMemory = true;
    //ReefAngel.DCPump.SetMode( rmode );
    ReefAngel.DCPump.DaylightChannel = None;
    ReefAngel.DCPump.ActinicChannel = None;
    ReefAngel.DCPump.ExpansionChannel[0] = None;
    ReefAngel.DCPump.ExpansionChannel[1] = None;
    ReefAngel.DCPump.ExpansionChannel[2] = Sync;
    ReefAngel.DCPump.ExpansionChannel[3] = AntiSync;
    ReefAngel.DCPump.ExpansionChannel[4] = None;
    ReefAngel.DCPump.ExpansionChannel[5] = None;    
    ////// Place your custom code below here
// Add random mode if we set to Mode to Custom in portal
static int rmode;
static boolean changeMode=true;

// Add Else Mode definition..
const int Else=16;

// These are the modes we can cycle through. You can add more and even repeat...
byte modes[] = { Lagoon, Else, ReefCrest, TidalSwell, ShortPulse, LongPulse, NutrientTransport };

if (now()%SECS_PER_DAY==0 || changeMode==true) { // Change at midnight or if controller rebooted
rmode=random(100)%sizeof(modes); // Change the mode once per day to pick from our array
changeMode=false;
}

// Set timer when in feeding mode
static unsigned long feeding;
if (ReefAngel.DisplayedMenu==FEEDING_MODE) feeding=now();

if (now()-feeding<900) { 
  // First 15 minutes after feeding mode stops. Skimmer is off
  ReefAngel.Relay.Off(Port3);
  //else 
  //ReefAngel.Relay.On(Port3);
  // First 15 minutes after feeding mode stops. Smart_NTM
  ReefAngel.DCPump.UseMemory=false;
  ReefAngel.DCPump.Mode=NutrientTransport;
} else if (now()-feeding<4500) { // 15 minutes plus 1 hour
  // Continue NTM for the next 60 minutes (75 minutes total)
  ReefAngel.DCPump.UseMemory=false;
  ReefAngel.DCPump.Mode=NutrientTransport;
} else if (now()%SECS_PER_DAY<30600 || now()%SECS_PER_DAY>=81000) { // 8:30am / 10:30pm
  // Night mode (go to 30%)
  ReefAngel.DCPump.UseMemory=false;
  ReefAngel.DCPump.Mode=Constant;
  ReefAngel.DCPump.Speed=30;
} else if (InternalMemory.DCPumpMode_read()==11) { 
  // Custom Mode and nothing else going on
  ReefAngel.DCPump.UseMemory=false;
  ReefAngel.DCPump.Duration=InternalMemory.DCPumpDuration_read();
  if (modes[rmode]==Else) {
    ReefAngel.DCPump.UseMemory=false;
    ReefAngel.DCPump.Mode=Constant;
    ReefAngel.DCPump.Speed=ElseMode(InternalMemory.DCPumpSpeed_read(),25,true );    // ElseMode on sync mode, Portal Speed Setting +/- 25%
  } else {
    ReefAngel.DCPump.Mode=modes[rmode];  // Put the mode to the random mode :)
    ReefAngel.DCPump.Speed=InternalMemory.DCPumpSpeed_read(); // Set speed from portal
  }
} else {
  ReefAngel.DCPump.UseMemory=true; // Will reset all values from memory
}

////////// Variables used for all channels
  byte acclDay = InternalMemory.read(Mem_B_AcclDay); 
// What day in the acclimation cycle it is 
  byte acclDuration = InternalMemory.read(Mem_B_AcclDuration); 
// Acclimation Duration in days
  byte startPercent = InternalMemory.read(Mem_B_SlopeStart); 
// Normal start% being used by all 3 channels

ReefAngel.CustomVar[Var_AcclDay]=acclDay;

////////// Blue Channel Variables
  byte acclStartEndBlue = InternalMemory.read(Mem_B_AcclStartEndBlue); 
// Starting End% for Acclimation cycle
  float acclendPercentBlue = InternalMemory.read(Mem_B_SlopeEndBlue); 
// Your target Blue end% once acclimation is complete

////////// Blue Channel Formula
  float acclPercentPerDayBlue = (acclendPercentBlue - acclStartEndBlue) / acclDuration;
// How much your Blue end% rises per acclimation day 
  float acclFactorBlue = acclDay * acclPercentPerDayBlue; 
// endPercentBlue will be offset by this much. If acclDay = 0 then this value will be 0
  byte endPercentBlue = acclendPercentBlue - acclFactorBlue; 
// Your final Blue end% for the day



////////// White Channel Variables
  byte acclStartEndWhite = InternalMemory.read(Mem_B_AcclStartEndWhite); 
// Starting End% for Acclimation cycle
  float acclEndPercentWhite = InternalMemory.read(Mem_B_SlopeEndWhite); 
// Your target White end% once acclimation is complete

////////// White Channel Formula
  float acclPercentPerDayWhite= (acclEndPercentWhite - acclStartEndWhite) / acclDuration; 
// How much your White end% rises per acclimation day
  float acclFactorWhite = acclDay * acclPercentPerDayWhite; 
// endPercentWhite will be offset by this much. If acclDay = 0 then this value will be 0
  byte endPercentWhite = acclEndPercentWhite - acclFactorWhite; 

// At the end of the day, we need to decrement the acclimation counter.
  static boolean acclCounterReady=false; // We need a boolean so we only do this once per day
  if (now()%SECS_PER_DAY!=0) acclCounterReady=true; // If it's not midnight we'll get the boolean ready
  if (now()%SECS_PER_DAY==0 && acclCounterReady && acclDay>0) { // It's midnight, our bool is true and acclDay is more than 0
    acclDay--; // Reduce the counter
    acclCounterReady=false; // Reset the boolean flag
    InternalMemory.write(Mem_B_AcclDay,acclDay); // Update memory
}
    
    // handle updating sunrise and sunset values
    sl.CheckAndUpdate();
    //sl.SetOffset(10,0,10,0); // rise_hour, rise_seconds, set_hour, set_seconds
    ////// Place your custom code above here

    // This should always be the last line
    ReefAngel.Portal( "89delta" );
    ReefAngel.ShowInterface();
    
    
  // Calculate your regular sunrise/sunset PWM value
  ActinicPWMValue=PWMSlope(sl.GetRiseHour(),sl.GetRiseMinute(),sl.GetSetHour(),sl.GetSetMinute(),startPercent,endPercentBlue,120,(MoonPhase()/3));
  DaylightPWMValue=PWMSlope(sl.GetRiseHour(),sl.GetRiseMinute(),sl.GetSetHour(),sl.GetSetMinute(),startPercent,endPercentWhite,120,DaylightPWMValue);
  //ActinicPWMValue=PWMSlope(sl.GetRiseHour(),sl.GetRiseMinute(),sl.GetSetHour(),sl.GetSetMinute(),0,90,120,(MoonPhase()/3));
  //DaylightPWMValue=PWMSlope(sl.GetRiseHour(),sl.GetRiseMinute(),sl.GetSetHour(),sl.GetSetMinute(),0,90,120,DaylightPWMValue);
  CheckCloud();
  
  ReefAngel.PWM.SetActinic(ActinicPWMValue);
  ReefAngel.PWM.SetDaylight(DaylightPWMValue);    
  
  

}





//*********************************************************************************************************************************
// Random Cloud/Thunderstorm effects function
void CheckCloud()
{

  // ------------------------------------------------------------
  // Change the values below to customize your cloud/storm effect

  // Frequency in days based on the day of the month - number 2 means every 2 days, for example (day 2,4,6 etc)
  // For testing purposes, you can use 1 and cause the cloud to occur everyday
#define Clouds_Every_X_Days 1 

  // Percentage chance of a cloud happening today
  // For testing purposes, you can use 100 and cause the cloud to have 100% chance of happening
#define Cloud_Chance_per_Day 100

  // Minimum number of minutes for cloud duration.  Don't use max duration of less than 6
#define Min_Cloud_Duration 6

  // Maximum number of minutes for the cloud duration. Don't use max duration of more than 255
#define Max_Cloud_Duration 15

  // Minimum number of clouds that can happen per day
#define Min_Clouds_per_Day 3

  // Maximum number of clouds that can happen per day
#define Max_Clouds_per_Day 10

  // Only start the cloud effect after this setting
  // In this example, start could after 11:30am
#define Start_Cloud_After NumMins(8,30)

  // Always end the cloud effect before this setting
  // In this example, end could before 8:00pm
#define End_Cloud_Before NumMins(18,30)

  // Percentage chance of a lightning happen for every cloud
  // For testing purposes, you can use 100 and cause the lightning to have 100% chance of happening
#define Lightning_Change_per_Cloud 100

  // Note: Make sure to choose correct values that will work within your PWMSLope settings.
  // For example, in our case, we could have a max of 5 clouds per day and they could last for 50 minutes.
  // Which could mean 250 minutes of clouds. We need to make sure the PWMSlope can accomodate 250 minutes of effects or unforseen resul could happen.
    // Also, make sure that you can fit double those minutes between Start_Cloud_After and End_Cloud_Before.
  // In our example, we have 510 minutes between Start_Cloud_After and End_Cloud_Before, so double the 250 minutes (or 500 minutes) can fit in that 510 minutes window.
    // It's a tight fit, but it did.

    //#define printdebug // Uncomment this for debug print on Serial Monitor window
  #define forcecloudcalculation // Uncomment this to force the cloud calculation to happen in the boot process. 


  // Change the values above to customize your cloud/storm effect
  // ------------------------------------------------------------
  // Do not change anything below here

  static byte cloudchance=255;
  static byte cloudduration=0;
  static int cloudstart=0;
  static byte numclouds=0;
  static byte lightningchance=0;
  static byte cloudindex=0;
  static byte lightningstatus=0;
  static int LastNumMins=0;
  // Every day at midnight, we check for chance of cloud happening today
  if (hour()==0 && minute()==0 && second()==0) cloudchance=255;

#ifdef forcecloudcalculation
    if (cloudchance==255)
#else
    if (hour()==0 && minute()==0 && second()==1 && cloudchance==255) 
#endif
    {
      //Pick a random number between 0 and 99
      cloudchance=random(100); 
      // if picked number is greater than Cloud_Chance_per_Day, we will not have clouds today
      if (cloudchance>Cloud_Chance_per_Day) cloudchance=0;
      // Check if today is day for clouds. 
      if ((day()%Clouds_Every_X_Days)!=0) cloudchance=0; 
      // If we have cloud today
      if (cloudchance)
      {
        // pick a random number for number of clouds between Min_Clouds_per_Day and Max_Clouds_per_Day
        numclouds=random(Min_Clouds_per_Day,Max_Clouds_per_Day);
        // pick the time that the first cloud will start
        // the range is calculated between Start_Cloud_After and the even distribuition of clouds on this day. 
        cloudstart=random(Start_Cloud_After,Start_Cloud_After+((End_Cloud_Before-Start_Cloud_After)/(numclouds*2)));
        // pick a random number for the cloud duration of first cloud.
        cloudduration=random(Min_Cloud_Duration,Max_Cloud_Duration);
        //Pick a random number between 0 and 99
        lightningchance=random(100);
        // if picked number is greater than Lightning_Change_per_Cloud, we will not have lightning today
        if (lightningchance>Lightning_Change_per_Cloud) lightningchance=0;
      }
    }
  // Now that we have all the parameters for the cloud, let's create the effect

  if (cloudchance)
  {
    //is it time for cloud yet?
    if (NumMins(hour(),minute())>=cloudstart && NumMins(hour(),minute())<(cloudstart+cloudduration))
    {
      DaylightPWMValue=ReversePWMSlope(cloudstart,cloudstart+cloudduration,DaylightPWMValue,0,180);
      if (lightningchance && (NumMins(hour(),minute())==(cloudstart+(cloudduration/2))) && second()<5) 
      {
        if (random(100)<20) lightningstatus=1; 
        else lightningstatus=0;
        if (lightningstatus)
        {
          DaylightPWMValue=100; 
          ActinicPWMValue=100;
        }
        else 
        {
          DaylightPWMValue=0;
          ActinicPWMValue=0;
        }
        delay(1);
      }
    }
    if (NumMins(hour(),minute())>(cloudstart+cloudduration))
    {
      cloudindex++;
      if (cloudindex < numclouds)
      {
        cloudstart=random(Start_Cloud_After+(((End_Cloud_Before-Start_Cloud_After)/(numclouds*2))*cloudindex*2),(Start_Cloud_After+(((End_Cloud_Before-Start_Cloud_After)/(numclouds*2))*cloudindex*2))+((End_Cloud_Before-Start_Cloud_After)/(numclouds*2)));
        // pick a random number for the cloud duration of first cloud.
        cloudduration=random(Min_Cloud_Duration,Max_Cloud_Duration);
        //Pick a random number between 0 and 99
        lightningchance=random(100);
        // if picked number is greater than Lightning_Change_per_Cloud, we will not have lightning today
        if (lightningchance>Lightning_Change_per_Cloud) lightningchance=0;
      }
    }
  }
  
  if (LastNumMins!=NumMins(hour(),minute()))
  {
    LastNumMins=NumMins(hour(),minute());
    ReefAngel.LCD.Clear(255,0,62,132,132);
  ReefAngel.LCD.DrawText(0,255,5,62,"C");
  ReefAngel.LCD.DrawText(0,255,11,62,"00:00");
  ReefAngel.LCD.DrawText(0,255,45,62,"L");
  ReefAngel.LCD.DrawText(0,255,51,62,"00:00");
    if (cloudchance && (NumMins(hour(),minute())<cloudstart))
    {
      int x=0;
      if ((cloudstart/60)>=10) x=11; else x=17;
      ReefAngel.LCD.DrawText(0,255,x,62,(cloudstart/60));
      if ((cloudstart%60)>=10) x=29; else x=35;
      ReefAngel.LCD.DrawText(0,255,x,62,(cloudstart%60));
    }
    ReefAngel.LCD.DrawText(0,255,90,62,cloudduration);
    if (lightningchance) 
    {
      int x=0;
      if (((cloudstart+(cloudduration/2))/60)>=10) x=51; else x=57;
      ReefAngel.LCD.DrawText(0,255,x,62,((cloudstart+(cloudduration/2))/60));
      if (((cloudstart+(cloudduration/2))%60)>=10) x=69; else x=75;
      ReefAngel.LCD.DrawText(0,255,x,62,((cloudstart+(cloudduration/2))%60));
    }
  }   
}

byte ReversePWMSlope(long cstart,long cend,byte PWMStart,byte PWMEnd, byte clength)
{
  long n=elapsedSecsToday(now());
  cstart*=60;
  cend*=60;
  if (n<cstart) return PWMStart;
  if (n>=cstart && n<=(cstart+clength)) return map(n,cstart,cstart+clength,PWMStart,PWMEnd);
  if (n>(cstart+clength) && n<(cend-clength)) return PWMEnd;
  if (n>=(cend-clength) && n<=cend) return map(n,cend-clength,cend,PWMEnd,PWMStart);
  if (n>cend) return PWMStart;
}

byte ElseMode( byte MidPoint, byte Offset, boolean WaveSync )
{
  // Static's only initialize the first time they are called
  static unsigned long LastChange=millis();        // Set the inital time that the last change occurred
  static int Delay = random( 500, 3000);           // Set the initial delay
  static int NewSpeed = MidPoint;                  // Set the initial speed
  static int AntiSpeed = MidPoint;                 // Set the initial anti sync speed
  if ((millis()-LastChange) > Delay)               // Check if the delay has elapsed
  {
    Delay=random(500,5000);                        // If so, come up with a new delay
    int ChangeUp = random(Offset);                 // Amount to go up or down
    if (random(100)<50)                            // 50/50 chance of speed going up or going down
    {
      NewSpeed = MidPoint - ChangeUp;
      AntiSpeed = MidPoint + ChangeUp;
    }
    else
    {
      NewSpeed = MidPoint + ChangeUp;
      AntiSpeed = MidPoint - ChangeUp;
    }
    LastChange=millis();                           // Reset the time of the last change
  }
  if (WaveSync)
  {
    return NewSpeed;
  }
  else
  {
    return AntiSpeed;
  }
}
User avatar
lnevo
Posts: 5430
Joined: Fri Jul 20, 2012 9:42 am

Re: Skimmer not coming back on after feed mode

Post by lnevo »

Move ReefAngel.Relay.On(Port3); to the top of the loop() function instead of setup().

Essentially you are turning it off during feeding mode and nothing is turning it back on. You may also want to use DelayedOn instead of On also to prevent an overflow.
Post Reply