Cloud and Lightning Code

Do you have a question on how to do something.
Ask in here.
89delta
Posts: 163
Joined: Mon Oct 15, 2012 7:21 pm
Location: Leesburg, GA

Re: Cloud and Lightning Code

Post by 89delta »

Am sure if we can do some sort of last state on the relays before the lighting it'd fix it....

Sent from my SAMSUNG-SGH-I717 using Tapatalk
User avatar
cosmith71
Posts: 1437
Joined: Fri Mar 29, 2013 3:51 pm
Location: Oklahoma City

Re: Cloud and Lightning Code

Post by cosmith71 »

89delta wrote:Am sure if we can do some sort of last state on the relays before the lighting it'd fix it....

Sent from my SAMSUNG-SGH-I717 using Tapatalk
I think it would be better if we could prevent the reset to begin with. I have some ideas. I'll work on them Monday when I have some time. :ugeek:

--Colin
89delta
Posts: 163
Joined: Mon Oct 15, 2012 7:21 pm
Location: Leesburg, GA

Re: Cloud and Lightning Code

Post by 89delta »

Sounds good Colin. Thanks for working on a fix for it. But figured you would want to know about the "bug".
User avatar
cosmith71
Posts: 1437
Joined: Fri Mar 29, 2013 3:51 pm
Location: Oklahoma City

Re: Cloud and Lightning Code

Post by cosmith71 »

You're welcome!

--Colin
User avatar
cosmith71
Posts: 1437
Joined: Fri Mar 29, 2013 3:51 pm
Location: Oklahoma City

Re: Cloud and Lightning Code

Post by cosmith71 »

I have a fix, in theory at least. I haven't had a lot of time to test but it appears to work.

Find this section in cloudcheck()

Code: Select all

static byte cloudchance=255;
  static byte cloudduration=0;
  static int cloudstart=0;
  static byte numclouds=0;
  static byte lightningchance=0;
  static byte cloudindex=0;
  static byte lightningstatus=0;
  static int LastNumMins=0;
And add these two lines:

Code: Select all

static time_t DelayCounter=millis();
static int DelayTime=random(1000);
Remove this section:

Code: Select all

if (lightningchance && (NumMins(hour(),minute())==(cloudstart+(cloudduration/2))) && second()<5) 
      {
        int a=random(5);
        for (int i=0; i<a; i++)
        {
          analogWrite(daylightPWMPin, 255);
          delay(20+random(50));
          analogWrite(daylightPWMPin, 0);
          delay(30+random(20));
        }
        delay(random(1000));
      }
And replace with this:

Code: Select all

if (lightningchance && (NumMins(hour(),minute())==(cloudstart+(cloudduration/2))) && second()<5 && (millis()-DelayCounter)>DelayTime) 
      {
        int a=random(5);
        for (int i=0; i<a; i++)
        {
          analogWrite(daylightPWMPin, 255);
          delay(20+random(50));
          analogWrite(daylightPWMPin, 0);
          delay(30+random(20));
        }
        DelayCounter=millis();
        DelayTime=random(1000);
      }
This appears to work without setting off the watchdog timer and resetting the unit.

--Colin
Last edited by cosmith71 on Sun Aug 03, 2014 1:29 pm, edited 1 time in total.
User avatar
Sacohen
Posts: 1833
Joined: Sun Apr 21, 2013 6:25 am
Location: Davie, FL

Re: Cloud and Lightning Code

Post by Sacohen »

I bit OT, but do the LDD drivers generate enough heat to be concerned about.
I'm putting my 4 up board in a Radio Shack 5x2.5x2 Project Enclosure with openings cut in the sides to gain access to the screw down terminals for wiring.

Image

Do I need another source of ventilation?
User avatar
cosmith71
Posts: 1437
Joined: Fri Mar 29, 2013 3:51 pm
Location: Oklahoma City

Re: Cloud and Lightning Code

Post by cosmith71 »

I was surprised at how hot mine get. The more LED's on the string, the hotter they get. Some of mine get up to 60C, and they are open air.

--Colin
User avatar
Sacohen
Posts: 1833
Joined: Sun Apr 21, 2013 6:25 am
Location: Davie, FL

Re: Cloud and Lightning Code

Post by Sacohen »

Thanks and thanks for the code.

Here is what my enclosure looks like.
I may have to leave it open air or have a fan blowing on it.

Image
rimai
Posts: 12881
Joined: Fri Mar 18, 2011 6:47 pm

Re: Cloud and Lightning Code

Post by rimai »

I think the reboot issue is the watchdog kicking in.
We need to reset it inside the lightning sequence.
I'm pretty sure if you use the original code and just add the code below inside the for loop, it will stop:

Code: Select all

wdt_reset();
Roberto.
User avatar
cosmith71
Posts: 1437
Joined: Fri Mar 29, 2013 3:51 pm
Location: Oklahoma City

Re: Cloud and Lightning Code

Post by cosmith71 »

How often does the watchdog timer need to be reset? I thought it was every second. The big delay is the delay(random(1000)) just outside the loop which might be pushing it over the top.

I'm thinking we may need more lightning. Like a chance during most of the cloud. Might be my day-off project. :mrgreen:

--Colin
rimai
Posts: 12881
Joined: Fri Mar 18, 2011 6:47 pm

Re: Cloud and Lightning Code

Post by rimai »

Yes, every second and you are right. You may need one wdt_reset outside the loop too.
Roberto.
User avatar
lnevo
Posts: 5430
Joined: Fri Jul 20, 2012 9:42 am

Re: Cloud and Lightning Code

Post by lnevo »

Do we need a delay here? Sorry I haven't looked deep enough at the code, but is there any way to be non-blocking? Delays can add up...

I've already seen slowdown in some calculations because my INO is slow to begin with...

What i would recommend maybe is increasing the watchdog timeout if possible or disable/enable before and after the delay is needed.
User avatar
cosmith71
Posts: 1437
Joined: Fri Mar 29, 2013 3:51 pm
Location: Oklahoma City

Re: Cloud and Lightning Code

Post by cosmith71 »

Take a look at the replacement code. It doesn't delay so much as it just doesn't flash again until an appropriate period of time has passed. The for() loop can take up to 600 ms max to execute, but past that it's non-blocking.

That, and in it's current form, it only happens for 5 seconds max in the middle of a cloud.

--Colin
User avatar
lnevo
Posts: 5430
Joined: Fri Jul 20, 2012 9:42 am

Re: Cloud and Lightning Code

Post by lnevo »

You don't need a for loop...we are already in a loop....if the for loop is what is taking time we can change that so its less stateful and doesnt require a second loop. I'll take a better look this week..
User avatar
cosmith71
Posts: 1437
Joined: Fri Mar 29, 2013 3:51 pm
Location: Oklahoma City

Re: Cloud and Lightning Code

Post by cosmith71 »

The new code has ran a couple of times today already. No resets so far.

--Colin
User avatar
lnevo
Posts: 5430
Joined: Fri Jul 20, 2012 9:42 am

Re: Cloud and Lightning Code

Post by lnevo »

Post it
User avatar
cosmith71
Posts: 1437
Joined: Fri Mar 29, 2013 3:51 pm
Location: Oklahoma City

Re: Cloud and Lightning Code

Post by cosmith71 »

I did. See previous page. :)

--Colin
User avatar
lnevo
Posts: 5430
Joined: Fri Jul 20, 2012 9:42 am

Re: Cloud and Lightning Code

Post by lnevo »

I meant the update...wasnt sure you updated the first post or not
User avatar
cosmith71
Posts: 1437
Joined: Fri Mar 29, 2013 3:51 pm
Location: Oklahoma City

Re: Cloud and Lightning Code

Post by cosmith71 »

lnevo wrote:I meant the update...wasnt sure you updated the first post or not
Not yet, I wanted to test it first. But I will soon.

--Colin
User avatar
cosmith71
Posts: 1437
Joined: Fri Mar 29, 2013 3:51 pm
Location: Oklahoma City

Re: Cloud and Lightning Code

Post by cosmith71 »

OP updated with non-apocalyptic timing. It shouldn't set off the watchdog timer and reset the unit anymore. It's also less monopolistic of resources when it's running.

--Colin
User avatar
cosmith71
Posts: 1437
Joined: Fri Mar 29, 2013 3:51 pm
Location: Oklahoma City

Re: Cloud and Lightning Code

Post by cosmith71 »

Also added option for Mega Storm to OP, with lightning throughout the cloud increasing in intensity as the cloud gets darker. Pretty awesome, if I do say so myself!

--Colin
User avatar
lnevo
Posts: 5430
Joined: Fri Jul 20, 2012 9:42 am

Re: Cloud and Lightning Code

Post by lnevo »

Colin, any chance you can integrate the "mini" storm (non-fast/responsive drivers) so i have one cloud function to work on? I'm going to add high resolution dimming and potentially turn this into a class for ease of use/configuration.
User avatar
lnevo
Posts: 5430
Joined: Fri Jul 20, 2012 9:42 am

Re: Cloud and Lightning Code

Post by lnevo »

Oh and btw, that sounds AWESOME!!!
89delta
Posts: 163
Joined: Mon Oct 15, 2012 7:21 pm
Location: Leesburg, GA

Re: Cloud and Lightning Code

Post by 89delta »

Oh wow....just got home from work....added ur update last night but haven't checked the relay state yet for the skimmer.....but the mega storm option sounds wicked.....

Sent from my SAMSUNG-SGH-I717 using Tapatalk
User avatar
lnevo
Posts: 5430
Joined: Fri Jul 20, 2012 9:42 am

Re: Cloud and Lightning Code

Post by lnevo »

We should add an array of storm types you want and randomize between them. :) sometimes mega, sometimes mini, could even simulate a storm coming in. Where is Jon, time to start talking about the audio out he has again...
User avatar
cosmith71
Posts: 1437
Joined: Fri Mar 29, 2013 3:51 pm
Location: Oklahoma City

Re: Cloud and Lightning Code

Post by cosmith71 »

OK, added the slow response lightning to the OP. It's selectable via a variable switch in the checkcloud() routine.

I doubt I would want to run anything but Mega-Storm. It's awesome. :mrgreen:

--Colin
User avatar
cosmith71
Posts: 1437
Joined: Fri Mar 29, 2013 3:51 pm
Location: Oklahoma City

Re: Cloud and Lightning Code

Post by cosmith71 »

89delta wrote:Oh wow....just got home from work....added ur update last night but haven't checked the relay state yet for the skimmer.....but the mega storm option sounds wicked.....

Sent from my SAMSUNG-SGH-I717 using Tapatalk
I haven't had any issues with overrides with the new code. Even with the Mega-Storm, everything runs smooth with no resets.

--Colin
User avatar
Sacohen
Posts: 1833
Joined: Sun Apr 21, 2013 6:25 am
Location: Davie, FL

Re: Cloud and Lightning Code

Post by Sacohen »

God I can't wait to get my LEE's up and running.
89delta
Posts: 163
Joined: Mon Oct 15, 2012 7:21 pm
Location: Leesburg, GA

Re: Cloud and Lightning Code

Post by 89delta »

No issues with the relays resetting Colin...Thanks.....but am gonna update the new code tonight. Lnevo....great idea about the storm mode being randomized.
User avatar
lnevo
Posts: 5430
Joined: Fri Jul 20, 2012 9:42 am

Cloud and Lightning Code

Post by lnevo »

Colin,

You left the default as Mega :)

I added the random selection, you'll just need to set this array to the types of lightning you want:

Code: Select all

  // Set which modes you want to use  
byte LightningModes[] = { Slow, Fast, Mega };
Once you set that, each cloud should have a unique lightning type. If you just want Slow, or Fast you can put one. If you want one more than the others, you can put it multiple times in the array :) Need to think a little more how we could combine multiple types of lightning during one cloud episode. I need to actually run the code though too to see how it looks overall :)

Code: Select all

// Random Cloud/Thunderstorm effects function

void CheckCloud()
{

  // ------------------------------------------------------------
  // Change the values below to customize your cloud/storm effect

  // Frequency in days based on the day of the month - number 2 means every 2 days, for example (day 2,4,6 etc)
  // For testing purposes, you can use 1 and cause the cloud to occur everyday
#define Clouds_Every_X_Days 1 

  // Percentage chance of a cloud happening today
  // For testing purposes, you can use 100 and cause the cloud to have 100% chance of happening
#define Cloud_Chance_per_Day 100

  // Minimum number of minutes for cloud duration.  Don't use max duration of less than 6
#define Min_Cloud_Duration 7

  // Maximum number of minutes for the cloud duration. Don't use max duration of more than 255
#define Max_Cloud_Duration 10

  // Minimum number of clouds that can happen per day
#define Min_Clouds_per_Day 3

  // Maximum number of clouds that can happen per day
#define Max_Clouds_per_Day 5

  // Only start the cloud effect after this setting
  // In this example, start cloud after noon
#define Start_Cloud_After NumMins(12,00)

  // Always end the cloud effect before this setting
  // In this example, end cloud before 9:00pm
#define End_Cloud_Before NumMins(21,00)

  // Percentage chance of a lightning happen for every cloud
  // For testing purposes, you can use 100 and cause the lightning to have 100% chance of happening
#define Lightning_Change_per_Cloud 100

  // Note: Make sure to choose correct values that will work within your PWMSLope settings.
  // For example, in our case, we could have a max of 5 clouds per day and they could last for 50 minutes.
  // Which could mean 250 minutes of clouds. We need to make sure the PWMSlope can accomodate 250 minutes of effects or unforseen resul could happen.
  // Also, make sure that you can fit double those minutes between Start_Cloud_After and End_Cloud_Before.
  // In our example, we have 510 minutes between Start_Cloud_After and End_Cloud_Before, so double the 250 minutes (or 500 minutes) can fit in that 510 minutes window.
  // It's a tight fit, but it did.

  //#define printdebug // Uncomment this for debug print on Serial Monitor window
#define forcecloudcalculation // Uncomment this to force the cloud calculation to happen in the boot process. 

  // Add Random Lightning modes
#define Slow 0
#define Fast 1
#define Mega 2
  // Set which modes you want to use  
byte LightningModes[] = { Slow, Fast, Mega };

  // Change the values above to customize your cloud/storm effect
  // ------------------------------------------------------------
  // Do not change anything below here

  static byte cloudchance=255;
  static byte cloudduration=0;
  static int cloudstart=0;
  static byte numclouds=0;
  static byte lightningchance=0;
  static byte cloudindex=0;
  static byte lightningstatus=0;
  static int LastNumMins=0;
  static byte lightningMode=0;
  static boolean chooseLightning=true;
  
  static time_t DelayCounter=millis();    // Variable for lightning timing.  
  static int DelayTime=random(1000);      // Variable for lightning timimg.
  
  // Every day at midnight, we check for chance of cloud happening today
  if (hour()==0 && minute()==0 && second()==0) cloudchance=255;

#ifdef forcecloudcalculation
    if (cloudchance==255)
#else
    if (hour()==0 && minute()==0 && second()==1 && cloudchance==255) 
#endif
    {
      randomSeed(millis());    // Seed the random number generator
      //Pick a random number between 0 and 99
      cloudchance=random(100); 
      // if picked number is greater than Cloud_Chance_per_Day, we will not have clouds today
      if (cloudchance>Cloud_Chance_per_Day) cloudchance=0;
      // Check if today is day for clouds. 
      if ((day()%Clouds_Every_X_Days)!=0) cloudchance=0; 
      // If we have cloud today
      if (cloudchance)
      {
        // pick a random number for number of clouds between Min_Clouds_per_Day and Max_Clouds_per_Day
        numclouds=random(Min_Clouds_per_Day,Max_Clouds_per_Day);
        // pick the time that the first cloud will start
        // the range is calculated between Start_Cloud_After and the even distribuition of clouds on this day. 
        cloudstart=random(Start_Cloud_After,Start_Cloud_After+((End_Cloud_Before-Start_Cloud_After)/(numclouds*2)));
        // pick a random number for the cloud duration of first cloud.
        cloudduration=random(Min_Cloud_Duration,Max_Cloud_Duration);
        //Pick a random number between 0 and 99
        lightningchance=random(100);
        // if picked number is greater than Lightning_Change_per_Cloud, we will not have lightning today
        if (lightningchance>Lightning_Change_per_Cloud) lightningchance=0; 
      }
    }
  // Now that we have all the parameters for the cloud, let's create the effect

  
  if (cloudchance)
  {
    //is it time for cloud yet?
    if (NumMins(hour(),minute())>=cloudstart && NumMins(hour(),minute())<(cloudstart+cloudduration))
    {
      DaylightPWMValue=ReversePWMSlope(cloudstart,cloudstart+cloudduration,DaylightPWMValue,0,180);
      // Check for lightning.  When lightning occurs, it will happen for 5 seconds at the middle of a cloud.
      // We will have from 1 to 4 consecutive flashes, then a random delay of up to 1000 ms before another set of flashes.
      // This first line basically says:  Is there supposed to be lightning?  Are we within a 5 second window in the middle
      // of the cloud when lightning occurs?  Are we not in a delay between sets of flashes?  If so, do another round of flashes.
      if (chooseLightning) { lightningMode=LightningModes[random(100)%sizeof(LightningModes)]; chooseLightning=false; } 
        switch (lightningMode) {
        case Mega:
      if (lightningchance && random(ReversePWMSlope(cloudstart,cloudstart+cloudduration,100,0,180))<1 && (millis()-DelayCounter)>DelayTime)
      {
        int a=random(1,5);    // Pick a number of consecutive flashes from 1 to 4.  
        for (int i=0; i<a; i++)
        {
          analogWrite(daylightPWMPin, 255);    // Flash on
          delay(20+random(50));                // Wait from 20 to 69 ms
          analogWrite(daylightPWMPin, 0);      // Flash off
          delay(30+random(20));                // Wait from 30 to 49 ms 
        }
        DelayCounter=millis();    // If we just had a round of flashes, then lets put in a longer delay
        DelayTime=random(1000);   // of up to a second for dramatic effect before we do another round. 
      }
      break;
        case Fast:
      if (lightningchance && (NumMins(hour(),minute())==(cloudstart+(cloudduration/2))) && second()<5 && (millis()-DelayCounter)>DelayTime)
      {
        int a=random(1,5);    // Pick a number of consecutive flashes from 1 to 4.  
        for (int i=0; i<a; i++)
        {
          analogWrite(daylightPWMPin, 255);    // Flash on
          delay(20+random(50));                // Wait from 20 to 69 ms
          analogWrite(daylightPWMPin, 0);      // Flash off
          delay(30+random(20));                // Wait from 30 to 49 ms 
        }
        DelayCounter=millis();    // If we just had a round of flashes, then lets put in a longer delay
        DelayTime=random(1000);   // of up to a second for dramatic effect before we do another round. 
      }
      break;
        case Slow:
         if (lightningchance && (NumMins(hour(),minute())==(cloudstart+(cloudduration/2))) && second()<5) 
      {
        if (random(100)<20) lightningstatus=1; 
        else lightningstatus=0;
        if (lightningstatus)
        {
          DaylightPWMValue=100; 
        }
        else 
        {
          DaylightPWMValue=0;
        }
        delay(1);
      }
        break;
        default:
        break;
      }
    } else {
      chooseLightning=true; // Reset the flag to choose a new lightning type
    }
    
    if (NumMins(hour(),minute())>(cloudstart+cloudduration))
    {
      cloudindex++;
      if (cloudindex < numclouds)
      {
        cloudstart=random(Start_Cloud_After+(((End_Cloud_Before-Start_Cloud_After)/(numclouds*2))*cloudindex*2),(Start_Cloud_After+(((End_Cloud_Before-Start_Cloud_After)/(numclouds*2))*cloudindex*2))+((End_Cloud_Before-Start_Cloud_After)/(numclouds*2)));
        // pick a random number for the cloud duration of first cloud.
        cloudduration=random(Min_Cloud_Duration,Max_Cloud_Duration);
        //Pick a random number between 0 and 99
        lightningchance=random(100);
        // if picked number is greater than Lightning_Change_per_Cloud, we will not have lightning today
        if (lightningchance>Lightning_Change_per_Cloud) lightningchance=0;
      }
    }
  }
  
  // Write the times of the next cloud, next lightning, and cloud duration to the screen and into some customvars for the Portal.
  if (LastNumMins!=NumMins(hour(),minute()))
  {
    LastNumMins=NumMins(hour(),minute());
    ReefAngel.LCD.Clear(255,0,120,132,132);
    ReefAngel.LCD.DrawText(0,255,5,120,"C");
    ReefAngel.LCD.DrawText(0,255,11,120,"00:00");
    ReefAngel.LCD.DrawText(0,255,45,120,"L");
    ReefAngel.LCD.DrawText(0,255,51,120,"00:00");
    if (cloudchance && (NumMins(hour(),minute())<cloudstart))
    {
      int x=0;
      if ((cloudstart/60)>=10) x=11; else x=17;
      ReefAngel.LCD.DrawText(0,255,x,120,(cloudstart/60));
      ReefAngel.CustomVar[3]=cloudstart/60;    // Write the hour of the next cloud to custom variable for Portal reporting
      if ((cloudstart%60)>=10) x=29; else x=35;
      ReefAngel.LCD.DrawText(0,255,x,120,(cloudstart%60));
      ReefAngel.CustomVar[4]=cloudstart%60;    // Write the minute of the next cloud to custom variable for Portal reporting

    }
    ReefAngel.LCD.DrawText(0,255,90,120,cloudduration);
    ReefAngel.CustomVar[7]=(cloudduration);    // Put the duration of the next cloud in a custom var for the portal
    if (lightningchance) 
    {
      int x=0;
      if (((cloudstart+(cloudduration/2))/60)>=10) x=51; else x=57;
      ReefAngel.LCD.DrawText(0,255,x,120,((cloudstart+(cloudduration/2))/60));
      ReefAngel.CustomVar[5]=(cloudstart+(cloudduration/2))/60;    // Write the hour of the next lightning to a custom variable for the Portal
      if (((cloudstart+(cloudduration/2))%60)>=10) x=69; else x=75;
      ReefAngel.LCD.DrawText(0,255,x,120,((cloudstart+(cloudduration/2))%60));    // Write the minute of the next lightning to a custom variable for the Portal
      ReefAngel.CustomVar[6]=(cloudstart+(cloudduration/2))%60;
    }
  }   
}

byte ReversePWMSlope(long cstart,long cend,byte PWMStart,byte PWMEnd, byte clength)
{
  long n=elapsedSecsToday(now());
  cstart*=60;
  cend*=60;
  if (n<cstart) return PWMStart;
  if (n>=cstart && n<=(cstart+clength)) return map(n,cstart,cstart+clength,PWMStart,PWMEnd);
  if (n>(cstart+clength) && n<(cend-clength)) return PWMEnd;
  if (n>=(cend-clength) && n<=cend) return map(n,cend-clength,cend,PWMEnd,PWMStart);
  if (n>cend) return PWMStart;
}
Post Reply