3 black box (SB Basics) on Dimming Expansion

Do you have a question on how to do something.
Ask in here.

Posts: 81
Joined: Mon Aug 11, 2014 6:45 am
Location: Clermont, Florida
PostPosted: Sun Jul 17, 2016 3:17 pm
So I finished my wiring, got everything hung, loaded the code, and fired them up. To my delight, they are working, which means I didn't screw anything up, haha. Now, keeping in mind I just got them going about an hour ago, around 5 pm est, I am finding the parabolas are way off from where they should be. Could that be because I need to give it a day to reset overnight and correct itself?

Also, right now, the lefts are higher % than the rights. I know the wiring is correct, so will that correct itself overnight, or is the issue in the code?

Pretty happy so far though! Thank you Lee!!! I set the lights at 12", but I think I may need to lower them 3-4 inches. The tank is euro braced, and I believe I am getting some shadowing around the sides being up that high.
Image

Posts: 81
Joined: Mon Aug 11, 2014 6:45 am
Location: Clermont, Florida
PostPosted: Mon Jul 18, 2016 11:34 am
Ok, I figured out the issue. Adjust the code you supplied a bit. First, I changed my offsets from 30 minutes down to 15 minutes, so ignore the changes in values in that respect, but, I needed to make some of the values negative.

Here is the modified section.
Code: Select all
ReefAngel.PWM.Channel0PWMParabola(0,-30);     // Actinic Left
ReefAngel.PWM.Channel2PWMParabola(15,-15);    // Actinic Center
ReefAngel.PWM.Channel4PWMParabola(30,0);     // Actinic Right

ReefAngel.PWM.Channel1PWMParabola(150,-180);  // Daylight Left
ReefAngel.PWM.Channel3PWMParabola(165,-165);  // Daylight Center     
ReefAngel.PWM.Channel5PWMParabola(180,-150);  // Daylight Right


I think this is now working as I intended. The other question that has me baffled is that overnight, the actinics set themselves all to 100%. Is this a function of the moonlights somehow? Where would that value have come from?
Image
User avatar
Posts: 5355
Joined: Fri Jul 20, 2012 9:42 am
PostPosted: Mon Jul 18, 2016 5:24 pm
Set them to 0 before your logic. Its taking a default somewhere. Sorry about the negatives.

Posts: 81
Joined: Mon Aug 11, 2014 6:45 am
Location: Clermont, Florida
PostPosted: Mon Jul 18, 2016 5:35 pm
Set them to 0 before your logic.


Not sure how/where to do this.

No worries on the negatives. I am still far ahead of where I would be without your assistance.
Image
User avatar
Posts: 5355
Joined: Fri Jul 20, 2012 9:42 am
PostPosted: Mon Jul 18, 2016 10:29 pm
ReefAngel.PWM.SetChannel(0,0);

First arg is channel. Do that for each before the calls to parabola.
User avatar
Posts: 5355
Joined: Fri Jul 20, 2012 9:42 am
PostPosted: Fri Aug 05, 2016 5:17 am
Bump, someone else was looking for the same code

Posts: 81
Joined: Mon Aug 11, 2014 6:45 am
Location: Clermont, Florida
PostPosted: Tue Sep 27, 2016 10:19 am
I am ready to work on my weather modes, but need a lot of help. I am currently using sunrise/sunset, and have not found where clouds and lightning have been incorporated with this, yet.

I also had 1 attempt at using a virtual port to perform a temporary override of the normal light schedule. But it did not work. I have that function commented out in my current code.

Here is my current code:

Code: Select all
#include <ReefAngel_Features.h>
#include <Globals.h>
#include <RA_Wifi.h>
#include <Wire.h>
#include <OneWire.h>
#include <Time.h>
#include <DS1307RTC.h>
#include <InternalEEPROM.h>
#include <RA_NokiaLCD.h>
#include <RA_ATO.h>
#include <RA_Joystick.h>
#include <LED.h>
#include <RA_TempSensor.h>
#include <Relay.h>
#include <RA_PWM.h>
#include <Timer.h>
#include <Memory.h>
#include <InternalEEPROM.h>
#include <RA_Colors.h>
#include <RA_CustomColors.h>
#include <Salinity.h>
#include <RF.h>
#include <IO.h>
#include <ORP.h>
#include <AI.h>
#include <PH.h>
#include <WaterLevel.h>
#include <Humidity.h>
#include <DCPump.h>
#include <PAR.h>
#include <ReefAngel.h>
#include <SunLocation.h>
#include <Tide.h>
#include <Moon.h>
#include <WiFiAlert.h>


////// Place global variable code below here
 
  SunLocation sl;
 
  int avgph[10];
    unsigned long totalavgph=0;
    byte avgindex=0;

void DrawCustomMain()
    {
      byte x;
      byte y = 2;
      char text[7];

      // *********** CHANGE TEMP READOUT COLOR DEPENDENT ON FAN AND HEATER STATUS ***********
      int TempColor;                                    // Color for drawing temperature
      boolean HeatOn = ReefAngel.Relay.Status(Port6);   // Get the status of the heater relay
      if (HeatOn)
      {
        TempColor = COLOR_NAVY;                         // Blue text, too cold, heater is on
      }

      if (!HeatOn)
      {
          TempColor = COLOR_GREEN;                      // Green text, no fan or heater on
      }
      // ***********************************************************************************
             int pHColor;                                 // Color for drawing pH
      boolean LowpH = (ReefAngel.Params.PH < 780) ;     // Check for Low pH Value
      boolean HighpH = (ReefAngel.Params.PH > 850);     // Check for High pH Value
      if (LowpH)
      {
        pHColor = COLOR_NAVY;                          // Blue text, Low pH value
      }
      if (HighpH)   
      {
        pHColor = COLOR_RED;                           // Red text, High pH value
      }
      if (!LowpH && !HighpH)
      {
        pHColor = COLOR_GREEN;                         // Green text, pH acceptable
      }
      // ***********************************************************************************
      ReefAngel.LCD.DrawLargeText(COLOR_DARKSLATEBLUE,DefaultBGColor, 6, 3, " Thunder Reef",Font8x8);   // Put a banner at the top
      ReefAngel.LCD.DrawDate(6, 119);                                                                   // Put the date and time at the bottom
      ReefAngel.LCD.Clear(COLOR_BLACK, 1, 12, 132, 12);                                                 // Draw a black line under the banner
      x = 6;
      y += MENU_START_ROW*1.4;                                                                          // MENU_START_ROW is 10, according to globals.h, so y=2+10+1=13
      ReefAngel.LCD.DrawLargeText(COLOR_BLUE, COLOR_WHITE, x, y+1, " Temp      pH");

      ConvertNumToString(text, ReefAngel.Params.Temp[T1_PROBE], 10);                                    // Get T1 temp and convert
      x = 2;
      y += MENU_START_ROW*1.6;
      ReefAngel.LCD.DrawHugeNumbers(COLOR_BLACK, TempColor, x, y, text);                                // Draw the temperature, white numbers on a colored background
      ConvertNumToString(text, ReefAngel.Params.PH, 100);                                               // Get pH reading and convert
      x = 2;
      y = MENU_START_ROW*2.6;
      ReefAngel.LCD.DrawHugeNumbers(COLOR_YELLOW, pHColor, x+65, y+6, text);                            // Put pH on the screen
     
      x += 6;
      y += MENU_START_ROW*3.3;
  ReefAngel.LCD.DrawLargeText(COLOR_INDIGO,DefaultBGColor,25,y,"Sump Level",Font8x8);      // Draw the Sump Float switch status
  if (ReefAngel.LowATO.IsActive())
  {ReefAngel.LCD.FillCircle(15,y+3,7,COLOR_RED);
  }
  else
  {
  ReefAngel.LCD.FillCircle(15,y+3,7,COLOR_GREEN);
  }
  x += 6;
  y += MENU_START_ROW*2.0;
  ReefAngel.LCD.DrawLargeText(COLOR_INDIGO,DefaultBGColor,25,y,"Skimmer Cup",Font8x8);     // Draw the Skimmer Cup Float switch status
  if (ReefAngel.HighATO.IsActive()) {ReefAngel.LCD.FillCircle(15,y+3,7,COLOR_GREEN);
  }
  else
  {
  ReefAngel.LCD.FillCircle(15,y+3,7,COLOR_RED);
  }
     
     
      byte TempRelay = ReefAngel.Relay.RelayData;                                          // Code for drawing the relay box
      TempRelay &= ReefAngel.Relay.RelayMaskOff;
      TempRelay |= ReefAngel.Relay.RelayMaskOn;
      ReefAngel.LCD.DrawOutletBox(12, 100, TempRelay);
   }
void DrawCustomGraph()
{
}



////// Place global variable code above here


void setup()
{
    // This must be the first line
    ReefAngel.Init();                                                                        //Initialize controller
    ReefAngel.Use2014Screen();                                                               // Let's use 2014 Screen
    ReefAngel.FeedingModePorts = Port7Bit;                                                   // Ports toggled in Feeding Mode
    ReefAngel.WaterChangePorts = Port1Bit | Port6Bit | Port7Bit | Port8Bit;                  // Ports toggled in Water Change Mode
    ReefAngel.LightsOnPorts = Port2Bit | Port3Bit | Port4Bit;                                // Ports toggled when Lights On / Off menu entry selected
    ReefAngel.OverheatShutoffPorts = Port2Bit | Port3Bit | Port4Bit | Port6Bit | Port7Bit;   // Ports turned off when Overheat temperature exceeded
    ReefAngel.TempProbe = T1_PROBE;                                                          // Use T1 probe as temperature and overheat functions
    ReefAngel.OverheatProbe = T1_PROBE;
    InternalMemory.OverheatTemp_write( 820 );                                                // Set the Overheat temperature setting


    // Ports that are always on
    ReefAngel.Relay.On( Port1 );
    ReefAngel.Relay.On( Port5 );
   
    // Virtual Ports that are always off
    ReefAngel.Relay.Off( Box1_Port1);
    ReefAngel.Relay.Off( Box1_Port2);
    ReefAngel.Relay.Off( Box1_Port3);
    ReefAngel.Relay.Off( Box1_Port4);
    ReefAngel.Relay.Off( Box1_Port5);
    ReefAngel.Relay.Off( Box1_Port6);
    ReefAngel.Relay.Off( Box1_Port7);
    ReefAngel.Relay.Off( Box1_Port8);
   
   
    // Delayed start for skimmer to allow sump level to return to normal after water change
    ReefAngel.Relay.DelayedOn( Port7,4 );

    ////// Place additional initialization code below here
   
    sl.Init(28.5700, -81.6800);    // Lat/long for Clermont, FL
    sl.SetOffset(-2,0,-2,0);       // rise_hour, rise_seconds, set_hour, set_seconds (set 2 hrs later for better viewing time (-4 offset = actual time))

    randomSeed(now()%SECS_PER_DAY);
     
      //Custom Variable [0] =  Month/Season
   
    ReefAngel.CustomLabels[0]="Return"; 
    ReefAngel.CustomLabels[1]="Daylights"; 
    ReefAngel.CustomLabels[2]="Actinics"; 
    ReefAngel.CustomLabels[3]="Fuge Light"; 
    ReefAngel.CustomLabels[4]="Dosing Pumps"; 
    ReefAngel.CustomLabels[5]="Heater"; 
    ReefAngel.CustomLabels[6]="Skimmer"; 
    ReefAngel.CustomLabels[7]="ATO RoDi"; 

    // Virtual Ports reserved for custom lighting functions and effects

    ReefAngel.CustomLabels[8]="Lights 60/40"; 
    ReefAngel.CustomLabels[9]="Not Used"; 
    ReefAngel.CustomLabels[10]="Not Used"; 
    ReefAngel.CustomLabels[11]="Not Used"; 
    ReefAngel.CustomLabels[12]="Weather"; 
    ReefAngel.CustomLabels[13]="Weather"; 
    ReefAngel.CustomLabels[14]="Weather"; 
    ReefAngel.CustomLabels[15]="Weather"; 


    ////// Place additional initialization code above here
}

void loop()
{
 

    // seasonal temperatures
    SeasonalTemps();

// Lights on Dimming Expansion. (Left=East, Right=West)

ReefAngel.PWM.Channel0PWMParabola(0,-30);     // Actinic Left     - Starts at Sunrise, ends 30 minutes before Sunset
ReefAngel.PWM.Channel2PWMParabola(-15,-15);   // Actinic Center   - Starts 15 minute after Sunrise,  ends 15 minutes before Sunset
ReefAngel.PWM.Channel4PWMParabola(-30,0);     // Actinic Right    - Starts 30 minutes after Sunrise, ends at Sunset

ReefAngel.PWM.Channel1PWMParabola(-90,-120);  // Daylight Left   - Starts 90 minutes after Sunrise, ends 120 minutes before Sunset
ReefAngel.PWM.Channel3PWMParabola(-105,-105);  // Daylight Center - Starts 105 minutes after Sunrise, ends 105 minutes before Sunset
ReefAngel.PWM.Channel5PWMParabola(-120,-90);  // Daylight Right  - Starts 120 minutes after Sunrise, ends 90 minutes before Sunset

// Turn Actinic outlet on if any % is >= 2
(ReefAngel.PWM.GetChannelValue(0)>=2 || ReefAngel.PWM.GetChannelValue(2)>=2 || ReefAngel.PWM.GetChannelValue(4)>=2) ?  ReefAngel.Relay.On( Port3 ) :  ReefAngel.Relay.Off( Port3 );

// Turn Daylight outlet on if any % is >=2   
(ReefAngel.PWM.GetChannelValue(1)>=2 || ReefAngel.PWM.GetChannelValue(3)>=2 || ReefAngel.PWM.GetChannelValue(5)>=2) ?  ReefAngel.Relay.On( Port2 ) : ReefAngel.Relay.Off( Port2 );

ReefAngel.Relay.Set(Port4, !ReefAngel.Relay.Status(Port2));  // Refugium light.  Opposite Whites.

   
   
// Virtual Port Functions

//if (ReefAngel.Relay.Status( Box1_Port1 )); // Set Lights 60/40
//{
//ReefAngel.PWM.SetChannel(0,60);  // Actinic Left
//ReefAngel.PWM.SetChannel(2,60);  // Actinic Center
//ReefAngel.PWM.SetChannel(4,60);  // Actinic Right

//ReefAngel.PWM.SetChannel(1,40);  // Daylight Left
//ReefAngel.PWM.SetChannel(3,40);  // Daylight Center
//ReefAngel.PWM.SetChannel(5,40);  // Daylight Right
//}
 
   
   
    ////// Place your custom code below here



// WP-25 powerheads schedule   
if (hour()>=9 && hour()<13)
{
 ReefAngel.PWM.SetDaylight( ReefCrestMode(55,15,true) ); // reefcrest at 55% +/- 15% on sync mode       (Day Mode)
 ReefAngel.PWM.SetActinic( ReefCrestMode(55,15,false) ); // reefcrest at 55% +/- 15% on Anti-sync mode  (Day mode)
}
else if (hour()>=13 && hour()<18)
{
 ReefAngel.PWM.SetDaylight( ShortPulseMode(1,75,408,true) ); // Short pulse at 75% with 408ms pulse on sync mode (3/4" surface wave)
 ReefAngel.PWM.SetActinic( ShortPulseMode(1,75,408,false) ); // Short pulse at 75% with 408ms pulse on Anti-sync mode (3/4" surface wave)
}
else if (hour()>=18 && hour()<19)
{
 ReefAngel.PWM.SetDaylight( LongPulseMode(35,80,2,true) ); // Long Pulse 35% ramping up to 80% for 2 seconds on sync mode (nutrient transport)
 ReefAngel.PWM.SetActinic( LongPulseMode(35,80,2,false) ); // Long Pulse 35% ramping up to 80% for 2 seconds on Anti-sync mode  (nutrient transport)
}
else if (hour()>=19 && hour()<20)
{
 ReefAngel.PWM.SetDaylight( ReefCrestMode(55,15,true) ); // reefcrest at 55% +/- 15% on sync mode       (Day Mode)
 ReefAngel.PWM.SetActinic( ReefCrestMode(55,15,false) ); // reefcrest at 55% +/- 15% on Anti-sync mode  (Day mode)
}
else
{
 ReefAngel.PWM.SetDaylight( ReefCrestMode(50,10,true) ); // reefcrest at 50% +/- 10% on sync mode       (night Mode)
 ReefAngel.PWM.SetActinic( ReefCrestMode(50,10,false) ); // reefcrest at 50% +/- 10% on Anti-sync mode  (night mode)
}
 
if( ReefAngel.DisplayedMenu==FEEDING_MODE )
{
 ReefAngel.PWM.SetActinic( LongPulseMode(1,40,1,true) );
 ReefAngel.PWM.SetDaylight( LongPulseMode(1,40,1,true) );
}

if( ReefAngel.DisplayedMenu==WATERCHANGE_MODE )
{
 ReefAngel.PWM.SetActinic(35);
 ReefAngel.PWM.SetDaylight(35);
}

// enter feeding mode at 11am & 5pm
 if ( (hour()==11 && minute()==0 && second()==0))
 {
 ReefAngel.FeedingModeStart(); // turn on feeding mode
 }
  if ( (hour()==17 && minute()==0 && second()==0))
 {
 ReefAngel.FeedingModeStart(); // turn on feeding mode
 }
 
 
if(ReefAngel.HighATO.IsActive())           //  Float switch in Skimmer Locker
{
ReefAngel.Relay.DelayedOn( Port7,4 );
}
 else
{
 ReefAngel.Relay.Off(Port7);               //  Turn off Skimmer when locker full.
}
 

// ATO, Port 8 is ATO using Clear RoDi

 ReefAngel.SingleATO(true,Port8,400,0);   //  Sump switch.  If ATO/RoDi runs for 400 seconds, then shut off and send alert.

 
  {
    sl.CheckAndUpdate();  // handle updating sunrise and sunset values
  }
 
    ////// Place your custom code above here

    // This should always be the last line
    ReefAngel.Portal( "DmnYnkee" );
    ReefAngel.ShowInterface();
}

 void SeasonalTemps ()
 {
  static int heatArray[][2] = { {786,790},                  // default in case of error in month=0 (June)
                    {774,778},//January (winter)            // 77.6
                    {776,780},//February (winter)           // 77.8
                    {778,782},//March (early spring)        // 78.0
                    {780,784},//April (spring)              // 78.2
                    {782,786},//May (spring)                // 78.4
                    {786,790},//June (early summer)         // 78.8
                    {790,794},//July (summer)               // 79.2
                    {794,798},//August (summer)             // 79.6
                    {790,794},//September (early fall)      // 79.2
                    {786,790},//October (fall)              // 78.8
                    {782,786},//November (fall)             // 78.4
                    {778,782} };//December (early winter)   // 78.0
                   
               
  ReefAngel.StandardHeater( Port6,heatArray[month()][0],heatArray[month()][1]);
 }//end seasonalTemps
Image

Posts: 81
Joined: Mon Aug 11, 2014 6:45 am
Location: Clermont, Florida
PostPosted: Sun Oct 16, 2016 2:13 pm
Lee, and Colin, or anyone else that may want to chime in.

I have this breathing now, and have it close to where I want it.

I no longer have my lights working with sunset/sunrise, but would like to incorporate this back in at some point. I also no longer can adjust light percentages through the portal, and I really liked having that ability.

Issues that I would like to fix at this point are:

1.) I want to raise my actinics up about 20% as a cloud starts dimming the whites. (I think Lee did some work on this)

2.) I need the whites to go no lower than 2% for the duration of the cloud and/or lightning. I have tried several different ways to accomplish this, and none of them have worked, as they still went to 0.

3.) I would like the clouds to dim from left to right (maybe a 10-20 second delay to each channel), and right now, all 3 dim at the same time.

4.) Break the 3 channels out during "Mega", similar to how I have "Slow" set up now. (borrowed this from Lee to get to this point)

5.) I would like to add a basic "storm mode" for my wave makers. Just a higher than normal % short pulse mode that reverts back at end of cloud. These are on my standard actinic/daylight dimming channels.

Here is where my code is now:
Code: Select all
#include <ReefAngel_Features.h>
#include <Globals.h>
#include <RA_Wifi.h>
#include <Wire.h>
#include <OneWire.h>
#include <Time.h>
#include <DS1307RTC.h>
#include <InternalEEPROM.h>
#include <RA_NokiaLCD.h>
#include <RA_ATO.h>
#include <RA_Joystick.h>
#include <LED.h>
#include <RA_TempSensor.h>
#include <Relay.h>
#include <RA_PWM.h>
#include <Timer.h>
#include <Memory.h>
#include <InternalEEPROM.h>
#include <RA_Colors.h>
#include <RA_CustomColors.h>
#include <Salinity.h>
#include <RF.h>
#include <IO.h>
#include <ORP.h>
#include <AI.h>
#include <PH.h>
#include <WaterLevel.h>
#include <Humidity.h>
#include <DCPump.h>
#include <PAR.h>
#include <ReefAngel.h>
#include <SunLocation.h>
#include <Tide.h>
#include <Moon.h>
#include <WiFiAlert.h>


////// Place global variable code below here
 
  SunLocation sl;
 
  int avgph[10];
    unsigned long totalavgph=0;
    byte avgindex=0;

void DrawCustomMain()
    {
      byte x;
      byte y = 2;
      char text[7];

      // *********** CHANGE TEMP READOUT COLOR DEPENDENT ON FAN AND HEATER STATUS ***********
      int TempColor;                                    // Color for drawing temperature
      boolean HeatOn = ReefAngel.Relay.Status(Port6);   // Get the status of the heater relay
      if (HeatOn)
      {
        TempColor = COLOR_NAVY;                         // Blue text, too cold, heater is on
      }

      if (!HeatOn)
      {
          TempColor = COLOR_GREEN;                      // Green text, no fan or heater on
      }
      // ***********************************************************************************
             int pHColor;                                 // Color for drawing pH
      boolean LowpH = (ReefAngel.Params.PH < 780) ;     // Check for Low pH Value
      boolean HighpH = (ReefAngel.Params.PH > 850);     // Check for High pH Value
      if (LowpH)
      {
        pHColor = COLOR_NAVY;                          // Blue text, Low pH value
      }
      if (HighpH)   
      {
        pHColor = COLOR_RED;                           // Red text, High pH value
      }
      if (!LowpH && !HighpH)
      {
        pHColor = COLOR_GREEN;                         // Green text, pH acceptable
      }
      // ***********************************************************************************
      ReefAngel.LCD.DrawLargeText(COLOR_DARKSLATEBLUE,DefaultBGColor, 6, 3, " Thunder Reef",Font8x8);   // Put a banner at the top
      ReefAngel.LCD.DrawDate(6, 119);                                                                   // Put the date and time at the bottom
      ReefAngel.LCD.Clear(COLOR_BLACK, 1, 12, 132, 12);                                                 // Draw a black line under the banner
      x = 6;
      y += MENU_START_ROW*1.4;                                                                          // MENU_START_ROW is 10, according to globals.h, so y=2+10+1=13
      ReefAngel.LCD.DrawLargeText(COLOR_BLUE, COLOR_WHITE, x, y+1, " Temp      pH");

      ConvertNumToString(text, ReefAngel.Params.Temp[T1_PROBE], 10);                                    // Get T1 temp and convert
      x = 2;
      y += MENU_START_ROW*1.6;
      ReefAngel.LCD.DrawHugeNumbers(COLOR_BLACK, TempColor, x, y, text);                                // Draw the temperature, white numbers on a colored background
      ConvertNumToString(text, ReefAngel.Params.PH, 100);                                               // Get pH reading and convert
      x = 2;
      y = MENU_START_ROW*2.6;
      ReefAngel.LCD.DrawHugeNumbers(COLOR_YELLOW, pHColor, x+65, y+6, text);                            // Put pH on the screen
     
      x += 6;
      y += MENU_START_ROW*3.3;
  ReefAngel.LCD.DrawLargeText(COLOR_INDIGO,DefaultBGColor,25,y,"Sump Level",Font8x8);      // Draw the Sump Float switch status
  if (ReefAngel.LowATO.IsActive())
  {ReefAngel.LCD.FillCircle(15,y+3,7,COLOR_RED);
  }
  else
  {
  ReefAngel.LCD.FillCircle(15,y+3,7,COLOR_GREEN);
  }
  x += 6;
  y += MENU_START_ROW*2.0;
  ReefAngel.LCD.DrawLargeText(COLOR_INDIGO,DefaultBGColor,25,y,"Skimmer Cup",Font8x8);     // Draw the Skimmer Cup Float switch status
  if (ReefAngel.HighATO.IsActive()) {ReefAngel.LCD.FillCircle(15,y+3,7,COLOR_GREEN);
  }
  else
  {
  ReefAngel.LCD.FillCircle(15,y+3,7,COLOR_RED);
  }
     
     
      byte TempRelay = ReefAngel.Relay.RelayData;                                          // Code for drawing the relay box
      TempRelay &= ReefAngel.Relay.RelayMaskOff;
      TempRelay |= ReefAngel.Relay.RelayMaskOn;
      ReefAngel.LCD.DrawOutletBox(12, 100, TempRelay);
   }
void DrawCustomGraph()
{
}

int DaylightPWMValue1=0;        // For cloud code, channel 1
int DaylightPWMValue3=0;        // For cloud code, chennel 3
int DaylightPWMValue5=0;        // For cloud code, chennel 5

////// Place global variable code above here


void setup()
{
    // This must be the first line
    ReefAngel.Init();                                                                        //Initialize controller
    ReefAngel.Use2014Screen();                                                               // Let's use 2014 Screen
    ReefAngel.FeedingModePorts = Port7Bit;                                                   // Ports toggled in Feeding Mode
    ReefAngel.WaterChangePorts = Port1Bit | Port6Bit | Port7Bit | Port8Bit;                  // Ports toggled in Water Change Mode
    ReefAngel.LightsOnPorts = Port2Bit | Port3Bit | Port4Bit;                                // Ports toggled when Lights On / Off menu entry selected
    ReefAngel.OverheatShutoffPorts = Port2Bit | Port3Bit | Port4Bit | Port6Bit | Port7Bit;   // Ports turned off when Overheat temperature exceeded
    ReefAngel.TempProbe = T1_PROBE;                                                          // Use T1 probe as temperature and overheat functions
    ReefAngel.OverheatProbe = T1_PROBE;
    InternalMemory.OverheatTemp_write( 820 );                                                // Set the Overheat temperature setting


    // Ports that are always on
    ReefAngel.Relay.On( Port1 );
    ReefAngel.Relay.On( Port5 );
   
    // Virtual Ports that are always off
    ReefAngel.Relay.Off( Box1_Port1);
    ReefAngel.Relay.Off( Box1_Port2);
    ReefAngel.Relay.Off( Box1_Port3);
    ReefAngel.Relay.Off( Box1_Port4);
    ReefAngel.Relay.Off( Box1_Port5);
    ReefAngel.Relay.Off( Box1_Port6);
    ReefAngel.Relay.Off( Box1_Port7);
    ReefAngel.Relay.Off( Box1_Port8);
   
   
    // Delayed start for skimmer to allow sump level to return to normal after water change
    ReefAngel.Relay.DelayedOn( Port7,4 );

    ////// Place additional initialization code below here
   
    sl.Init(28.5700, -81.6800);    // Lat/long for Clermont, FL
    sl.SetOffset(-2,0,-2,0);       // rise_hour, rise_seconds, set_hour, set_seconds (set 2 hrs later for better viewing time (-4 offset = actual time))

    randomSeed(now()%SECS_PER_DAY);
     
      //Custom Variable [0] =  Month/Season
   
    ReefAngel.CustomLabels[0]="Return"; 
    ReefAngel.CustomLabels[1]="Daylights"; 
    ReefAngel.CustomLabels[2]="Actinics"; 
    ReefAngel.CustomLabels[3]="Fuge Light"; 
    ReefAngel.CustomLabels[4]="Dosing Pumps"; 
    ReefAngel.CustomLabels[5]="Heater"; 
    ReefAngel.CustomLabels[6]="Skimmer"; 
    ReefAngel.CustomLabels[7]="ATO RoDi"; 

    // Virtual Ports reserved for custom lighting functions and effects

    ReefAngel.CustomLabels[8]="Lights:  B60/W40"; 
    ReefAngel.CustomLabels[9]="Lighta: Whites 40"; 
    ReefAngel.CustomLabels[10]="Lights: Blues 60"; 
    ReefAngel.CustomLabels[11]="Not Used"; 
    ReefAngel.CustomLabels[12]="Storm"; 
    ReefAngel.CustomLabels[13]="Weather"; 
    ReefAngel.CustomLabels[14]="Weather"; 
    ReefAngel.CustomLabels[15]="Weather"; 


    ////// Place additional initialization code above here
}

void loop()
{
 

    // seasonal temperatures
    SeasonalTemps();

// Lights on Dimming Expansion. (Left=East, Center=Center, Right=West)

//if (ReefAngel.Relay.Status( Box1_Port1 )); // Set Lights 60/40
//{
//ReefAngel.PWM.SetChannel(0,60);  // Actinic Left
//ReefAngel.PWM.SetChannel(2,60);  // Actinic Center
//ReefAngel.PWM.SetChannel(4,60);  // Actinic Right
//ReefAngel.PWM.SetChannel(1,40);  // Daylight Left
//ReefAngel.PWM.SetChannel(3,40);  // Daylight Center
//ReefAngel.PWM.SetChannel(5,40);  // Daylight Right
//}

// Default lighting program

ReefAngel.PWM.SetChannelRaw( 0, PWMSlopeHighRes(9,30,21,30,1,65,120,0) );  // Schedule for blues
ReefAngel.PWM.SetChannelRaw( 2, PWMSlopeHighRes(9,45,21,45,1,65,120,0) );
ReefAngel.PWM.SetChannelRaw( 4, PWMSlopeHighRes(10,00,22,0,1,65,120,0) );

DaylightPWMValue1=PWMSlopeHighRes(10,30,20,30,1,25,90,0);    //  Default for whites
DaylightPWMValue3=PWMSlopeHighRes(10,45,20,45,1,25,90,0);
DaylightPWMValue5=PWMSlopeHighRes(11,00,21,0,1,25,90,0);

CheckCloud();    //  Check for cloud and slow lightning.
ReefAngel.PWM.SetChannelRaw(1,DaylightPWMValue1);  //  Write values for either default or cloud/slow
ReefAngel.PWM.SetChannelRaw(3,DaylightPWMValue3);  //  lightning if it's time.
ReefAngel.PWM.SetChannelRaw(5,DaylightPWMValue5);  //  lightning if it's time.

// Turn Actinic outlet on if any % is >= 2
(ReefAngel.PWM.GetChannelValue(0)>=2 || ReefAngel.PWM.GetChannelValue(2)>=2 || ReefAngel.PWM.GetChannelValue(4)>=2) ?  ReefAngel.Relay.On( Port3 ) :  ReefAngel.Relay.Off( Port3 );

// Turn Daylight outlet on if any % is >=2   
(ReefAngel.PWM.GetChannelValue(1)>=2 || ReefAngel.PWM.GetChannelValue(3)>=2 || ReefAngel.PWM.GetChannelValue(5)>=2) ?  ReefAngel.Relay.On( Port2 ) : ReefAngel.Relay.Off( Port2 );

   
////// Place your custom code below here



// WP-25 powerheads schedule   
if (hour()>=9 && hour()<13)
{
 ReefAngel.PWM.SetDaylight( ReefCrestMode(55,15,true) ); // reefcrest at 55% +/- 15% on sync mode       (Day Mode)
 ReefAngel.PWM.SetActinic( ReefCrestMode(55,15,false) ); // reefcrest at 55% +/- 15% on Anti-sync mode  (Day mode)
}
else if (hour()>=13 && hour()<18)
{
 byte random_speed=60;
 if (now()%5==1) random_speed=random(58,78);
 ReefAngel.PWM.SetDaylight( ShortPulseMode(1,random_speed,408,true) ); // Short pulse at 58%-78% with 408ms pulse on sync mode (surface wave)
 ReefAngel.PWM.SetActinic( ShortPulseMode(1,random_speed,408,false) ); // Short pulse at 58%-78%% with 408ms pulse on Anti-sync mode (surface wave)
}
else if (hour()>=18 && hour()<19)
{
 byte random_speed=65;
 if (now()%5==1) random_speed=random(65,80);
 byte random_duration=2;
 if (now()%5==1) random_duration=random(2,5);
 ReefAngel.PWM.SetDaylight( LongPulseMode(35,random_speed,random_duration,true) ); // Long Pulse 35% ramping up to 65%-80% for 2-5 seconds on sync mode (nutrient transport)
 ReefAngel.PWM.SetActinic( LongPulseMode(35,random_speed,random_duration,false) ); // Long Pulse 35% ramping up to 65%-80% for 2-5 seconds on Anti-sync mode  (nutrient transport)
}
else if (hour()>=19 && hour()<20)
{
 ReefAngel.PWM.SetDaylight( ReefCrestMode(55,15,true) ); // reefcrest at 55% +/- 15% on sync mode       (Day Mode)
 ReefAngel.PWM.SetActinic( ReefCrestMode(55,15,false) ); // reefcrest at 55% +/- 15% on Anti-sync mode  (Day mode)
}
else
{
 ReefAngel.PWM.SetDaylight( ReefCrestMode(50,10,true) ); // reefcrest at 50% +/- 10% on sync mode       (night Mode)
 ReefAngel.PWM.SetActinic( ReefCrestMode(50,10,false) ); // reefcrest at 50% +/- 10% on Anti-sync mode  (night mode)
}
 
if( ReefAngel.DisplayedMenu==FEEDING_MODE )
{
 ReefAngel.PWM.SetActinic(1);
 ReefAngel.PWM.SetDaylight(1);
}

if( ReefAngel.DisplayedMenu==WATERCHANGE_MODE )
{
 ReefAngel.PWM.SetActinic(35);
 ReefAngel.PWM.SetDaylight(35);
}

// enter feeding mode at 5:30pm
if ( (hour()==17 && minute()==30 && second()==0))
 {
 ReefAngel.FeedingModeStart(); // turn on feeding mode
 }
 
 
if(ReefAngel.HighATO.IsActive())           //  Float switch in Skimmer Locker
{
ReefAngel.Relay.DelayedOn( Port7,4 );
}
 else
{
 ReefAngel.Relay.Off(Port7);               //  Turn off Skimmer when locker full.
}
 

// ATO, Port 8 is ATO using Clear RoDi

 ReefAngel.SingleATO(true,Port8,400,0);   //  Sump switch.  If ATO/RoDi runs for 400 seconds, then shut off and send alert.

 
  {
    sl.CheckAndUpdate();  // handle updating sunrise and sunset values
  }
 
    ////// Place your custom code above here

    // This should always be the last line
    ReefAngel.Portal( "DmnYnkee" );
    ReefAngel.ShowInterface();
}

 void SeasonalTemps ()
 {
  static int heatArray[][2] = { {786,790},                  // default in case of error in month=0 (June)
                    {774,778},//January (winter)            // 77.6
                    {776,780},//February (winter)           // 77.8
                    {778,782},//March (early spring)        // 78.0
                    {780,784},//April (spring)              // 78.2
                    {782,786},//May (spring)                // 78.4
                    {786,790},//June (early summer)         // 78.8
                    {790,794},//July (summer)               // 79.2
                    {794,798},//August (summer)             // 79.6
                    {790,794},//September (early fall)      // 79.2
                    {786,790},//October (fall)              // 78.8
                    {782,786},//November (fall)             // 78.4
                    {778,782} };//December (early winter)   // 78.0
                   
               
  ReefAngel.StandardHeater( Port6,heatArray[month()][0],heatArray[month()][1]);
 }//end seasonalTemps
 
 // ------------------------------------------------------------
// Do not change anything below here

static byte cloudchance=255;
static byte cloudduration=0;
static int cloudstart=0;
static byte numclouds=0;
static byte lightningchance=0;
static byte cloudindex=0;
static byte lightningstatus=0;
static byte lightningMode=0;
static boolean chooseLightning=true;

void CheckCloud()
{

  // ------------------------------------------------------------
  // Change the values below to customize your cloud/storm effect

  // Frequency in days based on the day of the month - number 2 means every 2 days, for example (day 2,4,6 etc)
  // For testing purposes, you can use 1 and cause the cloud to occur everyday
#define Clouds_Every_X_Days 1

  // Percentage chance of a cloud happening today
  // For testing purposes, you can use 100 and cause the cloud to have 100% chance of happening
#define Cloud_Chance_per_Day 100

  // Minimum number of minutes for cloud duration.  Don't use min duration of less than 6
#define Min_Cloud_Duration 6

  // Maximum number of minutes for the cloud duration. Don't use max duration of more than 255
#define Max_Cloud_Duration 12

  // Minimum number of clouds that can happen per day
#define Min_Clouds_per_Day 1

  // Maximum number of clouds that can happen per day
#define Max_Clouds_per_Day 4

  // Only start the cloud effect after this setting
  // In this example, start cloud after noon
#define Start_Cloud_After NumMins(12,00)

  // Always end the cloud effect before this setting
  // In this example, end cloud before 9:00pm
#define End_Cloud_Before NumMins(21,00)

  // Percentage chance of a lightning happen for every cloud
  // For testing purposes, you can use 100 and cause the lightning to have 100% chance of happening
#define Lightning_Change_per_Cloud 100

  // Note: Make sure to choose correct values that will work within your PWMSLope settings.
  // For example, in our case, we could have a max of 5 clouds per day and they could last for 50 minutes.
  // Which could mean 250 minutes of clouds. We need to make sure the PWMSlope can accomodate 250 minutes
  // of effects or unforseen result could happen.
  // Also, make sure that you can fit double those minutes between Start_Cloud_After and End_Cloud_Before.
  // In our example, we have 510 minutes between Start_Cloud_After and End_Cloud_Before, so double the
  // 250 minutes (or 500 minutes) can fit in that 510 minutes window.
  // It's a tight fit, but it did.

  //#define printdebug // Uncomment this for debug print on Serial Monitor window
#define forcecloudcalculation // Uncomment this to force the cloud calculation to happen in the boot process.

  // Add Random Lightning modes
#define Calm 0    // No lightning
#define Slow 1    // 5 seconds of slow lightning in the middle of a cloud for ELN style (slow response) drivers
#define Fast 2    // 5 seconds of fast lightning in the middle of a cloud for LDD style (fast response) drivers
#define Mega 3    // Lightning throughout the cloud, higher chance as it gets darker
#define Mega2 4   // Like Mega, but with more lightning
  // Set which modes you want to use
  // Example:  { Calm, Fast, Mega, Mega2 } to randomize all four modes. 
  // { Mega2 } for just Mega2.  { Mega, Mega, Fast} for Mega and Fast, with twice the chance of Mega.
  byte LightningModes[] = { Calm, Slow, Mega, Mega };

  // Change the values above to customize your cloud/storm effect

  static time_t DelayCounter=millis();    // Variable for lightning timing. 
  static int DelayTime=random(1000);      // Variable for lightning timimg.

  // Every day at midnight, we check for chance of cloud happening today
  if (hour()==0 && minute()==0 && second()==0) cloudchance=255;

#ifdef forcecloudcalculation
  if (cloudchance==255)
#else
    if (hour()==0 && minute()==0 && second()==1 && cloudchance==255)
#endif
    {
      randomSeed(millis());    // Seed the random number generator
      //Pick a random number between 0 and 99
      cloudchance=random(100);
      // if picked number is greater than Cloud_Chance_per_Day, we will not have clouds today
      if (cloudchance>Cloud_Chance_per_Day) cloudchance=0;
      // Check if today is day for clouds.
      if ((day()%Clouds_Every_X_Days)!=0) cloudchance=0;
      // If we have cloud today
      if (cloudchance)
      {
        // pick a random number for number of clouds between Min_Clouds_per_Day and Max_Clouds_per_Day
        numclouds=random(Min_Clouds_per_Day,Max_Clouds_per_Day);
        // pick the time that the first cloud will start
        // the range is calculated between Start_Cloud_After and the even distribuition of clouds on this day.
        cloudstart=random(Start_Cloud_After,Start_Cloud_After+((End_Cloud_Before-Start_Cloud_After)/(numclouds*2)));
        // pick a random number for the cloud duration of first cloud.
        cloudduration=random(Min_Cloud_Duration,Max_Cloud_Duration);
        //Pick a random number between 0 and 99
        lightningchance=random(100);
        // if picked number is greater than Lightning_Change_per_Cloud, we will not have lightning today
        if (lightningchance>Lightning_Change_per_Cloud) lightningchance=0;
      }
    }
  // Now that we have all the parameters for the cloud, let's create the effect


  if (cloudchance)
  {
    if (ReefAngel.Relay.isMaskOn(Box1_Port5))      // Change this to whatever port you want to use as a trigger.
    {
      cloudstart = NumMins(hour(), minute());
      ReefAngel.Relay.Auto(Box1_Port5);    // Here, too.
    }
    //is it time for cloud yet?
    if (NumMins(hour(),minute())>=cloudstart && NumMins(hour(),minute())<(cloudstart+cloudduration))
    {
      // Increase Blue channel first for better effect and to compensate for drop in Whites
      //ActinicPWMValue1=ReversePWMSlopeHighRes(cloudstart,cloudstart+cloudduration,ActinicPWMValue1,ActinicPWMValue1+DaylightPWMValue0,180);
      //ActinicPWMValue3=ReversePWMSlopeHighRes(cloudstart,cloudstart+cloudduration,ActinicPWMValue3,ActinicPWMValue3+DaylightPWMValue2,180);
      //ActinicPWMValue3=ReversePWMSlopeHighRes(cloudstart,cloudstart+cloudduration,ActinicPWMValue3,ActinicPWMValue3+DaylightPWMValue4,180);
     
      DaylightPWMValue1=ReversePWMSlope(cloudstart,cloudstart+cloudduration,DaylightPWMValue1,2,150);
      DaylightPWMValue3=ReversePWMSlope(cloudstart,cloudstart+cloudduration,DaylightPWMValue3,2,150);
      DaylightPWMValue5=ReversePWMSlope(cloudstart,cloudstart+cloudduration,DaylightPWMValue5,2,150);
     

      if (chooseLightning)
      {
        lightningMode=LightningModes[random(100)%sizeof(LightningModes)];
        chooseLightning=false;
      }
      switch (lightningMode)
      {
      case Calm:
        break;
      case Mega:
        // Lightning chance from beginning of cloud through the end.  Chance increases with darkness of cloud.
        if (lightningchance && random(ReversePWMSlope(cloudstart,cloudstart+cloudduration,100,2,150))<1 && (millis()-DelayCounter)>DelayTime)
        {
          // Send the trigger
          Strike();
          DelayCounter=millis();    // If we just had a round of flashes, then lets put in a longer delay
          DelayTime=random(1000);   // of up to a second for dramatic effect before we do another round.
        }
        break;
      case Mega2:
        // Higher lightning chance from beginning of cloud through the end.  Chance increases with darkness of cloud.
        if (lightningchance && random(ReversePWMSlope(cloudstart,cloudstart+cloudduration,100,2,150))<2)
        {
          Strike();
        }
        break;
      case Fast:
        // 5 seconds of lightning in the middle of the cloud
        if (lightningchance && (NumMins(hour(),minute())==(cloudstart+(cloudduration/2))) && second()<5 && (millis()-DelayCounter)>DelayTime)
        {
          Strike();

          DelayCounter=millis();    // If we just had a round of flashes, then lets put in a longer delay
          DelayTime=random(1000);   // of up to a second for dramatic effect before we do another round.
        }
        break;
      case Slow:
        // Slow lightning for 5 seconds in the middle of the cloud.  Suitable for slower ELN style drivers
        if (lightningchance && (NumMins(hour(),minute())>=(cloudstart+(cloudduration/3))) && second()<10)
        {
          SlowStrike();
        }
        break;
      default:
        break;
      }
    }
    else
    {
      chooseLightning=true; // Reset the flag to choose a new lightning type
    }

    if (NumMins(hour(),minute())>(cloudstart+cloudduration))
    {
      cloudindex++;
      if (cloudindex < numclouds)
      {
        cloudstart=random(Start_Cloud_After+(((End_Cloud_Before-Start_Cloud_After)/(numclouds*2))*cloudindex*2),(Start_Cloud_After+(((End_Cloud_Before-Start_Cloud_After)/(numclouds*2))*cloudindex*2))+((End_Cloud_Before-Start_Cloud_After)/(numclouds*2)));
        // pick a random number for the cloud duration of first cloud.
        cloudduration=random(Min_Cloud_Duration,Max_Cloud_Duration);
        //Pick a random number between 0 and 99
        lightningchance=random(100);
        // if picked number is greater than Lightning_Change_per_Cloud, we will not have lightning today
        if (lightningchance>Lightning_Change_per_Cloud) lightningchance=0;
      }
    } 
  }
 
  // Cloud ON option - Clouds every minute
  if (ReefAngel.Relay.isMaskOff(Box1_Port5) && now()%60<10)
  {
    SlowStrike();
  }
}

void SlowStrike()

{
    int r = random(80);
    if (r<20) lightningstatus=1;
    else lightningstatus=0;
    if (lightningstatus)
    {
      // Let's separate left, center, right, or All.
      if (r<10  ) {               // All 3
        DaylightPWMValue1=4095;
        DaylightPWMValue3=4095;
        DaylightPWMValue5=4095;
      } else if (r<12) {          // Left only
        DaylightPWMValue1=4095;
        DaylightPWMValue3=100;
        DaylightPWMValue5=100;
      } else if (r<14) {          // Center only
        DaylightPWMValue1=100;
        DaylightPWMValue3=4095;
        DaylightPWMValue5=100;
      } else if (r<16) {          // Right only
        DaylightPWMValue1=100;
        DaylightPWMValue3=100;
        DaylightPWMValue5=4095;
      } else if (r<18) {          // Left & Center only
        DaylightPWMValue1=4095;
        DaylightPWMValue3=4095;
        DaylightPWMValue5=100;
      } else {                    // Center & Right only
        DaylightPWMValue1=100;
        DaylightPWMValue3=4095;
        DaylightPWMValue5=4095;
      }
    }
    else
    {
      DaylightPWMValue1=100;
      DaylightPWMValue3=100;
      DaylightPWMValue5=100;
    }
    delay(1);


void DrawClouds(int x, int y)
{
    // Write the times of the next cloud, next lightning, and cloud duration to the screen and into some customvars for the Portal.
    ReefAngel.LCD.DrawText(0,255,x,y,"C"); x+=6;
    ReefAngel.LCD.DrawText(0,255,x,y,"00:00"); x+=34;
    ReefAngel.LCD.DrawText(0,255,x,y,"L"); x+=6;
    ReefAngel.LCD.DrawText(0,255,x,y,"00:00"); x=5;
    if (cloudchance && (NumMins(hour(),minute())<cloudstart))
    {
      int x=0;
      if ((cloudstart/60)>=10) x=11;
      else x=17;
      ReefAngel.LCD.DrawText(0,255,x,y,(cloudstart/60));
      //ReefAngel.CustomVar[3]=cloudstart/60; // Write the hour of the next cloud to custom variable for Portal reporting
      if ((cloudstart%60)>=10) x=29;
      else x=35;
      ReefAngel.LCD.DrawText(0,255,x,y,(cloudstart%60));
      //ReefAngel.CustomVar[4]=cloudstart%60; // Write the minute of the next cloud to custom variable for Portal reporting

    }
    ReefAngel.LCD.DrawText(0,255,x+85,y,cloudduration);
    //ReefAngel.CustomVar[7]=(cloudduration);    // Put the duration of the next cloud in a custom var for the portal
    if (lightningchance)
    {
      int x=0;
      if (((cloudstart+(cloudduration/3))/60)>=10) x=51;
      else x=57;
      ReefAngel.LCD.DrawText(0,255,x,y,((cloudstart+(cloudduration/3))/60));
      //ReefAngel.CustomVar[5]=(cloudstart+(cloudduration/2))/60;    // Write the hour of the next lightning to a custom variable for the Portal
      if (((cloudstart+(cloudduration/3))%60)>=10) x=69;
      else x=75;
        ReefAngel.LCD.DrawText(0,255,x,y,((cloudstart+(cloudduration/3))%60)); // Write the minute of the next lightning to a custom variable for the Portal
        //ReefAngel.CustomVar[6]=(cloudstart+(cloudduration/2))%60;
    }
}

void Strike()
{
  int a=random(1,5);    // Pick a number of consecutive flashes from 1 to 4. 
  for (int i=0; i<a; i++)
  {
    // Flash on
    int newdata=4095;
    Wire.beginTransmission(0x40);      // Address of the dimming expansion module
    Wire.write(0x8+(4*1));             // 0x8 is channel 0, 0x12 is channel 1, etc.  This is channel 1.
    Wire.write(newdata&0xff);          // Send the data 8 bits at a time.  This sends the LSB
    Wire.write(newdata>>8);            // This sends the MSB
    Wire.endTransmission();
   
    Wire.beginTransmission(0x40);      // Address of the dimming expansion module
    Wire.write(0x8+(4*3));             // 0x8 is channel 0, 0x12 is channel 1, etc.  This is channel 3.
    Wire.write(newdata&0xff);          // Send the data 8 bits at a time.  This sends the LSB
    Wire.write(newdata>>8);            // This sends the MSB
    Wire.endTransmission();
   
    Wire.beginTransmission(0x40);      // Address of the dimming expansion module
    Wire.write(0x8+(4*5));             // 0x8 is channel 0, 0x12 is channel 1, etc.  This is channel 5.
    Wire.write(newdata&0xff);          // Send the data 8 bits at a time.  This sends the LSB
    Wire.write(newdata>>8);            // This sends the MSB
    Wire.endTransmission();
   
    int randy=random(20,80);    // Random number for a delay
    if (randy>71) randy=((randy-70)/2)*100;    // Small chance of a longer delay
    delay(randy);                // Wait from 20 to 69 ms, or 100-400 ms
   
    // Flash off.  Return to baseline.
    newdata=ReefAngel.PWM.GetChannelValueRaw(1);   // Use the channel number you're flashing here
    Wire.beginTransmission(0x40);    // Same as above
    Wire.write(0x8+(4*1));
    Wire.write(newdata&0xff);
    Wire.write(newdata>>8);
    Wire.endTransmission();
   
    newdata=ReefAngel.PWM.GetChannelValueRaw(3);   // Use the channel number you're flashing here
    Wire.beginTransmission(0x40);    // Same as above
    Wire.write(0x8+(4*3));
    Wire.write(newdata&0xff);
    Wire.write(newdata>>8);
    Wire.endTransmission();
   
    newdata=ReefAngel.PWM.GetChannelValueRaw(5);   // Use the channel number you're flashing here
    Wire.beginTransmission(0x40);    // Same as above
    Wire.write(0x8+(4*5));
    Wire.write(newdata&0xff);
    Wire.write(newdata>>8);
    Wire.endTransmission();
   
    delay(random(30,50));                // Wait from 30 to 49 ms
    wdt_reset();    // Reset watchdog timer to avoid re-boots
  }
}

byte ReversePWMSlope(long cstart,long cend,byte PWMStart,byte PWMEnd, byte clength)
{
  long n=elapsedSecsToday(now());
  cstart*=60;
  cend*=60;
  if (n<cstart) return PWMStart;
  if (n>=cstart && n<=(cstart+clength)) return map(n,cstart,cstart+clength,PWMStart,PWMEnd);
  if (n>(cstart+clength) && n<(cend-clength)) return PWMEnd;
  if (n>=(cend-clength) && n<=cend) return map(n,cend-clength,cend,PWMEnd,PWMStart);
  if (n>cend) return (int) PWMStart;
}

int ReversePWMSlope(long cstart,long cend,int PWMStart,int PWMEnd, byte clength)
{
  long n=elapsedSecsToday(now());
  cstart*=60;
  cend*=60;
  if (n<cstart) return PWMStart;
  if (n>=cstart && n<=(cstart+clength)) return map(n,cstart,cstart+clength,PWMStart,PWMEnd);
  if (n>(cstart+clength) && n<(cend-clength)) return PWMEnd;
  if (n>=(cend-clength) && n<=cend) return map(n,cend-clength,cend,PWMEnd,PWMStart);
  if (n>cend) return (int) PWMStart;
}
Image
Previous

Return to How do I code ...

Who is online

Users browsing this forum: No registered users and 3 guests

cron