Custom Main Screens

Would you like to help?
Share your walkthrough tutorial with others
alexwbush
Posts: 327
Joined: Tue Mar 22, 2011 12:45 am
Location: San Diego, CA

Re: Custom Main Screens

Post by alexwbush »

DrewPalmer04 wrote:Lol good ol' photobucket messing up
Is the Cloud and time portion meant to eventually show when the next clouds are?
User avatar
DrewPalmer04
Posts: 818
Joined: Tue May 29, 2012 2:12 pm
Location: Christopher, IL

Re: Custom Main Screens

Post by DrewPalmer04 »

Cloud is the time for the next cloud. And duration is how long it will last.
Out for now...but not over.

VISIT: Ethernet Module/Wifi Alternative
alexwbush
Posts: 327
Joined: Tue Mar 22, 2011 12:45 am
Location: San Diego, CA

Re: Custom Main Screens

Post by alexwbush »

nice. Eventually programming that? I see it as text in your code. I am still trying to wrap my head around where to create the moon phases code.
User avatar
DrewPalmer04
Posts: 818
Joined: Tue May 29, 2012 2:12 pm
Location: Christopher, IL

Re: Custom Main Screens

Post by DrewPalmer04 »

I'll list my code later. It works like a charm. Moonphase is in the libs now so just upload how you want to run it and you'll be set
Out for now...but not over.

VISIT: Ethernet Module/Wifi Alternative
User avatar
DrewPalmer04
Posts: 818
Joined: Tue May 29, 2012 2:12 pm
Location: Christopher, IL

Re: Custom Main Screens

Post by DrewPalmer04 »

Here is my code:

Code: Select all

#define VersionMenu
#define DisplayLEDPWM
#define wifi
#define WDT
#define SIMPLE_MENU




#include <ReefAngel_Features.h>
#include <Globals.h>
#include <RA_Wifi.h>
#include <Wire.h>
#include <OneWire.h>
#include <Time.h>
#include <DS1307RTC.h>
#include <InternalEEPROM.h>
#include <RA_NokiaLCD.h>
#include <RA_ATO.h>
#include <RA_Joystick.h>
#include <LED.h>
#include <RA_TempSensor.h>
#include <Relay.h>
#include <RA_PWM.h>
#include <Timer.h>
#include <Memory.h>
#include <ReefAngel.h>
#include <RA_Colors.h>
#include <RA_CustomColors.h>


byte ActinicPWMValue=0;
byte DaylightPWMValue=0;

////// Place global variable code below here
void DrawCustomMain()
{
  byte x = 6;
  byte y = 2;
  byte t;
  char text[7];
  

  ReefAngel.LCD.DrawDate(6, 2);
  ReefAngel.LCD.Clear(COLOR_BLACK, 1, 11, 132, 11);
  pingSerial();
  
  ReefAngel.LCD.DrawText(0,255,3,17,"Drew Palmer's 75 Reef");
  
 

  pingSerial();

  ReefAngel.LCD.DrawText(COLOR_BLACK,255, 6, 90, "--------------------");
  ReefAngel.LCD.DrawText(COLOR_BLACK,255, 6, 126, "--------------------");
  ReefAngel.LCD.DrawText(COLOR_BLACK,255, 2, 93, "|");
  ReefAngel.LCD.DrawText(COLOR_BLACK,255, 2, 103, "|");
  ReefAngel.LCD.DrawText(COLOR_BLACK,255, 2, 113, "|");
  ReefAngel.LCD.DrawText(COLOR_BLACK,255, 2, 123, "|");
  ReefAngel.LCD.DrawText(COLOR_BLACK,255, 126, 93, "|");
  ReefAngel.LCD.DrawText(COLOR_BLACK,255, 126, 103, "|");
  ReefAngel.LCD.DrawText(COLOR_BLACK,255, 126, 113, "|");
  ReefAngel.LCD.DrawText(COLOR_BLACK,255, 126, 123, "|");
  
  

  ReefAngel.LCD.DrawText(0,255,10,30,"Display");
  ConvertNumToString(text, ReefAngel.Params.Temp[T3_PROBE], 10);
  ReefAngel.LCD.DrawText(COLOR_BLACK, 255, 10, 40, text);
  
  ReefAngel.LCD.DrawText(0,255,8,68,"Room");
  ReefAngel.LCD.DrawSingleMonitor(ReefAngel.Params.Temp[T2_PROBE], COLOR_BLACK, 40, 68, 10);

  ReefAngel.LCD.DrawText(0,255,70,68,"Light");
  ReefAngel.LCD.DrawSingleMonitor(ReefAngel.Params.Temp[T1_PROBE], COLOR_BLACK, 99, 68, 10);
  pingSerial();

  ReefAngel.LCD.DrawText(0,255,100,30,"pH");
  ConvertNumToString(text, ReefAngel.Params.PH, 100);
  ReefAngel.LCD.DrawText(COLOR_BLACK, 255, 95, 40, text);
  
  pingSerial();

  byte TempRelay = ReefAngel.Relay.RelayData;
  TempRelay &= ReefAngel.Relay.RelayMaskOff;
  TempRelay |= ReefAngel.Relay.RelayMaskOn;
  ReefAngel.LCD.DrawOutletBox(12, 77, TempRelay);

  pingSerial();
  
  ReefAngel.LCD.DrawText(0,255,8,100, "CWLED");  
  ReefAngel.LCD.DrawText(COLOR_BLACK,255,15,119, ReefAngel.PWM.GetDaylightValue());
  
  ReefAngel.LCD.DrawText(0,255,88,100, "RBLED");  
  ReefAngel.LCD.DrawText(COLOR_BLACK,255,95,119, ReefAngel.PWM.GetActinicValue());
  
  ReefAngel.LCD.DrawText(0,255,48,100, "Cloud");
  ReefAngel.LCD.DrawText(0,255,41,108, "Duration"); 
  ReefAngel.LCD.DrawText(0,255,60,30, "5v");
  ReefAngel.LCD.DrawText(0,255,60,40,PWMSlope(20,2,6,0,0,100,255,0));
 

}
void DrawCustomGraph()
{
}

////// Place global variable code above here


void setup()
{
    // This must be the first line
    ReefAngel.Init();  //Initialize controller
     ReefAngel.FeedingModePorts = Port5Bit | Port6Bit | Port3Bit;
    // Ports toggled in Water Change Mode
    ReefAngel.WaterChangePorts = 0;
    // Ports toggled when Lights On / Off menu entry selected
    ReefAngel.LightsOnPorts = 0;
    // Ports turned off when Overheat temperature exceeded
    ReefAngel.OverheatShutoffPorts = Port5Bit | Port6Bit | Port7Bit;
    // Use T1 probe as temperature and overheat functions
    ReefAngel.TempProbe = T1_PROBE;
    ReefAngel.OverheatProbe = T3_PROBE;
    // Set the Overheat temperature setting
    InternalMemory.OverheatTemp_write( 860 );
    
    ReefAngel.PHMin=830; // 830=PH10.0
    ReefAngel.PHMin=480; // 480=PH7.0
    

    
    ReefAngel.SingleATO( true,Port1,60,0 );
    pinMode(lowATOPin,OUTPUT); 
    //pinMode(highATOPin,false);//disable highATOpin    

    // Ports that are always on
    ReefAngel.Relay.On(Port3);//Koralia
    ReefAngel.Relay.On(Port4);
    ReefAngel.Relay.Off(Port2);//Off
    ReefAngel.Relay.Off(Port1);//Off
    
    ReefAngel.Relay.On(Port8);//temp fan on (see Standard Fan)
    
    ////// Place additional initialization code below here
    


    
    
    //ReefAngel.AddWifi();

    ////// Place additional initialization code above here
}

void loop()
{
    // Specific functions that use Internal Memory values
    // Calculate your regular sunrise/sunset PWM value
  ActinicPWMValue=PWMParabola(6,5,21,0,0,85,0);//85%
  DaylightPWMValue=PWMParabola(7,5,19,0,0,80,0);//80%
  CheckCloud();
  ReefAngel.PWM.SetActinic(ActinicPWMValue);
  ReefAngel.PWM.SetDaylight(DaylightPWMValue);
  
    //ReefAngel.StandardHeater( Port4,740,770 );
    ReefAngel.StandardLights(Port7,8,15,18,30);//On 8:15 Off 6:30
    ReefAngel.StandardFan(Port8,900,910);
    
    
//5 min turbulence wavemaker    
   if ( (hour()>=7 && hour()<11))
{

static unsigned long nexttoggle=now();
static boolean state=false;
int cycle=nexttoggle-now();
ReefAngel.Relay.Set(Port5,state);
ReefAngel.Relay.Set(Port6,!ReefAngel.Relay.Status(Port5));
if (cycle<0)
{
nexttoggle+=random(35,45);
state=!state;
}
if (cycle<5)
{
ReefAngel.Relay.On(Port5);
ReefAngel.Relay.On(Port6);
} 
}
else if ( (hour()>=11 && hour()<13) )
{
static unsigned long nexttoggle=now();
static boolean state=false;
int cycle=nexttoggle-now();
ReefAngel.Relay.Set(Port5,state);
ReefAngel.Relay.Set(Port6,!ReefAngel.Relay.Status(Port5));
if (cycle<0)
{
nexttoggle+=random(10,20);
state=!state;
}
if (cycle<5)
{
ReefAngel.Relay.On(Port5);
ReefAngel.Relay.On(Port6);
} 
} 
else if ( (hour()>=13 && hour()<20) )
{
static unsigned long nexttoggle=now();
static boolean state=false;
int cycle=nexttoggle-now();
ReefAngel.Relay.Set(Port5,state);
ReefAngel.Relay.Set(Port6,!ReefAngel.Relay.Status(Port5));
if (cycle<0)
{
nexttoggle+=random(15,45);
state=!state;
}
if (cycle<5)
{
ReefAngel.Relay.On(Port5);
ReefAngel.Relay.On(Port6);
} 
} 
else 
{
ReefAngel.Relay.Off(Port5);
ReefAngel.Relay.Off(Port6);
} 


    
    
   // ReefAngel.PWM.SetDaylight( PWMParabola(7,5,19,0,0,80,0) );//80%
   // ReefAngel.PWM.SetActinic( PWMParabola(6,5,21,0,0,85,0) );//85%
   
  

    
    
    ////// Place your custom code below here
    
    //if (hour()>=6 && hour()<20)
    //analogWrite(lowATOPin,0);
    //else
    analogWrite(lowATOPin,2.55*PWMSlope(20,2,6,0,0,100,255,0));

    ////// Place your custom code above here
  


    // This should always be the last line
    ReefAngel.ShowInterface();
}
//*********************************************************************************************************************************
// Random Cloud/Thunderstorm effects function
void CheckCloud()
{

  // ------------------------------------------------------------
  // Change the values below to customize your cloud/storm effect

  // Frequency in days based on the day of the month - number 2 means every 2 days, for example (day 2,4,6 etc)
  // For testing purposes, you can use 1 and cause the cloud to occur everyday
#define Clouds_Every_X_Days 2 

  // Percentage chance of a cloud happening today
  // For testing purposes, you can use 100 and cause the cloud to have 100% chance of happening
#define Cloud_Chance_per_Day 60

  // Minimum number of minutes for cloud duration.  Don't use max duration of less than 6
#define Min_Cloud_Duration 7

  // Maximum number of minutes for the cloud duration. Don't use max duration of more than 255
#define Max_Cloud_Duration 15

  // Minimum number of clouds that can happen per day
#define Min_Clouds_per_Day 2

  // Maximum number of clouds that can happen per day
#define Max_Clouds_per_Day 4

  // Only start the cloud effect after this setting
  // In this example, start could after 10:30am
#define Start_Cloud_After NumMins(10,30)

  // Always end the cloud effect before this setting
  // In this example, end could before 5:30pm
#define End_Cloud_Before NumMins(17,30)

  // Percentage chance of a lightning happen for every cloud
  // For testing purposes, you can use 100 and cause the lightning to have 100% chance of happening
#define Lightning_Change_per_Cloud 0

  // Note: Make sure to choose correct values that will work within your PWMSLope settings.
  // For example, in our case, we could have a max of 5 clouds per day and they could last for 50 minutes.
  // Which could mean 250 minutes of clouds. We need to make sure the PWMSlope can accomodate 250 minutes of effects or unforseen resul could happen.
    // Also, make sure that you can fit double those minutes between Start_Cloud_After and End_Cloud_Before.
  // In our example, we have 510 minutes between Start_Cloud_After and End_Cloud_Before, so double the 250 minutes (or 500 minutes) can fit in that 510 minutes window.
    // It's a tight fit, but it did.

    //#define printdebug // Uncomment this for debug print on Serial Monitor window
  #define forcecloudcalculation // Uncomment this to force the cloud calculation to happen in the boot process. 


  // Change the values above to customize your cloud/storm effect
  // ------------------------------------------------------------
  // Do not change anything below here

  static byte cloudchance=255;
  static byte cloudduration=0;
  static int cloudstart=0;
  static byte numclouds=0;
  static byte lightningchance=0;
  static byte cloudindex=0;
  static byte lightningstatus=0;
  static int LastNumMins=0;
  // Every day at midnight, we check for chance of cloud happening today
  if (hour()==0 && minute()==0 && second()==0) cloudchance=255;

#ifdef forcecloudcalculation
    if (cloudchance==255)
#else
    if (hour()==0 && minute()==0 && second()==1 && cloudchance==255) 
#endif
    {
      //Pick a random number between 0 and 99
      cloudchance=random(100); 
      // if picked number is greater than Cloud_Chance_per_Day, we will not have clouds today
      if (cloudchance>Cloud_Chance_per_Day) cloudchance=0;
      // Check if today is day for clouds. 
      if ((day()%Clouds_Every_X_Days)!=0) cloudchance=0; 
      // If we have cloud today
      if (cloudchance)
      {
        // pick a random number for number of clouds between Min_Clouds_per_Day and Max_Clouds_per_Day
        numclouds=random(Min_Clouds_per_Day,Max_Clouds_per_Day);
        // pick the time that the first cloud will start
        // the range is calculated between Start_Cloud_After and the even distribuition of clouds on this day. 
        cloudstart=random(Start_Cloud_After,Start_Cloud_After+((End_Cloud_Before-Start_Cloud_After)/(numclouds*2)));
        // pick a random number for the cloud duration of first cloud.
        cloudduration=random(Min_Cloud_Duration,Max_Cloud_Duration);
        //Pick a random number between 0 and 99
        lightningchance=random(100);
        // if picked number is greater than Lightning_Change_per_Cloud, we will not have lightning today
        if (lightningchance>Lightning_Change_per_Cloud) lightningchance=0;
      }
    }
  // Now that we have all the parameters for the cloud, let's create the effect

  if (cloudchance)
  {
    //is it time for cloud yet?
    if (NumMins(hour(),minute())>=cloudstart && NumMins(hour(),minute())<(cloudstart+cloudduration))
    {
      DaylightPWMValue=ReversePWMSlope(cloudstart,cloudstart+cloudduration,DaylightPWMValue,0,180);
      if (lightningchance && (NumMins(hour(),minute())==(cloudstart+(cloudduration/2))) && second()<5) 
      {
        if (random(100)<20) lightningstatus=1; 
        else lightningstatus=0;
        if (lightningstatus)
        {
          DaylightPWMValue=100; 
          ActinicPWMValue=100;
        }
        else 
        {
          DaylightPWMValue=0;
          ActinicPWMValue=0;
        }
        delay(1);
      }
    }
    if (NumMins(hour(),minute())>(cloudstart+cloudduration))
    {
      cloudindex++;
      if (cloudindex < numclouds)
      {
        cloudstart=random(Start_Cloud_After+(((End_Cloud_Before-Start_Cloud_After)/(numclouds*2))*cloudindex*2),(Start_Cloud_After+(((End_Cloud_Before-Start_Cloud_After)/(numclouds*2))*cloudindex*2))+((End_Cloud_Before-Start_Cloud_After)/(numclouds*2)));
        // pick a random number for the cloud duration of first cloud.
        cloudduration=random(Min_Cloud_Duration,Max_Cloud_Duration);
        //Pick a random number between 0 and 99
        lightningchance=random(100);
        // if picked number is greater than Lightning_Change_per_Cloud, we will not have lightning today
        if (lightningchance>Lightning_Change_per_Cloud) lightningchance=0;
      }
    }
  }
  
  if (LastNumMins!=NumMins(hour(),minute()))
  {
    LastNumMins=NumMins(hour(),minute());
    ReefAngel.LCD.Clear(255,0,120,132,132);
    ReefAngel.LCD.DrawText(0,255,48,47,"Cloud");
    ReefAngel.LCD.DrawText(0,255,48,57,"00:00");
    //ReefAngel.LCD.DrawText(0,255,45,120,"L");
    //ReefAngel.LCD.DrawText(0,255,51,120,"00:00");
    if (cloudchance && (NumMins(hour(),minute())<cloudstart))
    {
      int x=0;
      if ((cloudstart/60)>=10) x=48; else x=54;
      ReefAngel.LCD.DrawText(0,255,x,57,(cloudstart/60));
      if ((cloudstart%60)>=10) x=66; else x=72;
      ReefAngel.LCD.DrawText(0,255,x,57,(cloudstart%60));
    }
    ReefAngel.LCD.DrawText(0,255,56,119,cloudduration);
    if (lightningchance) 
    {
      int x=0;
      if (((cloudstart+(cloudduration/2))/60)>=10) x=51; else x=57;
      ReefAngel.LCD.DrawText(0,255,x,115,((cloudstart+(cloudduration/2))/60));
      if (((cloudstart+(cloudduration/2))%60)>=10) x=69; else x=75;
      ReefAngel.LCD.DrawText(0,255,x,115,((cloudstart+(cloudduration/2))%60));
    }
  }   
}

byte ReversePWMSlope(long cstart,long cend,byte PWMStart,byte PWMEnd, byte clength)
{
  long n=elapsedSecsToday(now());
  cstart*=60;
  cend*=60;
  if (n<cstart) return PWMStart;
  if (n>=cstart && n<=(cstart+clength)) return map(n,cstart,cstart+clength,PWMStart,PWMEnd);
  if (n>(cstart+clength) && n<(cend-clength)) return PWMEnd;
  if (n>=(cend-clength) && n<=cend) return map(n,cend-clength,cend,PWMEnd,PWMStart);
  if (n>cend) return PWMStart;
}




Out for now...but not over.

VISIT: Ethernet Module/Wifi Alternative
alexwbush
Posts: 327
Joined: Tue Mar 22, 2011 12:45 am
Location: San Diego, CA

Re: Custom Main Screens

Post by alexwbush »

ugh, I need my RA+ back. It's running my temporary tank 6 hours north with basic RA equipment. Meanwhile my basic RA is down here maxed out on memory and not able to run all kinds of expansion modules. Expect some huge improvements in custom screens and other code once I get my + on this tank! :)
alexwbush
Posts: 327
Joined: Tue Mar 22, 2011 12:45 am
Location: San Diego, CA

Re: Custom Main Screens

Post by alexwbush »

any idea how to draw an ellipse or oval? Or a half circle?
rimai
Posts: 12881
Joined: Fri Mar 18, 2011 6:47 pm

Re: Custom Main Screens

Post by rimai »

:(
Not in the libraries. You will need to come up with your own function.
Can you find an algorithm? We are using Jsclownfish drawing algorithm for the circles. He's the man behind it :)
Roberto.
User avatar
jsclownfish
Posts: 378
Joined: Mon Oct 24, 2011 7:52 pm
Location: Saint Louis

Custom Main Screens

Post by jsclownfish »

Here is the code I adopted ...
http://forum.reefangel.com/viewtopic.php?t=606
Jon
User avatar
lnevo
Posts: 5430
Joined: Fri Jul 20, 2012 9:42 am

Custom Main Screens

Post by lnevo »

I think we should take that half oval and we should write a fuel guage

Easier would be a bar chart...

Omg just thought of equalizer view of all parameters with your target value for temp ph sal orp water level on the center line or rather for that to just be 0-100 (e / f with ticks for half quarter 3/4)
Kinda like the dimming bar on the dimmer channels but on lcd.

1/2 circle could also represent moonphase...
alexwbush
Posts: 327
Joined: Tue Mar 22, 2011 12:45 am
Location: San Diego, CA

Re: Custom Main Screens

Post by alexwbush »

lnevo wrote:1/2 circle could also represent moonphase...
bingo ;) and ellipse
User avatar
jsclownfish
Posts: 378
Joined: Mon Oct 24, 2011 7:52 pm
Location: Saint Louis

Re: Custom Main Screens

Post by jsclownfish »

I found this on the web and with a little modification for RA seems to work OK. I haven't played with it much, but it seems to work in this little demo I tried...

http://tronixstuff.wordpress.com/2011/0 ... olour-lcd/

Code: Select all

#include <Salinity.h>
#include <ReefAngel_Features.h>
#include <Globals.h>
#include <RA_Wifi.h>
#include <Wire.h>
#include <OneWire.h>
#include <Time.h>
#include <DS1307RTC.h>
#include <InternalEEPROM.h>
#include <RA_NokiaLCD.h>
#include <RA_ATO.h>
#include <RA_Joystick.h>
#include <LED.h>
#include <RA_TempSensor.h>
#include <Relay.h>
#include <RA_PWM.h>
#include <Timer.h>
#include <Memory.h>
#include <InternalEEPROM.h>
#include <RA_Colors.h>
#include <RA_CustomColors.h>
#include <RF.h>
#include <IO.h>
#include <ORP.h>
#include <AI.h>
#include <PH.h>
#include <WaterLevel.h>
#include <ReefAngel.h>

byte a;

//************************************************************************
//*	Edit History  modified  from.....
//*		<MLS>	= Mark Sproul msproul -at- jove.rutgers.edu
//************************************************************************
int FULLCIRCLE = 1;
int OPENEAST = 2;
int OPENWEST= 3;
int OPENNORTH = 4;
int OPENSOUTH = 5;
int OPENNORTHEAST = 6;
int OPENNORTHWEST = 7;
int OPENSOUTHEAST = 8;
int OPENSOUTHWEST = 9;

void LCDDrawCircle (int xCenter, int yCenter, int radius, int color, int circleType)
{
       int tSwitch, x1 = 0, y1 = radius;
       int Width = 2*radius, Height=Width;
       tSwitch = 3 - 2 * radius;

       while (x1 <= y1) {
         if (circleType == FULLCIRCLE||circleType == OPENSOUTH||circleType == OPENEAST||circleType == OPENSOUTHEAST) {
           ReefAngel.LCD.PutPixel(color,xCenter+radius - x1, yCenter+radius - y1);
           ReefAngel.LCD.PutPixel(color,xCenter+radius - y1, yCenter+radius - x1);
         }
         if (circleType == FULLCIRCLE||circleType == OPENNORTH||circleType == OPENEAST||circleType == OPENNORTHEAST) {
           ReefAngel.LCD.PutPixel(color,xCenter+Width-radius + x1, yCenter+radius - y1);
           ReefAngel.LCD.PutPixel(color,xCenter+Width-radius + y1, yCenter+radius - x1);
         }
         if (circleType == FULLCIRCLE||circleType == OPENNORTH||circleType == OPENWEST||circleType == OPENNORTHWEST) {
           ReefAngel.LCD.PutPixel(color,xCenter+Width-radius + x1, yCenter+Height-radius + y1);
           ReefAngel.LCD.PutPixel(color,xCenter+Width-radius + y1, yCenter+Height-radius + x1);
         }
         if (circleType == FULLCIRCLE||circleType == OPENSOUTH||circleType == OPENWEST||circleType == OPENSOUTHWEST) {
           ReefAngel.LCD.PutPixel(color,xCenter+radius - x1, yCenter+Height-radius + y1);
           ReefAngel.LCD.PutPixel(color,xCenter+radius - y1, yCenter+Height-radius + x1);
         }
         if (tSwitch < 0) {
               tSwitch += (4 * x1 + 6);
         } else {
               tSwitch += (4 * (x1 - y1) + 10);
             y1--;
         }
         x1++;
       }
}
void DrawCustomGraph()
{
}
void DrawCustomMain()
{
a=second()%9;
if (a==1) (LCDDrawCircle(50, 50, 20, T1TempColor, OPENEAST));
ReefAngel.LCD.Clear(255, 10, 10, 120,120);
if (a==2) (LCDDrawCircle(50, 50, 20, T1TempColor, OPENWEST));
ReefAngel.LCD.Clear(255, 10, 10, 120,120);
if (a==3) (LCDDrawCircle(50, 50, 20, T1TempColor, OPENNORTH));
ReefAngel.LCD.Clear(255, 10, 10, 120,120);
if (a==4) (LCDDrawCircle(50, 50, 20, T1TempColor, OPENSOUTH));
ReefAngel.LCD.Clear(255, 10, 10, 120,120);
if (a==5) (LCDDrawCircle(50, 50, 20, T1TempColor, OPENNORTHEAST));
ReefAngel.LCD.Clear(255, 10, 10, 120,120);
if (a==6) (LCDDrawCircle(50, 50, 20, T1TempColor, OPENNORTHWEST));
ReefAngel.LCD.Clear(255, 10, 10, 120,120);
if (a==7) (LCDDrawCircle(50, 50, 20, T1TempColor, OPENSOUTHEAST));
ReefAngel.LCD.Clear(255, 10, 10, 120,120);
if (a==8) (LCDDrawCircle(50, 50, 20, T1TempColor, OPENSOUTHWEST));
ReefAngel.LCD.Clear(255, 10, 10, 120,120);
if (a==8) (LCDDrawCircle(50, 50, 20, T1TempColor, FULLCIRCLE));
ReefAngel.LCD.Clear(255, 10, 10, 120,120);
ReefAngel.LCD.DrawDate(5,121);
}
void setup()
{
  ReefAngel.Init(); 
}
void loop()
{
    ReefAngel.ShowInterface();
}
stevengreen2
Posts: 29
Joined: Thu Sep 27, 2012 11:02 pm
Location: Redding

Re: Custom Main Screens

Post by stevengreen2 »

DrewPalmer I want to use the display screen you setup, but I can't figure out how to put in values from the dimming add on box.

The code from the dimming add on box has this code:

Code: Select all

// Dimming Expansion
    x = 15;
    y = 2;
    for ( int a=0;a<6;a++ )
    {
      if ( a>2 ) x = 75;
      if ( a==3 ) y = 2;
      ReefAngel.LCD.DrawText( COLOR_DARKGOLDENROD,DefaultBGColor,x,y,"Ch :" );
      ReefAngel.LCD.DrawText( COLOR_DARKGOLDENROD,DefaultBGColor,x+12,y,a );
      ReefAngel.LCD.DrawText( COLOR_DARKGOLDENROD,DefaultBGColor,x+24,y,ReefAngel.PWM.GetChannelValue(a) );
      y += 10;
    }
    pingSerial();
I just want to put channel 0 as the RB and channel 1 as the CWB
alexwbush
Posts: 327
Joined: Tue Mar 22, 2011 12:45 am
Location: San Diego, CA

Re: Custom Main Screens

Post by alexwbush »

dear Roberto,
Can we have a draw ellipse function?
rimai
Posts: 12881
Joined: Fri Mar 18, 2011 6:47 pm

Re: Custom Main Screens

Post by rimai »

Do you have the algorithm?
Roberto.
alexwbush
Posts: 327
Joined: Tue Mar 22, 2011 12:45 am
Location: San Diego, CA

Re: Custom Main Screens

Post by alexwbush »

I haven't had an RA to test JS's code :-(
User avatar
jsclownfish
Posts: 378
Joined: Mon Oct 24, 2011 7:52 pm
Location: Saint Louis

Re: Custom Main Screens

Post by jsclownfish »

The code above is for circles and arcs from a circle. You would need to modify the code a bit for ellipses.
-Jon
User avatar
jsclownfish
Posts: 378
Joined: Mon Oct 24, 2011 7:52 pm
Location: Saint Louis

Re: Custom Main Screens

Post by jsclownfish »

You could work from this to get an ellipse...
http://code.google.com/p/glcd-arduino/i ... tail?id=15


Jon
JoelIreland
Posts: 58
Joined: Sat Jan 26, 2013 1:27 am

Re: Custom Main Screens

Post by JoelIreland »

Hi all, thought i'd share my custom main screen ( still tweaking ) would love to know your thoughts.
Image

Error Screen
Image

No Power with timer Countdown
Image
binder
Posts: 2871
Joined: Fri Mar 18, 2011 6:20 pm
Location: Illinois
Contact:

Re: Custom Main Screens

Post by binder »

That's pretty sweet. Nice job!! :)
rimai
Posts: 12881
Joined: Fri Mar 18, 2011 6:47 pm

Re: Custom Main Screens

Post by rimai »

Very cool!!!
Roberto.
JoelIreland
Posts: 58
Joined: Sat Jan 26, 2013 1:27 am

Re: Custom Main Screens

Post by JoelIreland »

Ive self taught myself too. I am a web developer but only php,html,css,js etc so had to learn new code but principle is still the same. Off topic is there a way to display the LowATO and HighATO positions, id like the green / red circles to go orange when they half way
rimai
Posts: 12881
Joined: Fri Mar 18, 2011 6:47 pm

Re: Custom Main Screens

Post by rimai »

Floats are only on or off. There is no between.
Roberto.
User avatar
lnevo
Posts: 5430
Joined: Fri Jul 20, 2012 9:42 am

Re: Custom Main Screens

Post by lnevo »

Where's the code :)
bencollinz
Posts: 151
Joined: Wed Mar 13, 2013 5:36 pm

Re: Custom Main Screens

Post by bencollinz »

JoelIreland wrote:Hi all, thought i'd share my custom main screen ( still tweaking ) would love to know your thoughts.
Image

Error Screen
Image

No Power with timer Countdown
Image
lnevo wrote:Where's the code :)
yes, code please?
Image
binder
Posts: 2871
Joined: Fri Mar 18, 2011 6:20 pm
Location: Illinois
Contact:

Re: Custom Main Screens

Post by binder »

Finally updated the document to remove the references of RAGen and to tell how to do it with the Wizard.
Badger55
Posts: 27
Joined: Thu Mar 07, 2013 12:33 pm

Re: Custom Main Screens

Post by Badger55 »

OK this is my first attempt and I'm not even close to sure if this is right. I stole most of Drew's code and made what modifications I THOUGHT i should. Can anyone confirm?

#include <ReefAngel_Features.h>
#include <Globals.h>
#include <RA_Wifi.h>
#include <Wire.h>
#include <OneWire.h>
#include <Time.h>
#include <DS1307RTC.h>
#include <InternalEEPROM.h>
#include <RA_NokiaLCD.h>
#include <RA_ATO.h>
#include <RA_Joystick.h>
#include <LED.h>
#include <RA_TempSensor.h>
#include <Relay.h>
#include <RA_PWM.h>
#include <Timer.h>
#include <Memory.h>
#include <InternalEEPROM.h>
#include <RA_Colors.h>
#include <RA_CustomColors.h>
#include <Salinity.h>
#include <RF.h>
#include <IO.h>
#include <ORP.h>
#include <AI.h>
#include <PH.h>
#include <WaterLevel.h>
#include <ReefAngel.h>

////// Place global variable code below here


////// Place global variable code above here


void setup()
{
    // This must be the first line
    ReefAngel.Init(); //Initialize controller
    // Ports toggled in Feeding Mode
    ReefAngel.FeedingModePorts = 0;
    // Ports toggled in Water Change Mode
    ReefAngel.WaterChangePorts = Port1Bit | Port2Bit | Port3Bit | Port4Bit | Port5Bit | Port6Bit | Port7Bit | Port8Bit;
    // Ports toggled when Lights On / Off menu entry selected
    ReefAngel.LightsOnPorts = 0;
    // Ports turned off when Overheat temperature exceeded
    ReefAngel.OverheatShutoffPorts = Port1Bit | Port2Bit | Port3Bit;
    // Use T1 probe as temperature and overheat functions
    ReefAngel.TempProbe = T1_PROBE;
    ReefAngel.OverheatProbe = T1_PROBE;
    // Set the Overheat temperature setting
    InternalMemory.OverheatTemp_write( 850 );


    // Ports that are always on
    ReefAngel.Relay.On( Port8 );

    ////// Place additional initialization code below here
    

    ////// Place additional initialization code above here
}

void loop()
{
    ReefAngel.StandardHeater( Port1,780,790 );
    ReefAngel.StandardHeater( Port2,780,790 );
    ReefAngel.StandardHeater( Port3,780,790 );
    ReefAngel.MHLights( Port4,10,0,21,0,7 );
    ReefAngel.Wavemaker( Port5,100 );
    ReefAngel.WavemakerRandom( Port6,60,120 );
    ReefAngel.Relay.Set( Port7, !ReefAngel.Relay.Status( Port5 ) );
    ReefAngel.PWM.SetDaylight( PWMParabola(10,0,21,0,0,90,0) );
    ReefAngel.PWM.SetActinic( PWMParabola(9,30,22,0,0,90,0) );
    ////// Place your custom code below here
    #define VersionMenu
#define DisplayLEDPWM
#define wifi
#define WDT
#define SIMPLE_MENU




#include <ReefAngel_Features.h>
#include <Globals.h>
#include <RA_Wifi.h>
#include <Wire.h>
#include <OneWire.h>
#include <Time.h>
#include <DS1307RTC.h>
#include <InternalEEPROM.h>
#include <RA_NokiaLCD.h>
#include <RA_ATO.h>
#include <RA_Joystick.h>
#include <LED.h>
#include <RA_TempSensor.h>
#include <Relay.h>
#include <RA_PWM.h>
#include <Timer.h>
#include <Memory.h>
#include <ReefAngel.h>
#include <RA_Colors.h>
#include <RA_CustomColors.h>


byte ActinicPWMValue=0;
byte DaylightPWMValue=0;

////// Place global variable code below here
void DrawCustomMain()
{
  byte x = 6;
  byte y = 2;
  byte t;
  char text[7];
  

  ReefAngel.LCD.DrawDate(6, 2);
  ReefAngel.LCD.Clear(COLOR_BLACK, 1, 11, 132, 11);
  pingSerial();
  
  ReefAngel.LCD.DrawText(0,255,3,17,"Dan's 90 gal Reef");
  


  pingSerial();

  ReefAngel.LCD.DrawText(COLOR_BLACK,255, 6, 90, "--------------------");
  ReefAngel.LCD.DrawText(COLOR_BLACK,255, 6, 126, "--------------------");
  ReefAngel.LCD.DrawText(COLOR_BLACK,255, 2, 93, "|");
  ReefAngel.LCD.DrawText(COLOR_BLACK,255, 2, 103, "|");
  ReefAngel.LCD.DrawText(COLOR_BLACK,255, 2, 113, "|");
  ReefAngel.LCD.DrawText(COLOR_BLACK,255, 2, 123, "|");
  ReefAngel.LCD.DrawText(COLOR_BLACK,255, 126, 93, "|");
  ReefAngel.LCD.DrawText(COLOR_BLACK,255, 126, 103, "|");
  ReefAngel.LCD.DrawText(COLOR_BLACK,255, 126, 113, "|");
  ReefAngel.LCD.DrawText(COLOR_BLACK,255, 126, 123, "|");
  
  ReefAngel.LCD.Clear(255,0,120,132,132);
  ReefAngel.LCD.DrawText(0,255,48,47,"Cloud");
  ReefAngel.LCD.DrawText(0,255,48,57,"00:00");

  
  ReefAngel.LCD.DrawText(0,255,70,68,"Display");
  ReefAngel.LCD.DrawSingleMonitor(ReefAngel.Params.Temp[T1_PROBE], COLOR_BLACK, 99, 68, 10);
  pingSerial();

  ReefAngel.LCD.DrawText(0,255,100,30,"pH");
  ConvertNumToString(text, ReefAngel.Params.PH, 100);
  ReefAngel.LCD.DrawText(COLOR_BLACK, 255, 95, 40, text);
  
  pingSerial();

  byte TempRelay = ReefAngel.Relay.RelayData;
  TempRelay &= ReefAngel.Relay.RelayMaskOff;
  TempRelay |= ReefAngel.Relay.RelayMaskOn;
  ReefAngel.LCD.DrawOutletBox(12, 77, TempRelay);

  pingSerial();
  
  ReefAngel.LCD.DrawText(0,255,8,100, "CWLED");
  ReefAngel.LCD.DrawText(COLOR_BLACK,255,15,119, ReefAngel.PWM.GetDaylightValue());
  
  ReefAngel.LCD.DrawText(0,255,88,100, "RBLED");
  ReefAngel.LCD.DrawText(COLOR_BLACK,255,90,119, ReefAngel.PWM.GetActinicValue());
  

}
void DrawCustomGraph()
{
}

    ////// Place your custom code above here

    // This should always be the last line
    ReefAngel.Portal( "badger55" );
    ReefAngel.ShowInterface();
}
Image

Reefcam: dansreef.swanndvr.net login: guest pw: guest
rimai
Posts: 12881
Joined: Fri Mar 18, 2011 6:47 pm

Re: Custom Main Screens

Post by rimai »

Try this:

Code: Select all

#include <ReefAngel_Features.h>
#include <Globals.h>
#include <RA_Wifi.h>
#include <Wire.h>
#include <OneWire.h>
#include <Time.h>
#include <DS1307RTC.h>
#include <InternalEEPROM.h>
#include <RA_NokiaLCD.h>
#include <RA_ATO.h>
#include <RA_Joystick.h>
#include <LED.h>
#include <RA_TempSensor.h>
#include <Relay.h>
#include <RA_PWM.h>
#include <Timer.h>
#include <Memory.h>
#include <InternalEEPROM.h>
#include <RA_Colors.h>
#include <RA_CustomColors.h>
#include <Salinity.h>
#include <RF.h>
#include <IO.h>
#include <ORP.h>
#include <AI.h>
#include <PH.h>
#include <WaterLevel.h>
#include <ReefAngel.h>

////// Place global variable code below here


////// Place global variable code above here


void setup()
{
    // This must be the first line
    ReefAngel.Init(); //Initialize controller
    // Ports toggled in Feeding Mode
    ReefAngel.FeedingModePorts = 0;
    // Ports toggled in Water Change Mode
    ReefAngel.WaterChangePorts = Port1Bit | Port2Bit | Port3Bit | Port4Bit | Port5Bit | Port6Bit | Port7Bit | Port8Bit;
    // Ports toggled when Lights On / Off menu entry selected
    ReefAngel.LightsOnPorts = 0;
    // Ports turned off when Overheat temperature exceeded
    ReefAngel.OverheatShutoffPorts = Port1Bit | Port2Bit | Port3Bit;
    // Use T1 probe as temperature and overheat functions
    ReefAngel.TempProbe = T1_PROBE;
    ReefAngel.OverheatProbe = T1_PROBE;
    // Set the Overheat temperature setting
    InternalMemory.OverheatTemp_write( 850 );


    // Ports that are always on
    ReefAngel.Relay.On( Port8 );

    ////// Place additional initialization code below here
    

    ////// Place additional initialization code above here
}

void loop()
{
    ReefAngel.StandardHeater( Port1,780,790 );
    ReefAngel.StandardHeater( Port2,780,790 );
    ReefAngel.StandardHeater( Port3,780,790 );
    ReefAngel.MHLights( Port4,10,0,21,0,7 );
    ReefAngel.Wavemaker( Port5,100 );
    ReefAngel.WavemakerRandom( Port6,60,120 );
    ReefAngel.Relay.Set( Port7, !ReefAngel.Relay.Status( Port5 ) );
    ReefAngel.PWM.SetDaylight( PWMParabola(10,0,21,0,0,90,0) );
    ReefAngel.PWM.SetActinic( PWMParabola(9,30,22,0,0,90,0) );
    ////// Place your custom code below here

    ////// Place your custom code above here

    // This should always be the last line
    ReefAngel.Portal( "badger55" );
    ReefAngel.ShowInterface();
}

void DrawCustomMain()
{
  byte x = 6;
  byte y = 2;
  byte t;
  char text[7];
  

  ReefAngel.LCD.DrawDate(6, 2);
  ReefAngel.LCD.Clear(COLOR_BLACK, 1, 11, 132, 11);
  pingSerial();
  
  ReefAngel.LCD.DrawText(0,255,3,17,"Dan's 90 gal Reef");
  


  pingSerial();

  ReefAngel.LCD.DrawText(COLOR_BLACK,255, 6, 90, "--------------------");
  ReefAngel.LCD.DrawText(COLOR_BLACK,255, 6, 126, "--------------------");
  ReefAngel.LCD.DrawText(COLOR_BLACK,255, 2, 93, "|");
  ReefAngel.LCD.DrawText(COLOR_BLACK,255, 2, 103, "|");
  ReefAngel.LCD.DrawText(COLOR_BLACK,255, 2, 113, "|");
  ReefAngel.LCD.DrawText(COLOR_BLACK,255, 2, 123, "|");
  ReefAngel.LCD.DrawText(COLOR_BLACK,255, 126, 93, "|");
  ReefAngel.LCD.DrawText(COLOR_BLACK,255, 126, 103, "|");
  ReefAngel.LCD.DrawText(COLOR_BLACK,255, 126, 113, "|");
  ReefAngel.LCD.DrawText(COLOR_BLACK,255, 126, 123, "|");
  
  ReefAngel.LCD.Clear(255,0,120,132,132);
  ReefAngel.LCD.DrawText(0,255,48,47,"Cloud");
  ReefAngel.LCD.DrawText(0,255,48,57,"00:00");

  
  ReefAngel.LCD.DrawText(0,255,70,68,"Display");
  ReefAngel.LCD.DrawSingleMonitor(ReefAngel.Params.Temp[T1_PROBE], COLOR_BLACK, 99, 68, 10);
  pingSerial();

  ReefAngel.LCD.DrawText(0,255,100,30,"pH");
  ConvertNumToString(text, ReefAngel.Params.PH, 100);
  ReefAngel.LCD.DrawText(COLOR_BLACK, 255, 95, 40, text);
  
  pingSerial();

  byte TempRelay = ReefAngel.Relay.RelayData;
  TempRelay &= ReefAngel.Relay.RelayMaskOff;
  TempRelay |= ReefAngel.Relay.RelayMaskOn;
  ReefAngel.LCD.DrawOutletBox(12, 77, TempRelay);

  pingSerial();
  
  ReefAngel.LCD.DrawText(0,255,8,100, "CWLED"); 
  ReefAngel.LCD.DrawText(COLOR_BLACK,255,15,119, ReefAngel.PWM.GetDaylightValue());
  
  ReefAngel.LCD.DrawText(0,255,88,100, "RBLED"); 
  ReefAngel.LCD.DrawText(COLOR_BLACK,255,90,119, ReefAngel.PWM.GetActinicValue());
  

}
void DrawCustomGraph()
{
}
Roberto.
Badger55
Posts: 27
Joined: Thu Mar 07, 2013 12:33 pm

Re: Custom Main Screens

Post by Badger55 »

That did it. Thanks Roberto!
Image

Reefcam: dansreef.swanndvr.net login: guest pw: guest
Badger55
Posts: 27
Joined: Thu Mar 07, 2013 12:33 pm

Re: Custom Main Screens

Post by Badger55 »

I have a question about this now, can I still use the wizard to make changes to my setup and this part of the code will remain or do I need to add it each time?
Image

Reefcam: dansreef.swanndvr.net login: guest pw: guest
Post Reply