Custom Main Screens

lukeluke · Post by **lukeluke** » Sun Jul 17, 2011 11:34 am

Curt, with the new version, i'd want on the screen:

the Relay , AP,DP,PH,T1,T2,T3 and not the graph... and i want to see if the Timeout is on.

Like:

ATO Timeout : YES
Overheat Timeout : NO

How can i do ?

THANKS

binder · Post by **binder** » Sun Jul 17, 2011 1:01 pm

lukeluke wrote:Curt, with the new version, i'd want on the screen:

the Relay , AP,DP,PH,T1,T2,T3 and not the graph... and i want to see if the Timeout is on.

Like:

ATO Timeout : YES
Overheat Timeout : NO

How can i do ?

THANKS

When you say if the "Timeout is on" what are you asking? You want to know if the ATO pump is currently running and if the timeout is counting down? Or do you want to know if the timeout limit has exceeded?
Is this for the single ato or for the dual ato? The code will be different for both of them.

I ask because the Overheat doesn't have a timeout. It only has an exceeded value that when exceeded it turns on the RED LED on the controller and shuts off the lights.

curt

PS. I moved your post to be under the proper topic for the custom main screens.

mbertalha · Post by **mbertalha** » Tue Aug 09, 2011 6:35 pm

Hi Curt,

I'm having this error:

'class ReefAngel_NokiaLCD'has no member named'DrawHugeNumbers'

ReefAngel.LCD.DrawHugeNumbers(T1TempColor, DefaultBGColor, x, y, text);

What might be happening?

Tanks

Marcelo

binder · Post by **binder** » Wed Aug 10, 2011 4:19 am

you are missing a define statement inside your features file. Add this line to ReefAngel_Features.h

Code: Select all

 #define NUMBERS_16X16

That will enable you to use that function.

curt

mbertalha · Post by **mbertalha** » Mon Aug 15, 2011 6:40 am

binder wrote:you are missing a define statement inside your features file. Add this line to ReefAngel_Features.h
Code: Select all
 #define NUMBERS_16X16
That will enable you to use that function.

curt

Tanks Curt.

My custon main screen,

just need to disable the functions that are not needed in the source code and fix the character that is trimmed further on the PH.

My PDE file:

Code: Select all

// Autogenerated file by RAGen (v1.0.4.92), (08/10/2011 10:52)
// RA_081011_1052.pde
//
// This version designed for v0.8.5 Beta 12 or later

/* The following features are enabled for this PDE File: 
#define DisplayImages
#define WavemakerSetup
#define DateTimeSetup
#define VersionMenu
#define ATOSetup
#define DirectTempSensor
#define SingleATOSetup
#define StandardLightSetup
*/


#include <ReefAngel_Features.h>
#include <ReefAngel_Globals.h>
#include <ReefAngel_Wifi.h>
#include <Wire.h>
#include <OneWire.h>
#include <Time.h>
#include <DS1307RTC.h>
#include <ReefAngel_EEPROM.h>
#include <ReefAngel_NokiaLCD.h>
#include <ReefAngel_ATO.h>
#include <ReefAngel_Joystick.h>
#include <ReefAngel_LED.h>
#include <ReefAngel_TempSensor.h>
#include <ReefAngel_Relay.h>
#include <ReefAngel_PWM.h>
#include <ReefAngel_Timer.h>
#include <ReefAngel_Memory.h>
#include <ReefAngel.h>
#include <Phillips6610LCDInv.h>
#include <avr/pgmspace.h>
Phillips6610LCDInv e;
void ConvertNumToString(char* string, int num, byte decimal)
{
  char temptxt[3];
  int Temp = num;
  if (Temp==0xFFFF) Temp=0;
  itoa(Temp/decimal,string,10);
  if (decimal>1)
  {
      itoa(Temp%decimal,temptxt,10);
      strcat(string, ".");
      if (Temp%decimal<10 && decimal==100) strcat(string, "0");
      strcat(string, temptxt);
  }
}
void DrawCustomMain()
{
  byte x = 6;
  byte y = 2;
  byte t;
  ReefAngel.LCD.DrawDate(6, 2);
  ReefAngel.LCD.Clear(COLOR_BLACK, 1, 11, 132, 11);
  pingSerial();
  x = 12;
  y += MENU_START_ROW+1;
  ReefAngel.LCD.DrawText(COLOR_BLUE, COLOR_WHITE, x, y+6, "Temp         pH");
  char text[7];
  ConvertNumToString(text, ReefAngel.Params.PH, 100);
  ReefAngel.LCD.Clear(DefaultBGColor, x+16, y+65, x+65, y+16);
  ReefAngel.LCD.DrawLargeText(PHColor, DefaultBGColor, x+75, y+18, text, 
Font8x16);
  pingSerial();
  
  ConvertNumToString(text, ReefAngel.Params.Temp1, 10);
  y += MENU_START_ROW*2;
  x = 10;
  ReefAngel.LCD.Clear(DefaultBGColor,x,y,x+(16*4),y+16);
  pingSerial();
  ReefAngel.LCD.DrawHugeNumbers(T1TempColor, DefaultBGColor, x, y, text);
  pingSerial();  
  x += (16*4) + 8;
  ReefAngel.LCD.DrawText(T2TempColor,DefaultBGColor,x+8,y+25,"Temp2:");
  ReefAngel.LCD.DrawSingleMonitor(ReefAngel.Params.Temp2, T2TempColor, 
x+24, y+35, 10);
  ReefAngel.LCD.DrawText(T3TempColor,DefaultBGColor,x+8,y+50,"Temp3:");
  ReefAngel.LCD.DrawSingleMonitor(ReefAngel.Params.Temp3, T3TempColor, 
x+24, y+60, 10);
 
  y += 39*2;
  x = 13;
  byte TempRelay = ReefAngel.Relay.RelayData;
  TempRelay &= ReefAngel.Relay.RelayMaskOff;
  TempRelay |= ReefAngel.Relay.RelayMaskOn;
  ReefAngel.LCD.DrawOutletBox(x, y, TempRelay);
  
}
void DrawCustomGraph()
{
}
void setup()
{
    ReefAngel.Init();  //Initialize controller
    ReefAngel.SetTemperatureUnit(1);  // set to Celsius Temperature


    // Ports that are always on
    ReefAngel.Relay.On(Port8);
    ReefAngel.Relay.On(Port7);
    ReefAngel.Relay.On(Port6);
}

void loop()
{
    ReefAngel.ShowInterface();
    

    // Specific functions
    
    ReefAngel.StandardLights(Port1, 13, 30, 00, 30);
    ReefAngel.StandardATO(Port2, 2400); //Quantidade de segundos para reposição, se desligar pelo timer, led vermelho do RA acende e bloqueia a reposição
    ReefAngel.StandardFan(Port3, 270, 264);  // Turn fan/chiller on at 270C and off at 264C
    ReefAngel.StandardHeater(Port4, 260, 266);  // Turn heater on at 260C and off at 266C

}

best regards

Marcelo

rimai · Post by **rimai** » Mon Aug 15, 2011 8:14 am

Sweet

binder · Post by **binder** » Mon Aug 15, 2011 2:29 pm

Marcelo

That's a nice and clean looking screen! I like it!

curt

binder · Post by **binder** » Mon Aug 15, 2011 2:32 pm

Side note:

You should be able to remove these lines from your PDE file. They are not used by the libraries.

Code: Select all

#include <Phillips6610LCDInv.h>
Phillips6610LCDInv e;

curt

mbertalha · Post by **mbertalha** » Tue Aug 16, 2011 6:55 am

I got friends thanks to Roberto and Curt.

Curt,
thanks for the recommendations.
I would leave the PDE file cleaner, if they have other recommendations, I will enjoy.
The only thing missing now I ride my custom menu, and remove some functions will not use. Do not use PWM and wave maker.

Best regards.

Marcelo

bmhair03 · Post by **bmhair03** » Thu Aug 25, 2011 9:31 am

Just wanted to add my Main Display. Its based off Marcelo's. It has room for a second Relay if needed.
Thanks to all. code to follow:

bmhair03 · Post by **bmhair03** » Thu Aug 25, 2011 9:53 am

Hope this is better.

Here is my .pde.

Code: Select all

#include <ReefAngel_Colors.h>
#include <ReefAngel_CustomColors.h>
#include <ReefAngel_Features.h>
#include <ReefAngel_Globals.h>
#include <ReefAngel_Wifi.h>
#include <Wire.h>
#include <OneWire.h>
#include <Time.h>
#include <DS1307RTC.h>
#include <ReefAngel_EEPROM.h>
#include <ReefAngel_NokiaLCD.h>
#include <ReefAngel_ATO.h>
#include <ReefAngel_Joystick.h>
#include <ReefAngel_LED.h>
#include <ReefAngel_TempSensor.h>
#include <ReefAngel_Relay.h>
#include <ReefAngel_PWM.h>
#include <ReefAngel_Timer.h>
#include <ReefAngel_Memory.h>
#include <ReefAngel.h>
void ConvertNumToString(char* string, int num, byte decimal)
{
  char temptxt[3];
  int Temp = num;
  if (Temp==0xFFFF) Temp=0;
  itoa(Temp/decimal,string,10);
  if (decimal>1)
  {
      itoa(Temp%decimal,temptxt,10);
      strcat(string, ".");
      if (Temp%decimal<10 && decimal==100) strcat(string, "0");
      strcat(string, temptxt);
  }
}
void DrawCustomMain()
{
  byte x = 6;
  byte y = 2;
  byte t;
  ReefAngel.LCD.DrawDate(6, 2);
  ReefAngel.LCD.Clear(COLOR_BLACK, 1, 11, 132, 11);
  pingSerial();
  x = 12;
  y += MENU_START_ROW+1;
  ReefAngel.LCD.DrawText(COLOR_BLUE, COLOR_WHITE, x, y+6, "Display         pH");
  char text[7];
  ConvertNumToString(text, ReefAngel.Params.PH, 100);
  ReefAngel.LCD.Clear(DefaultBGColor, x+16, y+65, x+65, y+16);
  ReefAngel.LCD.DrawLargeText(PHColor, DefaultBGColor, x+75, y+18, text, 
Font8x16);
  pingSerial();
  
  ConvertNumToString(text, ReefAngel.Params.Temp1, 10);
  y += MENU_START_ROW*2;
  x = 10;
  ReefAngel.LCD.Clear(DefaultBGColor,x,y,x+(16*4),y+16);
  pingSerial();
  ReefAngel.LCD.DrawHugeNumbers(T1TempColor, DefaultBGColor, x, y, text);
  pingSerial();  
  x += (16*4) + 8;
  ReefAngel.LCD.DrawText(T2TempColor,DefaultBGColor,8,y+25,"Sump:");
  ReefAngel.LCD.DrawSingleMonitor(ReefAngel.Params.Temp2, T2TempColor, 
24, y+35, 10);
  ReefAngel.LCD.DrawText(T3TempColor,DefaultBGColor,x+8,y+25,"LED:");
  ReefAngel.LCD.DrawSingleMonitor(ReefAngel.Params.Temp3, T3TempColor, 
x+24, y+35, 10);

  //y += 39*2;
 // x = 13;
  byte TempRelay = ReefAngel.Relay.RelayData;
  TempRelay &= ReefAngel.Relay.RelayMaskOff;
  TempRelay |= ReefAngel.Relay.RelayMaskOn;
  ReefAngel.LCD.DrawOutletBox(12, 92, TempRelay);
   // #ifdef RelayExp
  // draw 1st expansion relay
 // TempRelay = ReefAngel.Relay.RelayDataE[0];
 // TempRelay &= ReefAngel.Relay.RelayMaskOffE[0];
//  TempRelay |= ReefAngel.Relay.RelayMaskOnE[0];
 // ReefAngel.LCD.DrawOutletBox(12, 105, TempRelay);
//#endif   RelayExp

  
}
void DrawCustomGraph()
{
}





//*********************************************************************************************************************************
//Start of PWM Expansion Code Header

// This is just how we are going to reference the PWM expansion ports within the code.
// You can change the labels if you would like, just as long as they are changed all throughout the code too.
#define LEDPWM0 0
#define LEDPWM1 1
#define LEDPWM2 2
#define LEDPWM3 3
#define LEDPWM4 4
#define LEDPWM5 5

// Initial values to all 6 channels at startup. They will always be 0.
byte PWMChannel[]={
  0,0,0,0,0,0};

//End of PWM Expansion Code Header

//*********************************************************************************************************************************

void setup()
{

  ReefAngel.Init(); //Initialize controller
  randomSeed(second());

//  setTime(1313771580);  // Unix time
//  now();
//  ReefAngel.RTC.set(now());
  // Ports that are always on
  ReefAngel.Relay.On(Port1);
  ReefAngel.Relay.On(Port5);
  ReefAngel.Relay.On(Port6);
  ReefAngel.Relay.On(Port7);
  ReefAngel.Relay.On(Port8);
}

void loop()
{
  ReefAngel.ShowInterface();

  // Specific functions
  // ReefAngel.StandardLights(Port1,20,00,1,00);
  ReefAngel.SingleATOLow(Port2);
  ReefAngel.StandardLights(Port3,10,30,19,30);
  ReefAngel.StandardLights(Port4,10,00,20,00);
 // ReefAngel.StandardFan(Port8);
  //ReefAngel.PWM.SetActinic(PWMSlope(10,0,20,00,15,100,60,ReefAngel.PWM.GetActinicValue()));

  //ReefAngel.PWM.SetDaylight(PWMSlope(10,30,19,30,15,65,60,ReefAngel.PWM.GetDaylightValue()));
  // Calculate your regular sunrise/sunset PWM value
  PWMChannel[LEDPWM0]=PWMSlope(10,0,20,0,15,100,60,PWMChannel[LEDPWM0]);
  PWMChannel[LEDPWM1]=PWMSlope(10,30,19,30,15,75,60,PWMChannel[LEDPWM1]);
  //PWMChannel[LEDPWM2]=MoonPhase();
  if (hour()>=20 || hour()<1)
  {
    PWMChannel[LEDPWM2]=MoonPhase();
  }
  else
  {
    PWMChannel[LEDPWM2]=0;
  }
  CheckCloud();

  //PWMChannel[LEDPWM3]=PWMSlope(11,0,20,00,0,50,40,PWMChannel[LEDPWM3]);
  //PWMChannel[LEDPWM4]=PWMSlope(11,0,21,30,0,50,40,PWMChannel[LEDPWM4]);
  //PWMChannel[LEDPWM5]=PWMSlope(11,0,20,00,0,50,40,PWMChannel[LEDPWM5]);
  PWMExpansion(LEDPWM0,int(2.55*PWMChannel[LEDPWM0]));
  PWMExpansion(LEDPWM1,int(2.55*PWMChannel[LEDPWM1]));
  PWMExpansion(LEDPWM2,int(2.55*PWMChannel[LEDPWM2]));
  //PWMExpansion(LEDPWM3,int(2.55*PWMChannel[LEDPWM3]));
  //PWMExpansion(LEDPWM4,int(2.55*PWMChannel[LEDPWM2]));
  //PWMExpansion(LEDPWM5,int(2.55*PWMChannel[LEDPWM3]));
//  ReefAngel.LCD.DrawText(0,255,75,120,PWMChannel[LEDPWM1]);
//  ReefAngel.LCD.DrawText(0,255,35,120,PWMChannel[LEDPWM1]);
//  ReefAngel.LCD.DrawText(0,255,65,120,PWMChannel[LEDPWM2]);
//  ReefAngel.LCD.DrawText(0,255,95,120,PWMChannel[LEDPWM3]);
}


//*********************************************************************************************************************************
//Start of PWM slope function code designed for the PWM Expansion module
void PWMExpansion(byte cmd, byte data)
{ 
  Wire.beginTransmission(8); // transmit to device #2
  Wire.send('$'); // sends $ 
  Wire.send('$'); // sends $ 
  Wire.send('$'); // sends $ 
  Wire.send(cmd); // sends a value 
  Wire.send(data); // sends 255 
  Wire.endTransmission(); // stop transmitting
}
//End of PWM slope function code designed for the PWM Expansion module

//*********************************************************************************************************************************

byte MoonPhase()
{
  int m,d,y;
  int yy,mm;
  long K1,K2,K3,J,V;
  byte PWMvalue;
  m=month();
  d=day();
  y=year();
  yy=y-((12-m)/10);
  mm=m+9;
  if (mm>=12) mm-=12;
  K1=365.25*(yy+4712);
  K2=30.6*mm+.5;
  K3=int(int((yy/100)+49)*.75)-38;
  J=K1+K2+d+59-K3;
  V=(J-2451550.1)/0.29530588853;
  V-=int(V/100)*100;
  V=abs(V-50);
  PWMvalue=4*abs(50-V); // 5.12=100% 4=~80%
  //pinMode(lowATOPin,OUTPUT);
  return (PWMvalue*100)/255;
}

//*********************************************************************************************************************************
// Random Cloud/Thunderstorm effects function
void CheckCloud()
{

  // ------------------------------------------------------------
  // Change the values below to customize your cloud/storm effect

  // Frequency in days based on the day of the month - number 2 means every 2 days, for example (day 2,4,6 etc)
  // For testing purposes, you can use 1 and cause the cloud to occur everyday
#define Clouds_Every_X_Days 1 

  // Percentage chance of a cloud happening today
  // For testing purposes, you can use 100 and cause the cloud to have 100% chance of happening
#define Cloud_Chance_per_Day 100

  // Minimum number of minutes for cloud duration
#define Min_Cloud_Duration 3

  // Maximum number of minutes for the cloud duration. Don't use max duration of more than 255
#define Max_Cloud_Duration 10

  // Minimum number of clouds that can happen per day
#define Min_Clouds_per_Day 1

  // Maximum number of clouds that can happen per day
#define Max_Clouds_per_Day 5

  // Only start the cloud effect after this setting
  // In this example, start could after 11:30am
#define Start_Cloud_After NumMins(11,30)

  // Always end the cloud effect before this setting
  // In this example, end could before 8:00pm
#define End_Cloud_Before NumMins(18,30)

  // Percentage chance of a lightning happen for every cloud
  // For testing purposes, you can use 100 and cause the lightning to have 100% chance of happening
#define Lightning_Change_per_Cloud 100

  // Channels used by the actinic LEDs on the PWM Expansion module
  // These channels will not be dimmed when the cloud effect is triggered
  // Number is a binary form. B001100 means channel 2 and 3 are used for actinics
#define Actinic_Channels B000001

  // Channels used by the daylight LEDs on the PWM Expansion module
  // These channels will be used for the spike when lightning effect is triggered
  // Number is a binary form. B000011 means channel 0 and 1 are used for daylights
#define Daylight_Channels B000010

  // Note: Make sure to choose correct values that will work within your PWMSLope settings.
  // For example, in our case, we could have a max of 5 clouds per day and they could last for 50 minutes.
  // Which could mean 250 minutes of clouds. We need to make sure the PWMSlope can accomodate 250 minutes of effects or unforseen resul could happen.
    // Also, make sure that you can fit double those minutes between Start_Cloud_After and End_Cloud_Before.
  // In our example, we have 510 minutes between Start_Cloud_After and End_Cloud_Before, so double the 250 minutes (or 500 minutes) can fit in that 510 minutes window.
    // It's a tight fit, but it did.

    //#define printdebug // Uncomment this for debug print on Serial Monitor window
  #define forcecloudcalculation // Uncomment this to force the cloud calculation to happen in the boot process. 


    // Change the values above to customize your cloud/storm effect
  // ------------------------------------------------------------
  // Do not change anything below here

  static byte cloudchance=255;
  static byte cloudduration=0;
  static int cloudstart=0;
  static byte numclouds=0;
  static byte lightningchance=0;
  static byte cloudindex=0;
  static byte lightningstatus=0;
  static int LastNumMins=0;
  // Every day at midnight, we check for chance of cloud happening today
  if (hour()==0 && minute()==0 && second()==0) cloudchance=255;

#ifdef forcecloudcalculation
    if (cloudchance==255)
#else
    if (hour()==0 && minute()==0 && second()==1 && cloudchance==255) 
#endif
    {
      //Pick a random number between 0 and 99
      cloudchance=random(100); 
      // if picked number is greater than Cloud_Chance_per_Day, we will not have clouds today
      if (cloudchance>Cloud_Chance_per_Day) cloudchance=0;
      // Check if today is day for clouds. 
      if ((day()%Clouds_Every_X_Days)!=0) cloudchance=0; 
      // If we have cloud today
#ifdef printdebug
      Serial.print("Cloud Chance: ");
      Serial.println(cloudchance,DEC);
#endif
      if (cloudchance)
      {
        // pick a random number for number of clouds between Min_Clouds_per_Day and Max_Clouds_per_Day
        numclouds=random(Min_Clouds_per_Day,Max_Clouds_per_Day);
        // pick the time that the first cloud will start
        // the range is calculated between Start_Cloud_After and the even distribuition of clouds on this day. 
        cloudstart=random(Start_Cloud_After,Start_Cloud_After+((End_Cloud_Before-Start_Cloud_After)/(numclouds*2)));
        // pick a random number for the cloud duration of first cloud.
        cloudduration=random(Min_Cloud_Duration,Max_Cloud_Duration);
        //Pick a random number between 0 and 99
        lightningchance=random(100);
        // if picked number is greater than Lightning_Change_per_Cloud, we will not have lightning today
        if (lightningchance>Lightning_Change_per_Cloud) lightningchance=0;

#ifdef printdebug
        Serial.print("Num of Clouds: ");
        Serial.println(numclouds,DEC);
        Serial.print("Cloud Start: ");
        Serial.println(cloudstart,DEC);
        Serial.print("Cloud Start Range: ");
        Serial.print(Start_Cloud_After,DEC);
        Serial.print(" - ");
        Serial.println(Start_Cloud_After+((End_Cloud_Before-Start_Cloud_After)/(numclouds*2)),DEC);
        Serial.print("Cloud Duration: ");
        Serial.println(cloudduration,DEC);
        Serial.print("Lightning Chance: ");
        Serial.println(lightningchance,DEC);
        Serial.print("Lightning at: ");
        Serial.println(cloudstart+(cloudduration/2),DEC);

        time_t t=cloudstart;
        t*=60;
        t+=1311551999;
        setTime(t); // Unix time
        now();
        ReefAngel.RTC.set(now());
        LastNumMins=NumMins(hour(),minute());
        Serial.print("NumMins: ");
        Serial.println(LastNumMins,DEC);
#endif
      }
    }
  // Now that we have all the parameters for the cloud, let's create the effect

  if (cloudchance)
  {
    //is it time for cloud yet?
    if (NumMins(hour(),minute())>=cloudstart && NumMins(hour(),minute())<(cloudstart+cloudduration))
    {
      // let's go through all channels to pick which ones will be dimmed
      for (int a=0;a<6;a++)
      {
        if (bitRead(Actinic_Channels,a)==0)
        {
          // this will slope down the channel from the current PWM to 0 within 3minutes.
          // then it will stay at 0 for the duration of the cycle
          // and finally slope up from 0 to PWM value within 3 minutes
          // it is basically an inversed slope
          PWMChannel[a]-=PWMSlope(cloudstart/60,cloudstart%60,(cloudstart+cloudduration)/60,(cloudstart+cloudduration)%60,0,PWMChannel[a],3,PWMChannel[a]);
#ifdef printdebug
          if (second()==0)
          {
            Serial.print("Dimming Channel ");
            Serial.print(a,DEC);
            Serial.print(" - ");
            Serial.print(PWMChannel[a],DEC);
            Serial.println("%");
          }
          if (lightningchance && (NumMins(hour(),minute())==(cloudstart+(cloudduration/2))) && second()>5) 
          {
            adjustTime(((cloudduration/2)*60)-6);
            Serial.print("Adjusting time to: ");
            Serial.println(now());
          }
#endif
        }
      }
      if (lightningchance && (NumMins(hour(),minute())==(cloudstart+(cloudduration/2))) && second()<5) 
      {
#ifdef printdebug
        Serial.println("Lightning...");
#endif
        for (int b=0;b<6;b++)
        {
          if (bitRead(Daylight_Channels,b)==1)
          {
            if (random(100)<20) lightningstatus=1; 
            else lightningstatus=0;
            if (lightningstatus) PWMChannel[b]=100; 
            else PWMChannel[b]=0;
            //delay(10);
            
#ifdef printdebug
            Serial.print(b,DEC);
            Serial.print(" - ");
            Serial.println(PWMChannel[b],DEC);
#endif
          }
          else
          {
            PWMChannel[b]=20;
          }
        }
      }

#ifdef printdebug
      if ((NumMins(hour(),minute())!=(cloudstart+(cloudduration/2))) && second()==0) 
      {
        adjustTime(((cloudduration/2)*60)-1);
        Serial.print("Adjusting time to: ");
        Serial.println(now());
      }
      if (second()==0) delay(1000);
#endif
    }
    if (NumMins(hour(),minute())>(cloudstart+cloudduration))
    {
      cloudindex++;
      if (cloudindex < numclouds)
      {
        cloudstart=random(Start_Cloud_After+(((End_Cloud_Before-Start_Cloud_After)/(numclouds*2))*cloudindex*2),(Start_Cloud_After+(((End_Cloud_Before-Start_Cloud_After)/(numclouds*2))*cloudindex*2))+((End_Cloud_Before-Start_Cloud_After)/(numclouds*2)));
        // pick a random number for the cloud duration of first cloud.
        cloudduration=random(Min_Cloud_Duration,Max_Cloud_Duration);
        //Pick a random number between 0 and 99
        lightningchance=random(100);
        // if picked number is greater than Lightning_Change_per_Cloud, we will not have lightning today
        if (lightningchance>Lightning_Change_per_Cloud) lightningchance=0;
#ifdef printdebug
        Serial.print("Cloud Start: ");
        Serial.println(cloudstart,DEC);
        Serial.print("Cloud Start Range: ");
        Serial.print(Start_Cloud_After+(((End_Cloud_Before-Start_Cloud_After)/(numclouds*2))*cloudindex*2),DEC);
        Serial.print(" - ");
        Serial.println((Start_Cloud_After+(((End_Cloud_Before-Start_Cloud_After)/(numclouds*2))*cloudindex*2))+((End_Cloud_Before-Start_Cloud_After)/(numclouds*2)),DEC);
        Serial.print("Cloud Duration: ");
        Serial.println(cloudduration,DEC);
        Serial.print("Lightning Chance: ");
        Serial.println(lightningchance,DEC);
        Serial.print("Lightning at: ");
        Serial.println(cloudstart+(cloudduration/2),DEC);

        time_t t=cloudstart;
        t*=60;
        t+=1311551999;
        setTime(t); // Unix time
        now();
        ReefAngel.RTC.set(now());
        LastNumMins=NumMins(hour(),minute());
        Serial.print("NumMins: ");
        Serial.println(LastNumMins,DEC);
#endif
      }
    }
  }
  
  if (LastNumMins!=NumMins(hour(),minute()))
  {
    LastNumMins=NumMins(hour(),minute());
    ReefAngel.LCD.Clear(255,0,115,132,132);
    ReefAngel.LCD.DrawText(0,255,5,115,"C");
    ReefAngel.LCD.DrawText(0,255,11,115,"00:00");
    ReefAngel.LCD.DrawText(0,255,45,115,"L");
    ReefAngel.LCD.DrawText(0,255,51,115,"00:00");
    if (cloudchance && (NumMins(hour(),minute())<cloudstart))
    {
      int x=0;
      if ((cloudstart/60)>=10) x=11; else x=17;
      ReefAngel.LCD.DrawText(0,255,x,115,(cloudstart/60));
      if ((cloudstart%60)>=10) x=29; else x=35;
      ReefAngel.LCD.DrawText(0,255,x,115,(cloudstart%60));
    }
    //ReefAngel.LCD.DrawText(0,255,35,120,cloudstart);
    ReefAngel.LCD.DrawText(0,255,90,115,cloudduration);
    ReefAngel.LCD.DrawText(0,255,110,115,PWMChannel[LEDPWM1]);
    if (lightningchance) 
    {
      int x=0;
      if (((cloudstart+(cloudduration/2))/60)>=10) x=51; else x=57;
      ReefAngel.LCD.DrawText(0,255,x,115,((cloudstart+(cloudduration/2))/60));
      if (((cloudstart+(cloudduration/2))%60)>=10) x=69; else x=75;
      ReefAngel.LCD.DrawText(0,255,x,115,((cloudstart+(cloudduration/2))%60));
    }
#ifdef printdebug
    Serial.print("NumMins: ");
    Serial.println(LastNumMins,DEC);
#endif
  }   
}

mbertalha · Post by **mbertalha** » Thu Sep 01, 2011 2:43 pm

Hi bmhair03,

very good its Main Screen.
which means C11:47 L11:50 7 0???

congratulations

Marcelo

bmhair03 · Post by **bmhair03** » Fri Sep 02, 2011 9:21 am

Its display for the cloud lightning effect.
c=cloud L=lightning.

peitro · Post by **peitro** » Sun Dec 04, 2011 7:55 pm

Here is another display based off of Marcelo's, It adds status of the two float switch relays under the big temperature value. I have my head unit in an area that I cannot get a picture. Feel free to comment or improve on this.

Code: Select all

#include <ReefAngel_Features.h>
#include <ReefAngel_Globals.h>
#include <ReefAngel_Wifi.h>
#include <Wire.h>
#include <OneWire.h>
#include <Time.h>
#include <DS1307RTC.h>
#include <ReefAngel_EEPROM.h>
#include <ReefAngel_NokiaLCD.h>
#include <ReefAngel_ATO.h>
#include <ReefAngel_Joystick.h>
#include <ReefAngel_LED.h>
#include <ReefAngel_TempSensor.h>
#include <ReefAngel_Relay.h>
#include <ReefAngel_PWM.h>
#include <ReefAngel_Timer.h>
#include <ReefAngel_Memory.h>
#include <ReefAngel.h>
#include <avr/pgmspace.h>
#include <ReefAngel_Colors.h>
#include <ReefAngel_CustomColors.h>

// GLOBAL variables for display
int FloatHigh = 0;
int FloatLow = 0;

// custom menu code
void DrawCustomMain()
{
  byte x = 6;
  byte y = 2;
  byte t;
  ReefAngel.LCD.DrawDate(6, 2);
  ReefAngel.LCD.Clear(COLOR_BLACK, 1, 11, 132, 11);
  pingSerial();
  x = 12;
  y += MENU_START_ROW+1;
  ReefAngel.LCD.DrawText(COLOR_BLUE, COLOR_WHITE, x, y+6, "Sump         pH");
  char text[7];
  ConvertNumToString(text, ReefAngel.Params.PH, 100);
  ReefAngel.LCD.Clear(DefaultBGColor, x+16, y+65, x+65, y+16);
  ReefAngel.LCD.DrawLargeText(PHColor, DefaultBGColor, x+75, y+18, text,
Font8x16);
  pingSerial();
  ConvertNumToString(text, ReefAngel.Params.Temp1, 10);
  y += MENU_START_ROW*2;
  x = 10;
  ReefAngel.LCD.Clear(DefaultBGColor,x,y,x+(16*4),y+16);
  pingSerial();
  ReefAngel.LCD.DrawHugeNumbers(T1TempColor, DefaultBGColor, x, y, text);
  pingSerial(); 
  
  ReefAngel.LCD.DrawText(COLOR_BLUE, COLOR_WHITE, x, y+18, "High Float:");
  ConvertNumToString(text, FloatHigh, 1);
  ReefAngel.LCD.DrawLargeText(COLOR_DIMGREY, COLOR_DEEPSKYBLUE, x+5, y+25, text, Font8x16);
  ReefAngel.LCD.DrawText(COLOR_BLUE, COLOR_WHITE, x, y+41, "Low Float:");
  ConvertNumToString(text, FloatLow, 1);
  ReefAngel.LCD.DrawLargeText(COLOR_DIMGREY, COLOR_DEEPSKYBLUE, x+5, y+49, text, Font8x16);
  ReefAngel.LCD.DrawText(COLOR_GREEN, COLOR_WHITE, x, y+65, "0=Empty 1=Full");
  
  x += (16*4) + 8;
  ReefAngel.LCD.DrawText(T2TempColor,DefaultBGColor,x+8,y+25,"Refug:");
  ReefAngel.LCD.DrawSingleMonitor(ReefAngel.Params.Temp2, T2TempColor,
x+24, y+35, 10);
  ReefAngel.LCD.DrawText(T3TempColor,DefaultBGColor,x+8,y+50,"Room:");
  ReefAngel.LCD.DrawSingleMonitor(ReefAngel.Params.Temp3, T3TempColor,
x+24, y+60, 10);

  y += 39*2;
  x = 13;
  byte TempRelay = ReefAngel.Relay.RelayData;
  TempRelay &= ReefAngel.Relay.RelayMaskOff;
  TempRelay |= ReefAngel.Relay.RelayMaskOn;
  ReefAngel.LCD.DrawOutletBox(x, y, TempRelay);
 
}
void DrawCustomGraph()
{
}

Add this into your loop

Code: Select all

      // variables used for display
        FloatLow = digitalRead(lowATOPin);
        FloatHigh = digitalRead(highATOPin);

psyrob · Post by **psyrob** » Fri Dec 09, 2011 9:34 pm

Here is my humble attempt at a custom screen....thanks to all who do hard work coding for us newbies to Arduino coding...I am getting real good at cutting and pasting all the good work you do, and I can do some giggling of code, but without you all who know the nitty-gritty of writing the code, I would be lost...

Sorry for the junky iphone pic, it is the best I could get...

psyrob · Post by **psyrob** » Fri Dec 09, 2011 9:42 pm

Here is my PDE

Code: Select all

void DrawCustomMain()
{
byte x = 6;
byte y = 2;
byte t;
ReefAngel.LCD.DrawLargeText(COLOR_DARKTURQUOISE, COLOR_WHITE, 6, 2, "Rob's ReefAngel");
ReefAngel.LCD.DrawDate(6, 118);
ReefAngel.LCD.Clear(COLOR_BLACK, 1, 17, 132, 17);
pingSerial();
x = 12;
y += MENU_START_ROW+1;
ReefAngel.LCD.DrawText(COLOR_BLUE, COLOR_WHITE, x, y+6, "Display       PH");
char text[7];
ConvertNumToString(text, ReefAngel.Params.PH, 100);
ReefAngel.LCD.Clear(DefaultBGColor, x+16, y+65, x+65, y+16);
ReefAngel.LCD.DrawLargeText(PHColor, DefaultBGColor, x+75, y+18, text);
pingSerial();

ConvertNumToString(text, ReefAngel.Params.Temp1, 10);
y += MENU_START_ROW*2;
x = 10;
ReefAngel.LCD.Clear(DefaultBGColor,x,y,x+(16*4),y+16);
pingSerial();
ReefAngel.LCD.DrawHugeNumbers(T1TempColor, DefaultBGColor, x, y, text);
pingSerial(); 
x += (16*4) + 8;
ReefAngel.LCD.DrawText(T2TempColor,DefaultBGColor,8,y+25,"ROOM:");
ReefAngel.LCD.DrawSingleMonitor(ReefAngel.Params.Temp2, T2TempColor, 
9, y+35, 10);
ReefAngel.LCD.DrawText(T3TempColor,DefaultBGColor,x+8,y+25,"FRAG:");
ReefAngel.LCD.DrawSingleMonitor(ReefAngel.Params.Temp3, T3TempColor, 
x+9, y+35, 10);


byte TempRelay = ReefAngel.Relay.RelayData;
TempRelay &= ReefAngel.Relay.RelayMaskOff;
TempRelay |= ReefAngel.Relay.RelayMaskOn;
ReefAngel.LCD.DrawOutletBox(12, 93, TempRelay);



}

void DrawCustomGraph()
{
}

binder · Post by **binder** » Fri Dec 09, 2011 9:53 pm

Nice. Looks good. Good job.

curt

rimai · Post by **rimai** » Sat Dec 10, 2011 9:35 am

I like it

Deckoz2302 · Post by **Deckoz2302** » Sat Dec 17, 2011 7:04 pm

how come I always get 'class ReefAngel_NokiaLCD' has no class named 'DrawLargeText'?

rimai · Post by **rimai** » Sat Dec 17, 2011 7:41 pm

You need to pick the size of font you want to use and define it in the features file.
Either of these 2:

Code: Select all

#define FONT_8x8
#define FONT_8x16

Take a look at the manual for more info:
http://forum.reefangel.com/viewtopic.php?p=653#p653

Deckoz2302 · Post by **Deckoz2302** » Sat Dec 31, 2011 6:37 pm

Code: Select all

//*********************************************************************************************************************************
//Custom Main, Graph & Menu
void DrawCustomMain()
{
  Wire.requestFrom(8,8);
  for (int a=0;a<8;a++)
  {
    if (Wire.available()) SeasonsVar[a]=Wire.receive();
  }

  byte x = 6;
  byte y = 2;
  byte t;
  char text[7];

  ReefAngel.LCD.DrawDate(6, 2);
  ReefAngel.LCD.Clear(COLOR_BLACK, 1, 11, 132, 11);
  pingSerial();

  ReefAngel.LCD.DrawText(COLOR_TOMATO,255, 6, 90, "--------------------");
  ReefAngel.LCD.DrawText(COLOR_TOMATO,255, 6, 126, "--------------------");
  ReefAngel.LCD.DrawText(COLOR_TOMATO,255, 2, 93, "|");
  ReefAngel.LCD.DrawText(COLOR_TOMATO,255, 2, 103, "|");
  ReefAngel.LCD.DrawText(COLOR_TOMATO,255, 2, 113, "|");
  ReefAngel.LCD.DrawText(COLOR_TOMATO,255, 2, 123, "|");
  ReefAngel.LCD.DrawText(COLOR_TOMATO,255, 126, 93, "|");
  ReefAngel.LCD.DrawText(COLOR_TOMATO,255, 126, 103, "|");
  ReefAngel.LCD.DrawText(COLOR_TOMATO,255, 126, 113, "|");
  ReefAngel.LCD.DrawText(COLOR_TOMATO,255, 126, 123, "|");


  ReefAngel.LCD.DrawText(0,255,18,12,"EcoSmart Vortech");
  if (vtechmode == 0) ReefAngel.LCD.DrawLargeText(COLOR_LIMEGREEN,255,35,22,"Constant");
  else if(vtechmode == 1) ReefAngel.LCD.DrawLargeText(COLOR_GOLD,255,42,21,"Lagoon");
  else if (vtechmode == 2) ReefAngel.LCD.DrawLargeText(COLOR_GOLD,255,25,21,"Reef Crest");
  else if (vtechmode == 3) ReefAngel.LCD.DrawLargeText(COLOR_CORNFLOWERBLUE,255,22,21,"Short Pulse");
  else if (vtechmode == 4) ReefAngel.LCD.DrawLargeText(COLOR_PINK,255,25,21,"Long Pulse");
  else if (vtechmode == 5) ReefAngel.LCD.DrawLargeText(COLOR_MAGENTA,255,8,21,"Nutrient Trnsp.");
  else if (vtechmode == 6) ReefAngel.LCD.DrawLargeText(COLOR_MAGENTA,255,23,21,"Tidal Swell");
  else if (vtechmode == 9) ReefAngel.LCD.DrawLargeText(COLOR_WHITE,0,45,21,"Night");

  ReefAngel.LCD.DrawText(0,255,10,30,"Display");
  ConvertNumToString(text, ReefAngel.Params.Temp1, 10);
  ReefAngel.LCD.DrawLargeText(COLOR_INDIANRED, 255, 10, 40, text, Num8x8);
  pingSerial();

  ReefAngel.LCD.DrawText(0,255,100,30,"pH");
  ConvertNumToString(text, ReefAngel.Params.PH, 100);
  ReefAngel.LCD.DrawLargeText(COLOR_PLUM, 255, 85, 40, text, Num8x8);
  pingSerial();

  ReefAngel.LCD.DrawText(0,255,43,48,"Salinity");
  ConvertNumToString(text, ReefAngel.Params.Salinity, 100);
  ReefAngel.LCD.DrawLargeText(COLOR_LIMEGREEN, 255, 49, 58, text, Num8x8);
  pingSerial();

  pingSerial();
  byte TempRelay = ReefAngel.Relay.RelayData;
  TempRelay &= ReefAngel.Relay.RelayMaskOff;
  TempRelay |= ReefAngel.Relay.RelayMaskOn;
  ReefAngel.LCD.DrawOutletBox(12, 77, TempRelay);

  ReefAngel.LCD.DrawText(0,255,8,68,"Sump");
  ReefAngel.LCD.DrawSingleMonitor(ReefAngel.Params.Temp3, COLOR_CORNFLOWERBLUE, 40, 68, 10);

  ReefAngel.LCD.DrawText(0,255,70,68,"Room");
  ReefAngel.LCD.DrawSingleMonitor(ReefAngel.Params.Temp2, COLOR_CORNFLOWERBLUE, 99, 68, 10);

  ReefAngel.LCD.DrawText(0,255,8,97,"Moon");
  DayAge = MoonAge(day(), month(), year());
  MoonState(DayAge);
  if (ThisPhase == 0) ReefAngel.LCD.DrawText(COLOR_CORNFLOWERBLUE,255,35,97,"New");
  else if (ThisPhase == 1) ReefAngel.LCD.DrawText(COLOR_CORNFLOWERBLUE,255,35,97,"Waxing Crescent");
  else if (ThisPhase == 2) ReefAngel.LCD.DrawText(COLOR_CORNFLOWERBLUE,255,35,97,"First Quarter");
  else if (ThisPhase == 3) ReefAngel.LCD.DrawText(COLOR_CORNFLOWERBLUE,255,35,97,"Waxing Gibbous");
  else if (ThisPhase == 4) ReefAngel.LCD.DrawText(COLOR_CORNFLOWERBLUE,255,35,97,"Full");
  else if (ThisPhase == 5) ReefAngel.LCD.DrawText(COLOR_CORNFLOWERBLUE,255,35,97,"Waning Gibbous");
  else if (ThisPhase == 6) ReefAngel.LCD.DrawText(COLOR_CORNFLOWERBLUE,255,35,97,"Last Quarter");
  else if (ThisPhase == 7) ReefAngel.LCD.DrawText(COLOR_CORNFLOWERBLUE,255,35,97,"Waning Crescent");

  //  ReefAngel.LCD.DrawSingleMonitor(ReefAngel.PWM.GetActinicValue(),COLOR_CORNFLOWERBLUE, 105, 109, 1);  

  ReefAngel.LCD.DrawText(0,255,8,109, "Sunrise");  
  ReefAngel.LCD.DrawText(COLOR_CORNFLOWERBLUE,255,15,119, SeasonsVar[1]);
  ReefAngel.LCD.DrawText(COLOR_CORNFLOWERBLUE,255,20,119, ":");
  ReefAngel.LCD.DrawText(COLOR_CORNFLOWERBLUE,255,25,119, SeasonsVar[2]);

  ReefAngel.LCD.DrawText(0,255,75,109,"%");
  ReefAngel.LCD.DrawText(COLOR_CORNFLOWERBLUE,255, 60, 109, SeasonsVar[0]);

  ReefAngel.LCD.DrawText(0,255,88,109, "Sunset");  
  ReefAngel.LCD.DrawText(COLOR_CORNFLOWERBLUE,255,90,119, SeasonsVar[3]);
  ReefAngel.LCD.DrawText(COLOR_CORNFLOWERBLUE,255,102,119, ":");
  ReefAngel.LCD.DrawText(COLOR_CORNFLOWERBLUE,255,107,119, SeasonsVar[4]); 
}
void DrawCustomGraph()
{
}

rimai · Post by **rimai** » Sat Dec 31, 2011 7:30 pm

I love this screen!!!

Deckoz2302 · Post by **Deckoz2302** » Sat Dec 31, 2011 7:45 pm

Thanks man, I worked on it all day haha, nudging each thing around to make it perfect - ps all of the ecotech modes are centered when theyre called and the color of the vortech mode matches the driver

wolfador · Post by **wolfador** » Sat Dec 31, 2011 8:28 pm

very nice screen!

psyrob · Post by **psyrob** » Sat Dec 31, 2011 10:40 pm

Great screen!! Hey, where in your code does it make the relay box be blue and white instead of the standard red/black? I can't figure it out...

binder · Post by **binder** » Sat Dec 31, 2011 11:49 pm

psyrob wrote:Great screen!! Hey, where in your code does it make the relay box be blue and white instead of the standard red/black? I can't figure it out...

depends on how you want to do it. the values are stored in reefangel_globals.h or you can enable the colors file.

curt

Deckoz2302 · Post by **Deckoz2302** » Sun Jan 01, 2012 7:49 am

Like binder said - I edited the colors through globals.h

binder · Post by **binder** » Sun Jan 01, 2012 7:58 am

use caution with editing the globals.h file, that file gets updated with new releases of the libraries. the recommended way is to use the colors file.

curt

Deckoz2302 · Post by **Deckoz2302** » Sun Jan 01, 2012 8:26 am

hmmm yea i forgot that - come to think of it now that I went and looked at it, I did use colors. But I found out what colors were available/preprogrammed by looking at globals.h

binder · Post by **binder** » Sun Jan 01, 2012 12:31 pm

Deckoz2302 wrote:hmmm yea i forgot that - come to think of it now that I went and looked at it, I did use colors. But I found out what colors were available/preprogrammed by looking at globals.h

ReefAngel_Colors.h contains a list of the colors in it's own file (same as Globals.h, there's a reason why it's like this).
ReefAngel_CustomColors.h is the file that you can make your changes to.

If using those files, they must be included into your PDE file and also the Features.h file needs to have the #define CUSTOM_COLORS in it.

curt

Reef Angel Forum

Custom Main Screens

Re: Custom Menu

Re: Custom Menu

Re: Custom Main Screens

Re: Custom Main Screens

Re: Custom Main Screens

Re: Custom Main Screens

Re: Custom Main Screens

Re: Custom Main Screens

Re: Custom Main Screens

Re: Custom Main Screens

Re: Custom Main Screens

Re: Custom Main Screens

Re: Custom Main Screens

Re: Custom Main Screens

Re: Custom Main Screens

Re: Custom Main Screens

Re: Custom Main Screens

Re: Custom Main Screens

Re: Custom Main Screens

Re: Custom Main Screens

Re: Custom Main Screens

Re: Custom Main Screens

Re: Custom Main Screens

Re: Custom Main Screens

Re: Custom Main Screens

Re: Custom Main Screens

Re: Custom Main Screens

Re: Custom Main Screens

Re: Custom Main Screens

Re: Custom Main Screens

Login • Register