New to code ra and controls

Request new hardware or ideas for the controller
User avatar
lnevo
Posts: 5430
Joined: Fri Jul 20, 2012 9:42 am

Re: New to code ra and controls

Post by lnevo »

Ok that's because you need to setup port forwarding still. You need to make sure your wifi module gets a static dhcp reservation from your router and that you are forwarding port 2000 to the wifi module IP on port 2000.
User avatar
lnevo
Posts: 5430
Joined: Fri Jul 20, 2012 9:42 am

Re: New to code ra and controls

Post by lnevo »

Actually there's an issue with the way I did the high ato. I'll post a fix later for you.
troylong45
Posts: 214
Joined: Sat Oct 10, 2015 9:17 pm

Re: New to code ra and controls

Post by troylong45 »

Ok I changed the ddns to troylong45 and edited the "you can go to blah blah blah " stuff at the end of the code. Does my portal automatically find my reefangel .
So all I need to do now is figure out how to change port forwarding on my router like u mentioned I'll probably have to call my Internet provider it's there router/modem
Image
troylong45
Posts: 214
Joined: Sat Oct 10, 2015 9:17 pm

Re: New to code ra and controls

Post by troylong45 »

The high ato seems to work for the skimmer. Now keep this in mind though I haven't connected anything to the ra yet just to be safe lol
Image
User avatar
lnevo
Posts: 5430
Joined: Fri Jul 20, 2012 9:42 am

Re: New to code ra and controls

Post by lnevo »

It works but the relay status is currently tied directly to the float switch which could be bad too because skimmer goes off water level rises float switch turns skimmer back on, etc. you wanted an override so you would manually have to trigger it back on. If your using it in the collection cup then wouldn't really be a problem.
troylong45
Posts: 214
Joined: Sat Oct 10, 2015 9:17 pm

Re: New to code ra and controls

Post by troylong45 »

Well right now just going to use it to turn off skimmer like if the return stops for whatever reason it won't keep filling the cup or if power outage the skimmer won't Come on till the water level falls to proper level. I think I'm OK without a override for now.
Image
User avatar
lnevo
Posts: 5430
Joined: Fri Jul 20, 2012 9:42 am

Re: New to code ra and controls

Post by lnevo »

Yup should be fine then for now.
troylong45
Posts: 214
Joined: Sat Oct 10, 2015 9:17 pm

Re: New to code ra and controls

Post by troylong45 »

i dont think the white ch dimming expansion 1 is operating properly ill give it a day or 2 to get a graph of dimming 0 and 1 and relay 1 and relay 2

i think i got fowarding done on router it asked for

Local IP 192.168.0.18
Local Start Port 2000
Local End Port 2000
External IP 0.0.0.0
External Start Port 2000
External End Port 2000
Protocol both tcp/udp
Description moms tank
Enabled yes

i get this in portal
Reef Angel

Reef Angel wifi address:
My reefangelid: troylong45
Connection Status: Unreachable Address

Last Update: 10/18/2015, 5:57:42 PM
Displaying data from: Webbanner database

and if i try to switch things of view internal memory still says
Only available with valid wifi address. Please make sure your controller is sending data to the Portal web server.


i added this to end of code for the ip stuff does all this seem right

Code: Select all

        // This should always be the last line
        ReefAngel.Portal( "troylong45" );
        ReefAngel.DDNS( "reef" ); // Your DDNS is troylong45-reef.myreefangel.com
        ReefAngel.ShowInterface();
Image
User avatar
lnevo
Posts: 5430
Joined: Fri Jul 20, 2012 9:42 am

Re: New to code ra and controls

Post by lnevo »

Local ip needs to point to ip of wifi module. That message means your forwarding isnt yet working. The basis for the lights depends immensely on the memory variables you've set. Without the wifi forwarding happening we won't be able to validate that.
troylong45
Posts: 214
Joined: Sat Oct 10, 2015 9:17 pm

Re: New to code ra and controls

Post by troylong45 »

The local ip is the one of the ra. So forwarding isn't set in my router correctly yet then huh. Here's what I did start to finish.
I used the wifi tool to configure the wife add on just like the wifi manual said, added the code to the ra with the Androino schetch uploader , and that was it then the router stuff. There isn't anything here in the forum I setup right. Like profile or something for the portal. From all this info I gave u still points to properly setting router port forwarding right ?
Image
User avatar
lnevo
Posts: 5430
Joined: Fri Jul 20, 2012 9:42 am

Re: New to code ra and controls

Post by lnevo »

Yep
troylong45
Posts: 214
Joined: Sat Oct 10, 2015 9:17 pm

Re: New to code ra and controls

Post by troylong45 »

K my Internet provider hopefully will walk me through it. It's there router lol
Image
troylong45
Posts: 214
Joined: Sat Oct 10, 2015 9:17 pm

Re: New to code ra and controls

Post by troylong45 »

yea got it Reef Angel wifi address: 98.157.208.157:2000
My reefangelid:
troylong45
Connection Status:
Ready

Last Update:
10/20/2015, 7:17:28 PM
Displaying data from:
Reef Angel Controller (live)

now i need to see what the dimming does i think it was not working right
Image
User avatar
lnevo
Posts: 5430
Joined: Fri Jul 20, 2012 9:42 am

Re: New to code ra and controls

Post by lnevo »

Awesome. Start by reviewing the settings in memory and then we can re-review the code. I dont think your code is setting all your channels well. Would be good to know how your mapping your channels and ports so if you can post that at some point it will help.

You can do the following to see graphs of your pwm values:

http://forum.reefangel.com/status/chart ... lter=pwme3
troylong45
Posts: 214
Joined: Sat Oct 10, 2015 9:17 pm

Re: New to code ra and controls

Post by troylong45 »

ill let it run for a day or 2 and check the gragh
Image
troylong45
Posts: 214
Joined: Sat Oct 10, 2015 9:17 pm

Re: New to code ra and controls

Post by troylong45 »

if i set the time for lights on and off for internal memory that gets overridden by the sunrise code ? will the sunrise code with geological coordinates reflect in the graph for relays and dimming .and clouds and lighting reflect in the dimming graph ?
Image
User avatar
lnevo
Posts: 5430
Joined: Fri Jul 20, 2012 9:42 am

Re: New to code ra and controls

Post by lnevo »

It really depends on the code. The SunLocation will set the start time and end time for StandardLights. ActinicLights is based off of that using the ActinicOffset value. We can adjust the time in the code by setting the offsets for rise and set.

These times will also affect when the StanardLights turns on the relays.

Code: Select all

    ReefAngel.ActinicLights( Port1 );
    ReefAngel.DayLights( Port2 );
The dimming is controlled by these statements

Code: Select all

    ReefAngel.PWM.Channel0PWMParabola();
    ReefAngel.PWM.Channel1PWMParabola();
But are you only using 2 channels? I'd still like to understand the layout of your connections and how many boxes your controlling...

So the code above will set the dimming based on what youre seeing in Internal Memory, however then you do this:

Code: Select all

    DaylightPWMValue=PWMSlopeHighRes(10,30,22,0,0,30,240,0);
Which is hard-coding the pwmslope to those times and percentages. What I would do is replace that with

Code: Select all

DaylightPWMValue=GetChannelValueRaw(1);
After that, the CheckCloud() function gets run which uses the DaylightPWMValue to figure out what to set the clouds too. It then updates the channel with the next line

Code: Select all

ReefAngel.PWM.SetChannelRAW(1,DaylightPWMValue);
So you have quite a few things going on and mixing hard coded with set values. I think the recommendation above will help make things clearer, but not sure what you're seeing off at the moment. If the times your seeing that get updated in the InternalMemory aren't what you want then either adjust the GPS coordinates, or do this to change the offset

Code: Select all

sun.setOffset(1,-1); // this will add an hour to the sunrise and remove an hour from sunset
Somethign to keep in mind which gets confusing. The RA has no concept of TimeZone so it thinks that it is GMT which can make it a little confusing from what the expectations might be. So like I said, let's discuss what you're actually seeing and what you want to get it to.
User avatar
lnevo
Posts: 5430
Joined: Fri Jul 20, 2012 9:42 am

Re: New to code ra and controls

Post by lnevo »

Ok here's a correction for the PWM graph link I put up before

http://forum.reefangel.com/status/chart ... lter=pwme1

I can see now a bit what's going on.. it does look the cloud stuff is working. The only wierdness was the channel going to 32% all night long and I believe that's because of the statement I mentioned that used hard coded settings.

Try this:

Code: Select all

#include <ReefAngel_Features.h>
#include <Globals.h>
#include <RA_Wifi.h>
#include <Wire.h>
#include <OneWire.h>
#include <Time.h>
#include <DS1307RTC.h>
#include <InternalEEPROM.h>
#include <RA_NokiaLCD.h>
#include <RA_ATO.h>
#include <RA_Joystick.h>
#include <LED.h>
#include <RA_TempSensor.h>
#include <Relay.h>
#include <RA_PWM.h>
#include <Timer.h>
#include <Memory.h>
#include <InternalEEPROM.h>
#include <RA_Colors.h>
#include <RA_CustomColors.h>
#include <Salinity.h>
#include <RF.h>
#include <IO.h>
#include <ORP.h>
#include <AI.h>
#include <PH.h>
#include <WaterLevel.h>
#include <Humidity.h>
#include <DCPump.h>
#include <PAR.h>
#include <ReefAngel.h>
#include <SunLocation.h>

////// Place global variable code below here
SunLocation sun;
int DaylightPWMValue=0;        // For cloud code
int Latitude=-18;
int Longitude=147;

////// Place global variable code above here


void setup()
{
    // This must be the first line
    ReefAngel.Init();  //Initialize controller
    ReefAngel.Use2014Screen();  // Let's use 2014 Screen 
    // Ports toggled in Feeding Mode
    ReefAngel.FeedingModePorts = Port3Bit | Port4Bit | Port5Bit | Port6Bit | Port7Bit | Port8Bit;
    // Ports toggled in Water Change Mode
    ReefAngel.WaterChangePorts = Port3Bit | Port4Bit | Port5Bit | Port6Bit | Port7Bit | Port8Bit;
    // Ports toggled when Lights On / Off menu entry selected
    ReefAngel.LightsOnPorts = Port1Bit | Port2Bit;
    // Ports turned off when Overheat temperature exceeded
    ReefAngel.OverheatShutoffPorts = Port6Bit;
    // Use T1 probe as temperature and overheat functions
    ReefAngel.TempProbe = T1_PROBE;
    ReefAngel.OverheatProbe = T1_PROBE;


    // Ports that are always on

    ////// Place additional initialization code below here
    sun.Init(Latitude,Longitude); 

    ////// Place additional initialization code above here
}

    void CheckCloud()
    {
      // ------------------------------------------------------------
      // Change the values below to customize your cloud/storm effect

      // Frequency in days based on the day of the month - number 2 means every 2 days, for example (day 2,4,6 etc)
      // For testing purposes, you can use 1 and cause the cloud to occur everyday
    #define Clouds_Every_X_Days 1

      // Percentage chance of a cloud happening today
      // For testing purposes, you can use 100 and cause the cloud to have 100% chance of happening
    #define Cloud_Chance_per_Day 100

      // Minimum number of minutes for cloud duration.  Don't use max duration of less than 6
    #define Min_Cloud_Duration 7

      // Maximum number of minutes for the cloud duration. Don't use max duration of more than 255
    #define Max_Cloud_Duration 7

      // Minimum number of clouds that can happen per day
    #define Min_Clouds_per_Day 1

      // Maximum number of clouds that can happen per day
    #define Max_Clouds_per_Day 2

      // Only start the cloud effect after this setting
      // In this example, start cloud after noon
    #define Start_Cloud_After NumMins(12,00)

      // Always end the cloud effect before this setting
      // In this example, end cloud before 9:00pm
    #define End_Cloud_Before NumMins(21,00)

      // Percentage chance of a lightning happen for every cloud
      // For testing purposes, you can use 100 and cause the lightning to have 100% chance of happening
    #define Lightning_Change_per_Cloud 100

      // Note: Make sure to choose correct values that will work within your PWMSLope settings.
      // For example, in our case, we could have a max of 5 clouds per day and they could last for 50 minutes.
      // Which could mean 250 minutes of clouds. We need to make sure the PWMSlope can accomodate 250 minutes
      // of effects or unforseen result could happen.
      // Also, make sure that you can fit double those minutes between Start_Cloud_After and End_Cloud_Before.
      // In our example, we have 510 minutes between Start_Cloud_After and End_Cloud_Before, so double the
      // 250 minutes (or 500 minutes) can fit in that 510 minutes window.
      // It's a tight fit, but it did.

      //#define printdebug // Uncomment this for debug print on Serial Monitor window
    #define forcecloudcalculation // Uncomment this to force the cloud calculation to happen in the boot process.

      // Add Random Lightning modes
    #define Calm 0    // No lightning
    #define Slow 1    // 5 seconds of slow lightning in the middle of a cloud for ELN style (slow response) drivers
    #define Fast 2    // 5 seconds of fast lightning in the middle of a cloud for LDD style (fast response) drivers
    #define Mega 3    // Lightning throughout the cloud, higher chance as it gets darker
    #define Mega2 4   // Like Mega, but with more lightning
      // Set which modes you want to use
      // Example:  { Calm, Fast, Mega, Mega2 } to randomize all four modes. 
      // { Mega2 } for just Mega2.  { Mega, Mega, Fast} for Mega and Fast, with twice the chance of Mega.
      byte LightningModes[] = {Mega2,Mega,Mega};

      // Change the values above to customize your cloud/storm effect
      // ------------------------------------------------------------
      // Do not change anything below here

      static byte cloudchance=255;
      static byte cloudduration=0;
      static int cloudstart=0;
      static byte numclouds=0;
      static byte lightningchance=0;
      static byte cloudindex=0;
      static byte lightningstatus=0;
      static int LastNumMins=0;
      static byte lightningMode=0;
      static boolean chooseLightning=true;

      static time_t DelayCounter=millis();    // Variable for lightning timing. 
      static int DelayTime=random(1000);      // Variable for lightning timimg.

      // Every day at midnight, we check for chance of cloud happening today
      if (hour()==0 && minute()==0 && second()==0) cloudchance=255;

    #ifdef forcecloudcalculation
      if (cloudchance==255)
    #else
        if (hour()==0 && minute()==0 && second()==1 && cloudchance==255)
    #endif
        {
          randomSeed(millis());    // Seed the random number generator
          //Pick a random number between 0 and 99
          cloudchance=random(100);
          // if picked number is greater than Cloud_Chance_per_Day, we will not have clouds today
          if (cloudchance>Cloud_Chance_per_Day) cloudchance=0;
          // Check if today is day for clouds.
          if ((day()%Clouds_Every_X_Days)!=0) cloudchance=0;
          // If we have cloud today
          if (cloudchance)
          {
            // pick a random number for number of clouds between Min_Clouds_per_Day and Max_Clouds_per_Day
            numclouds=random(Min_Clouds_per_Day,Max_Clouds_per_Day);
            // pick the time that the first cloud will start
            // the range is calculated between Start_Cloud_After and the even distribuition of clouds on this day.
            cloudstart=random(Start_Cloud_After,Start_Cloud_After+((End_Cloud_Before-Start_Cloud_After)/(numclouds*2)));
            // pick a random number for the cloud duration of first cloud.
            cloudduration=random(Min_Cloud_Duration,Max_Cloud_Duration);
            //Pick a random number between 0 and 99
            lightningchance=random(100);
            // if picked number is greater than Lightning_Change_per_Cloud, we will not have lightning today
            if (lightningchance>Lightning_Change_per_Cloud) lightningchance=0;
          }
        }
      // Now that we have all the parameters for the cloud, let's create the effect


      if (cloudchance)
      {
        //is it time for cloud yet?
        if (NumMins(hour(),minute())>=cloudstart && NumMins(hour(),minute())<(cloudstart+cloudduration))
        {
          DaylightPWMValue=ReversePWMSlope(cloudstart,cloudstart+cloudduration,DaylightPWMValue/40.95,0,180)*40.95;
          if (chooseLightning)
          {
            lightningMode=LightningModes[random(100)%sizeof(LightningModes)];
            chooseLightning=false;
          }
          switch (lightningMode)
          {
          case Calm:
            break;
          case Mega:
            // Lightning chance from beginning of cloud through the end.  Chance increases with darkness of cloud.
            if (lightningchance && random(ReversePWMSlope(cloudstart,cloudstart+cloudduration,100,0,180))<1 && (millis()-DelayCounter)>DelayTime)
            {
              // Send the trigger
              Strike();
              DelayCounter=millis();    // If we just had a round of flashes, then lets put in a longer delay
              DelayTime=random(1000);   // of up to a second for dramatic effect before we do another round.
            }
            break;
          case Mega2:
            // Higher lightning chance from beginning of cloud through the end.  Chance increases with darkness of cloud.
            if (lightningchance && random(ReversePWMSlope(cloudstart,cloudstart+cloudduration,100,0,180))<2)
            {
              Strike();
            }
            break;
          case Fast:
            // 5 seconds of lightning in the middle of the cloud
            if (lightningchance && (NumMins(hour(),minute())==(cloudstart+(cloudduration/2))) && second()<5 && (millis()-DelayCounter)>DelayTime)
            {
              Strike();

              DelayCounter=millis();    // If we just had a round of flashes, then lets put in a longer delay
              DelayTime=random(1000);   // of up to a second for dramatic effect before we do another round.
            }
            break;
          case Slow:
            // Slow lightning for 5 seconds in the middle of the cloud.  Suitable for slower ELN style drivers
            if (lightningchance && (NumMins(hour(),minute())==(cloudstart+(cloudduration/2))) && second()<5)
            {
              if (random(100)<20) lightningstatus=1;
              else lightningstatus=0;
              if (lightningstatus)
              {
                DaylightPWMValue=4095;
              }
              else
              {
                DaylightPWMValue=0;
              }
              delay(1);
            }
            break;
          default:
            break;
          }
        }
        else
        {
          chooseLightning=true; // Reset the flag to choose a new lightning type
        }

        if (NumMins(hour(),minute())>(cloudstart+cloudduration))
        {
          cloudindex++;
          if (cloudindex < numclouds)
          {
            cloudstart=random(Start_Cloud_After+(((End_Cloud_Before-Start_Cloud_After)/(numclouds*2))*cloudindex*2),(Start_Cloud_After+(((End_Cloud_Before-Start_Cloud_After)/(numclouds*2))*cloudindex*2))+((End_Cloud_Before-Start_Cloud_After)/(numclouds*2)));
            // pick a random number for the cloud duration of first cloud.
            cloudduration=random(Min_Cloud_Duration,Max_Cloud_Duration);
            //Pick a random number between 0 and 99
            lightningchance=random(100);
            // if picked number is greater than Lightning_Change_per_Cloud, we will not have lightning today
            if (lightningchance>Lightning_Change_per_Cloud) lightningchance=0;
          }
        }
      }

      // Write the times of the next cloud, next lightning, and cloud duration to the screen and into some customvars for the Portal.
      if (LastNumMins!=NumMins(hour(),minute()))
      {
        LastNumMins=NumMins(hour(),minute());
        /*ReefAngel.LCD.Clear(255,0,120,132,132);
         ReefAngel.LCD.DrawText(0,255,5,120,"C");
         ReefAngel.LCD.DrawText(0,255,11,120,"00:00");
         ReefAngel.LCD.DrawText(0,255,45,120,"L");
         ReefAngel.LCD.DrawText(0,255,51,120,"00:00"); */
        if (cloudchance && (NumMins(hour(),minute())<cloudstart))
        {
          int x=0;
          if ((cloudstart/60)>=10) x=11;
          else x=17;
          //ReefAngel.LCD.DrawText(0,255,x,120,(cloudstart/60));
          ReefAngel.CustomVar[3]=cloudstart/60; // Write the hour of the next cloud to custom variable for Portal reporting
          if ((cloudstart%60)>=10) x=29;
          else x=35;
          //ReefAngel.LCD.DrawText(0,255,x,120,(cloudstart%60));
          ReefAngel.CustomVar[4]=cloudstart%60; // Write the minute of the next cloud to custom variable for Portal reporting

        }
        //ReefAngel.LCD.DrawText(0,255,90,120,cloudduration);
        ReefAngel.CustomVar[7]=(cloudduration);    // Put the duration of the next cloud in a custom var for the portal
        if (lightningchance)
        {
          int x=0;
          if (((cloudstart+(cloudduration/2))/60)>=10) x=51;
          else x=57;
          //ReefAngel.LCD.DrawText(0,255,x,120,((cloudstart+(cloudduration/2))/60));
          ReefAngel.CustomVar[5]=(cloudstart+(cloudduration/2))/60;    // Write the hour of the next lightning to a custom variable for the Portal
          if (((cloudstart+(cloudduration/2))%60)>=10) x=69;
          else x=75;
          //ReefAngel.LCD.DrawText(0,255,x,120,((cloudstart+(cloudduration/2))%60)); // Write the minute of the next lightning to a custom variable for the Portal
            ReefAngel.CustomVar[6]=(cloudstart+(cloudduration/2))%60;
        }
      }   
    }

    void Strike()
    {
      int a=random(1,5);    // Pick a number of consecutive flashes from 1 to 4. 
      for (int i=0; i<a; i++)
      {
        // Flash on
        int newdata=4095;
        Wire.beginTransmission(0x40);      // Address of the dimming expansion module
        Wire.write(0x8+(4*1));             // 0x8 is channel 0, 0x12 is channel 1, etc.  I'm using channel 1.
        Wire.write(newdata&0xff);          // Send the data 8 bits at a time.  This sends the LSB
        Wire.write(newdata>>8);            // This sends the MSB
        Wire.endTransmission();
       
        int randy=random(20,80);    // Random number for a delay
        if (randy>71) randy=((randy-70)/2)*100;    // Small chance of a longer delay
        delay(randy);                // Wait from 20 to 69 ms, or 100-400 ms
       
        // Flash off.  Return to baseline.
        newdata=ReefAngel.PWM.GetChannelValueRaw(1);   // Use the channel number you're flashing here
        Wire.beginTransmission(0x40);    // Same as above
        Wire.write(0x8+(4*1));
        Wire.write(newdata&0xff);
        Wire.write(newdata>>8);
        Wire.endTransmission();
       
        delay(random(30,50));                // Wait from 30 to 49 ms
        wdt_reset();    // Reset watchdog timer to avoid re-boots
      }
    }

    byte ReversePWMSlope(long cstart,long cend,byte PWMStart,byte PWMEnd, byte clength)
    {
      long n=elapsedSecsToday(now());
      cstart*=60;
      cend*=60;
      if (n<cstart) return PWMStart;
      if (n>=cstart && n<=(cstart+clength)) return map(n,cstart,cstart+clength,PWMStart,PWMEnd);
      if (n>(cstart+clength) && n<(cend-clength)) return PWMEnd;
      if (n>=(cend-clength) && n<=cend) return map(n,cend-clength,cend,PWMEnd,PWMStart);
      if (n>cend) return (int) PWMStart;
    }


void loop()
{
    ReefAngel.ActinicLights( Port1 );
    ReefAngel.DayLights( Port2 );
    ReefAngel.Relay.DelayedOn( Port3 );
    ReefAngel.Relay.DelayedOn( Port4 );
    ReefAngel.StandardHeater( Port6 );
    ReefAngel.Relay.Set(Port5, ReefAngel.HighATO.IsActive());
    ReefAngel.SingleATOLow( Port7 );
    ReefAngel.PWM.SetChannel(0,0); // Make sure we're at 0% at night
    ReefAngel.PWM.SetChannel(0,0); // Make sure we're at 0% at night
    ReefAngel.PWM.Channel0PWMParabola(); // Set Channel0 based on Parabola and Memory values
    ReefAngel.PWM.Channel1PWMParabola(); // Set Chanenl1 based on Parabola and Memory values
    ////// Place your custom code below here
    sun.CheckAndUpdate(); // Calculate today's Sunrise / Sunset
    DaylightPWMValue=ReefAngel.PWM.GetChannelValueRaw(1); // Get the current value of channel 1
    CheckCloud(); // Apply cloud routine
    ReefAngel.PWM.SetChannelRaw(1,DaylightPWMValue); // Override Channel 1 with the result from the Cloud operation
    ////// Place your custom code above here

    // This should always be the last line
    ReefAngel.Portal( "troylong45" );
    ReefAngel.DDNS( "209.18.47.61" ); // Your DDNS is troylong45-209.18.47.61.myreefangel.com
    ReefAngel.ShowInterface();
}
troylong45
Posts: 214
Joined: Sat Oct 10, 2015 9:17 pm

Re: New to code ra and controls

Post by troylong45 »

ok ill try to load the code tomorrow after work. right now its on my moms tank for a litte while cus im breaking my main tank down to reset it due to algae . so im running 1 blue 1 white channel but i have not reran the dimming control to the marsaqua yet. so not sure what the dimming actully looks like yet.

for my main tank when its done
dimming and light relays 1 left bl ch 1 right bl ch 1 left wh ch 1 right wh ch.
Image
troylong45
Posts: 214
Joined: Sat Oct 10, 2015 9:17 pm

Re: New to code ra and controls

Post by troylong45 »

is the new code u posted updated with the things needed from above that u mentined?
Image
User avatar
lnevo
Posts: 5430
Joined: Fri Jul 20, 2012 9:42 am

Re: New to code ra and controls

Post by lnevo »

Yes, but I don't understand your dimming map. everything is channel 1?
troylong45
Posts: 214
Joined: Sat Oct 10, 2015 9:17 pm

Re: New to code ra and controls

Post by troylong45 »

sry no currently will have dimming expansion pwm 0 for blue channel and pwm 1 for white channel .
Image
troylong45
Posts: 214
Joined: Sat Oct 10, 2015 9:17 pm

Re: New to code ra and controls

Post by troylong45 »

look like i need time change the location im using is 10 hours ahead of gmt and 14 hours ahead of me but my time has no bearing on the gps time right so i need to of set the time by 10 hours so since it is 10 hours ahead i need look like this

Code: Select all

sun.setOffset(10,-10); // this will add an hour to the sunrise and remove an hour from sunset
if thats right were does it go
Image
troylong45
Posts: 214
Joined: Sat Oct 10, 2015 9:17 pm

Re: New to code ra and controls

Post by troylong45 »

looks like 12 hours difference compared to internal memory . and i have location as great barrier reef and i know its normaly 12hrs of daylight but it has the daylights set to that. is that to much whites ?
Image
User avatar
lnevo
Posts: 5430
Joined: Fri Jul 20, 2012 9:42 am

Re: New to code ra and controls

Post by lnevo »

I would do 12 hours for actinic and 8 for blues. Go by the recommendations on the fb group files section :) you can use the offsets to fine tune it. I flipped the latitude to the norther hemisphere so it would follow our season and then i swung the latitude over to mine, i probably should have use GMT longitude.
troylong45
Posts: 214
Joined: Sat Oct 10, 2015 9:17 pm

Re: New to code ra and controls

Post by troylong45 »

since the gps location has daylights set for about 12 hrs is there a way to knock off 2 hours daylight from the sunrise and 2 hours from the sunset so i get estimated 8 hours daylights and still use the same gps
Image
User avatar
lnevo
Posts: 5430
Joined: Fri Jul 20, 2012 9:42 am

Re: New to code ra and controls

Post by lnevo »

Set the actinic offset to 2 hours and it should do exactly that.
troylong45
Posts: 214
Joined: Sat Oct 10, 2015 9:17 pm

Re: New to code ra and controls

Post by troylong45 »

Looks like it did thanks now I reset every thing to proper time that I want. I was looking at the moon time and the moon rise is right but not the moonset I don't think we added the moon code in . But currently no moon lights anyway so I'll wait till I get them to do that. Looks like one of the channels hasn't been going below 2% but I'll keep an eye on it I don't think it should matter though cus the relays still turn off so don't seem like should be a big deal I'll leave everything as is now and keep an eye on it and reorder parts to hook up the dimmers to the light.
Image
User avatar
lnevo
Posts: 5430
Joined: Fri Jul 20, 2012 9:42 am

Re: New to code ra and controls

Post by lnevo »

You won' see it go to 0. The portal doesn't store 0s and it only gets data every 5 minutes from the controller. We didn't do anything in the code for moon that I recall if you added then let's see what you did. We can do that pretty easily. I have the same kind of time issues that the sunlocation class does in that it doesn't really account well for timezones etc. but the schedule should be roughly what real moon does. 12 hours of moonlight and if rise is 8am-8pm, next day should be 9am-9pm and continuing. I'd love to see more feedback on your findings. The Moon class is a reimplementation of some code I found so it doesn't have functionality like offsets and stuff, but we can figure out some ways if you want more control.
troylong45
Posts: 214
Joined: Sat Oct 10, 2015 9:17 pm

Re: New to code ra and controls

Post by troylong45 »

The time zone to get my time right for around 8-8 sunrise and sunset I had to use gmt +2 -35 longitude or +35 I can't remember but I used -18 latertude to simulate the great barrier reef. So far look ok. In paper atleast lol since it's at my mom's never really see it. But when I break my 75 down and start clean I'll get better watch on it. I think everything is ok now till I add moonlights, hook up my dimmers and add more floats or water levels do u prefer water level or floats . Water level seems like the pvc will take a lot of room can ra be coded for certain reading of water level like use one for return chamber low and shut off return pump and as well operating the ato low and high settings?
Image
Post Reply