New to code ra and controls

Request new hardware or ideas for the controller
User avatar
Posts: 5349
Joined: Fri Jul 20, 2012 9:42 am
PostPosted: Mon Oct 26, 2015 3:27 pm
Yes :) water level sensor is great. It's 1/2" pvc i believe doesnt take up much space. Roberto can confirm the dimension, mines out of reach in my ato reservoir.

Posts: 214
Joined: Sat Oct 10, 2015 9:17 pm
PostPosted: Mon Oct 26, 2015 5:13 pm
It says 1/2 on the website I guess it would be ok. So ur only usein one and its in the ato tank. Then u use high and/or low float for water level to activate the ato
Image

Posts: 214
Joined: Sat Oct 10, 2015 9:17 pm
PostPosted: Sun Nov 08, 2015 2:41 pm
if i get a water level sensor can it run different things from 1 WLS the return chamber i have will be 5" water level
1 if it drops below 3" turns off return pump till cleared
2 ato turns on when water level falls below 4.75" and ato off above 5"
3 skimmer shuts off above 7" and on below 6"

seems like this all can be done with proper coding
Image
User avatar
Posts: 5349
Joined: Fri Jul 20, 2012 9:42 am
PostPosted: Sun Nov 08, 2015 6:10 pm
Absolutely. Best thing about the water level sensor. Only thing to consider is that it is measure by % but you calibrate it for your use. Roberto uses it to control his return pump speed with a full siphon drain. No gate valve or backup drain needed.

I would still consider the multi sensor though cause you'll want it for other stuff. They can be used together too for 5 total channels.

Posts: 214
Joined: Sat Oct 10, 2015 9:17 pm
PostPosted: Sun Nov 08, 2015 7:03 pm
U read my mind I was thinking the multi for the ato storage and skimmer collection cup to be added later
Image

Posts: 214
Joined: Sat Oct 10, 2015 9:17 pm
PostPosted: Sat Jan 23, 2016 1:01 pm
something is not right the relay 1 2 3 and 4 if not operating with auto light cycle 1 is left blue 2 is let white 3 is right bule 4 is right white i want a 30min delay in the light schedule for the right as well and on the dimming expansion 0 is 0 is left blue 1 is let white 2 is right blue 3 is right white and i want 30 min delay on the right dimming as well.

relay 3 is staying on and 1 2 and 4 is staying off
the only dimming that looks like is working is 1

and when i go in the app to over ride the dimming it works but everything is off buy 2 lines meaning if i override dimming 2 it overides 0 and same for 3 it overrides 1 and 4 doe 2 and 5 does 3 . but if i override 0 or 1 it updates and does nothing?

Code: Select all
    #include <ReefAngel_Features.h>
    #include <Globals.h>
    #include <RA_Wifi.h>
    #include <Wire.h>
    #include <OneWire.h>
    #include <Time.h>
    #include <DS1307RTC.h>
    #include <InternalEEPROM.h>
    #include <RA_NokiaLCD.h>
    #include <RA_ATO.h>
    #include <RA_Joystick.h>
    #include <LED.h>
    #include <RA_TempSensor.h>
    #include <Relay.h>
    #include <RA_PWM.h>
    #include <Timer.h>
    #include <Memory.h>
    #include <InternalEEPROM.h>
    #include <RA_Colors.h>
    #include <RA_CustomColors.h>
    #include <Salinity.h>
    #include <RF.h>
    #include <IO.h>
    #include <ORP.h>
    #include <AI.h>
    #include <PH.h>
    #include <WaterLevel.h>
    #include <Humidity.h>
    #include <DCPump.h>
    #include <PAR.h>
    #include <ReefAngel.h>
    #include <SunLocation.h>

    ////// Place global variable code below here
    SunLocation sun;
    int DaylightPWMValue=0;        // For cloud code
    int Latitude=-18;
    int Longitude=-87;

    ////// Place global variable code above here


    void setup()
    {
        // This must be the first line
        ReefAngel.Init();  //Initialize controller
        ReefAngel.Use2014Screen();  // Let's use 2014 Screen
        // Ports toggled in Feeding Mode
        ReefAngel.FeedingModePorts = Port8Bit;
        // Ports toggled in Water Change Mode
        ReefAngel.WaterChangePorts = Port5Bit | Port6Bit | Port7Bit | Port8Bit;
        // Ports toggled when Lights On / Off menu entry selected
        ReefAngel.LightsOnPorts = Port1Bit | Port2Bit | Port3Bit | Port4Bit;
        // Ports turned off when Overheat temperature exceeded
        ReefAngel.OverheatShutoffPorts = Port6Bit;
        // Use T2 probe as temperature and overheat functions
        ReefAngel.TempProbe = T1_PROBE;
        ReefAngel.OverheatProbe = T2_PROBE;


        // Ports that are always on

        ////// Place additional initialization code below here
        sun.Init(Latitude,Longitude);

        ////// Place additional initialization code above here
    }

        void CheckCloud()
        {
          // ------------------------------------------------------------
          // Change the values below to customize your cloud/storm effect

          // Frequency in days based on the day of the month - number 2 means every 2 days, for example (day 2,4,6 etc)
          // For testing purposes, you can use 1 and cause the cloud to occur everyday
        #define Clouds_Every_X_Days 1

          // Percentage chance of a cloud happening today
          // For testing purposes, you can use 100 and cause the cloud to have 100% chance of happening
        #define Cloud_Chance_per_Day 100

          // Minimum number of minutes for cloud duration.  Don't use max duration of less than 6
        #define Min_Cloud_Duration 7

          // Maximum number of minutes for the cloud duration. Don't use max duration of more than 255
        #define Max_Cloud_Duration 7

          // Minimum number of clouds that can happen per day
        #define Min_Clouds_per_Day 1

          // Maximum number of clouds that can happen per day
        #define Max_Clouds_per_Day 2

          // Only start the cloud effect after this setting
          // In this example, start cloud after noon
        #define Start_Cloud_After NumMins(12,00)

          // Always end the cloud effect before this setting
          // In this example, end cloud before 9:00pm
        #define End_Cloud_Before NumMins(21,00)

          // Percentage chance of a lightning happen for every cloud
          // For testing purposes, you can use 100 and cause the lightning to have 100% chance of happening
        #define Lightning_Change_per_Cloud 100

          // Note: Make sure to choose correct values that will work within your PWMSLope settings.
          // For example, in our case, we could have a max of 5 clouds per day and they could last for 50 minutes.
          // Which could mean 250 minutes of clouds. We need to make sure the PWMSlope can accomodate 250 minutes
          // of effects or unforseen result could happen.
          // Also, make sure that you can fit double those minutes between Start_Cloud_After and End_Cloud_Before.
          // In our example, we have 510 minutes between Start_Cloud_After and End_Cloud_Before, so double the
          // 250 minutes (or 500 minutes) can fit in that 510 minutes window.
          // It's a tight fit, but it did.

          //#define printdebug // Uncomment this for debug print on Serial Monitor window
        #define forcecloudcalculation // Uncomment this to force the cloud calculation to happen in the boot process.

          // Add Random Lightning modes
        #define Calm 0    // No lightning
        #define Slow 1    // 5 seconds of slow lightning in the middle of a cloud for ELN style (slow response) drivers
        #define Fast 2    // 5 seconds of fast lightning in the middle of a cloud for LDD style (fast response) drivers
        #define Mega 3    // Lightning throughout the cloud, higher chance as it gets darker
        #define Mega2 4   // Like Mega, but with more lightning
          // Set which modes you want to use
          // Example:  { Calm, Fast, Mega, Mega2 } to randomize all four modes.
          // { Mega2 } for just Mega2.  { Mega, Mega, Fast} for Mega and Fast, with twice the chance of Mega.
          byte LightningModes[] = {Mega2,Mega,Mega};

          // Change the values above to customize your cloud/storm effect
          // ------------------------------------------------------------
          // Do not change anything below here

          static byte cloudchance=255;
          static byte cloudduration=0;
          static int cloudstart=0;
          static byte numclouds=0;
          static byte lightningchance=0;
          static byte cloudindex=0;
          static byte lightningstatus=0;
          static int LastNumMins=0;
          static byte lightningMode=0;
          static boolean chooseLightning=true;

          static time_t DelayCounter=millis();    // Variable for lightning timing.
          static int DelayTime=random(1000);      // Variable for lightning timimg.

          // Every day at midnight, we check for chance of cloud happening today
          if (hour()==0 && minute()==0 && second()==0) cloudchance=255;

        #ifdef forcecloudcalculation
          if (cloudchance==255)
        #else
            if (hour()==0 && minute()==0 && second()==1 && cloudchance==255)
        #endif
            {
              randomSeed(millis());    // Seed the random number generator
              //Pick a random number between 0 and 99
              cloudchance=random(100);
              // if picked number is greater than Cloud_Chance_per_Day, we will not have clouds today
              if (cloudchance>Cloud_Chance_per_Day) cloudchance=0;
              // Check if today is day for clouds.
              if ((day()%Clouds_Every_X_Days)!=0) cloudchance=0;
              // If we have cloud today
              if (cloudchance)
              {
                // pick a random number for number of clouds between Min_Clouds_per_Day and Max_Clouds_per_Day
                numclouds=random(Min_Clouds_per_Day,Max_Clouds_per_Day);
                // pick the time that the first cloud will start
                // the range is calculated between Start_Cloud_After and the even distribuition of clouds on this day.
                cloudstart=random(Start_Cloud_After,Start_Cloud_After+((End_Cloud_Before-Start_Cloud_After)/(numclouds*2)));
                // pick a random number for the cloud duration of first cloud.
                cloudduration=random(Min_Cloud_Duration,Max_Cloud_Duration);
                //Pick a random number between 0 and 99
                lightningchance=random(100);
                // if picked number is greater than Lightning_Change_per_Cloud, we will not have lightning today
                if (lightningchance>Lightning_Change_per_Cloud) lightningchance=0;
              }
            }
          // Now that we have all the parameters for the cloud, let's create the effect


          if (cloudchance)
          {
            //is it time for cloud yet?
            if (NumMins(hour(),minute())>=cloudstart && NumMins(hour(),minute())<(cloudstart+cloudduration))
            {
              DaylightPWMValue=ReversePWMSlope(cloudstart,cloudstart+cloudduration,DaylightPWMValue/40.95,0,180)*40.95;
              if (chooseLightning)
              {
                lightningMode=LightningModes[random(100)%sizeof(LightningModes)];
                chooseLightning=false;
              }
              switch (lightningMode)
              {
              case Calm:
                break;
              case Mega:
                // Lightning chance from beginning of cloud through the end.  Chance increases with darkness of cloud.
                if (lightningchance && random(ReversePWMSlope(cloudstart,cloudstart+cloudduration,100,0,180))<1 && (millis()-DelayCounter)>DelayTime)
                {
                  // Send the trigger
                  Strike();
                  DelayCounter=millis();    // If we just had a round of flashes, then lets put in a longer delay
                  DelayTime=random(1000);   // of up to a second for dramatic effect before we do another round.
                }
                break;
              case Mega2:
                // Higher lightning chance from beginning of cloud through the end.  Chance increases with darkness of cloud.
                if (lightningchance && random(ReversePWMSlope(cloudstart,cloudstart+cloudduration,100,0,180))<2)
                {
                  Strike();
                }
                break;
              case Fast:
                // 5 seconds of lightning in the middle of the cloud
                if (lightningchance && (NumMins(hour(),minute())==(cloudstart+(cloudduration/2))) && second()<5 && (millis()-DelayCounter)>DelayTime)
                {
                  Strike();

                  DelayCounter=millis();    // If we just had a round of flashes, then lets put in a longer delay
                  DelayTime=random(1000);   // of up to a second for dramatic effect before we do another round.
                }
                break;
              case Slow:
                // Slow lightning for 5 seconds in the middle of the cloud.  Suitable for slower ELN style drivers
                if (lightningchance && (NumMins(hour(),minute())==(cloudstart+(cloudduration/2))) && second()<5)
                {
                  if (random(100)<20) lightningstatus=1;
                  else lightningstatus=0;
                  if (lightningstatus)
                  {
                    DaylightPWMValue=4095;
                  }
                  else
                  {
                    DaylightPWMValue=0;
                  }
                  delay(1);
                }
                break;
              default:
                break;
              }
            }
            else
            {
              chooseLightning=true; // Reset the flag to choose a new lightning type
            }

            if (NumMins(hour(),minute())>(cloudstart+cloudduration))
            {
              cloudindex++;
              if (cloudindex < numclouds)
              {
                cloudstart=random(Start_Cloud_After+(((End_Cloud_Before-Start_Cloud_After)/(numclouds*2))*cloudindex*2),(Start_Cloud_After+(((End_Cloud_Before-Start_Cloud_After)/(numclouds*2))*cloudindex*2))+((End_Cloud_Before-Start_Cloud_After)/(numclouds*2)));
                // pick a random number for the cloud duration of first cloud.
                cloudduration=random(Min_Cloud_Duration,Max_Cloud_Duration);
                //Pick a random number between 0 and 99
                lightningchance=random(100);
                // if picked number is greater than Lightning_Change_per_Cloud, we will not have lightning today
                if (lightningchance>Lightning_Change_per_Cloud) lightningchance=0;
              }
            }
          }

          // Write the times of the next cloud, next lightning, and cloud duration to the screen and into some customvars for the Portal.
          if (LastNumMins!=NumMins(hour(),minute()))
          {
            LastNumMins=NumMins(hour(),minute());
            /*ReefAngel.LCD.Clear(255,0,120,132,132);
             ReefAngel.LCD.DrawText(0,255,5,120,"C");
             ReefAngel.LCD.DrawText(0,255,11,120,"00:00");
             ReefAngel.LCD.DrawText(0,255,45,120,"L");
             ReefAngel.LCD.DrawText(0,255,51,120,"00:00"); */
            if (cloudchance && (NumMins(hour(),minute())<cloudstart))
            {
              int x=0;
              if ((cloudstart/60)>=10) x=11;
              else x=17;
              //ReefAngel.LCD.DrawText(0,255,x,120,(cloudstart/60));
              ReefAngel.CustomVar[3]=cloudstart/60; // Write the hour of the next cloud to custom variable for Portal reporting
              if ((cloudstart%60)>=10) x=29;
              else x=35;
              //ReefAngel.LCD.DrawText(0,255,x,120,(cloudstart%60));
              ReefAngel.CustomVar[4]=cloudstart%60; // Write the minute of the next cloud to custom variable for Portal reporting

            }
            //ReefAngel.LCD.DrawText(0,255,90,120,cloudduration);
            ReefAngel.CustomVar[7]=(cloudduration);    // Put the duration of the next cloud in a custom var for the portal
            if (lightningchance)
            {
              int x=0;
              if (((cloudstart+(cloudduration/2))/60)>=10) x=51;
              else x=57;
              //ReefAngel.LCD.DrawText(0,255,x,120,((cloudstart+(cloudduration/2))/60));
              ReefAngel.CustomVar[5]=(cloudstart+(cloudduration/2))/60;    // Write the hour of the next lightning to a custom variable for the Portal
              if (((cloudstart+(cloudduration/2))%60)>=10) x=69;
              else x=75;
              //ReefAngel.LCD.DrawText(0,255,x,120,((cloudstart+(cloudduration/2))%60)); // Write the minute of the next lightning to a custom variable for the Portal
                ReefAngel.CustomVar[6]=(cloudstart+(cloudduration/2))%60;
            }
          }   
        }

        void Strike()
        {
          int a=random(1,5);    // Pick a number of consecutive flashes from 1 to 4.
          for (int i=0; i<a; i++)
          {
            // Flash on
            int newdata=4095;
            Wire.beginTransmission(0x40);      // Address of the dimming expansion module
            Wire.write(0x8+(4*1));             // 0x8 is channel 0, 0x12 is channel 1, etc.  I'm using channel 1.
            Wire.write(newdata&0xff);          // Send the data 8 bits at a time.  This sends the LSB
            Wire.write(newdata>>8);            // This sends the MSB
            Wire.endTransmission();
           
            int randy=random(20,80);    // Random number for a delay
            if (randy>71) randy=((randy-70)/2)*100;    // Small chance of a longer delay
            delay(randy);                // Wait from 20 to 69 ms, or 100-400 ms
           
            // Flash off.  Return to baseline.
            newdata=ReefAngel.PWM.GetChannelValueRaw(1);   // Use the channel number you're flashing here
            Wire.beginTransmission(0x40);    // Same as above
            Wire.write(0x8+(4*1));
            Wire.write(newdata&0xff);
            Wire.write(newdata>>8);
            Wire.endTransmission();
           
            delay(random(30,50));                // Wait from 30 to 49 ms
            wdt_reset();    // Reset watchdog timer to avoid re-boots
          }
        }

        byte ReversePWMSlope(long cstart,long cend,byte PWMStart,byte PWMEnd, byte clength)
        {
          long n=elapsedSecsToday(now());
          cstart*=60;
          cend*=60;
          if (n<cstart) return PWMStart;
          if (n>=cstart && n<=(cstart+clength)) return map(n,cstart,cstart+clength,PWMStart,PWMEnd);
          if (n>(cstart+clength) && n<(cend-clength)) return PWMEnd;
          if (n>=(cend-clength) && n<=cend) return map(n,cend-clength,cend,PWMEnd,PWMStart);
          if (n>cend) return (int) PWMStart;
        }


    void loop()
    {
        ReefAngel.ActinicLights( Port1 | Port3 );  // actinicLight power
        ReefAngel.DayLights( Port2 | Port4 ); // daylight power
        ReefAngel.Relay.Set(Port5, ReefAngel.HighATO.IsActive()); // skimmer
        ReefAngel.StandardHeater( Port6 ); // heater
        ReefAngel.SingleATOLow( Port7 ); // auto top off
        ReefAngel.Relay.On(Port8); // return
        ReefAngel.PWM.Channel0PWMParabola();
        ReefAngel.PWM.Channel1PWMParabola();
        ReefAngel.PWM.Channel3PWMParabola();
        ReefAngel.PWM.Channel4PWMParabola();
        ////// Place your custom code below here
        sun.CheckAndUpdate(); // Calculate today's Sunrise / Sunset
        DaylightPWMValue=PWMSlopeHighRes(10,30,22,0,0,30,240,0);
        CheckCloud();
        ReefAngel.PWM.SetChannelRaw(1,DaylightPWMValue);
        ////// Place your custom code above here

        // This should always be the last line
        ReefAngel.Portal( "troylong45" );
        ReefAngel.DDNS( "reef" ); // Your DDNS is troylong45-reef.myreefangel.com
        ReefAngel.ShowInterface();
    }
Image
User avatar
Posts: 2739
Joined: Fri Mar 18, 2011 6:20 pm
Location: Illinois
PostPosted: Sun Jan 24, 2016 10:03 am
Looking at your code, your Actinic and Daylight problems are coming from these lines:
Code: Select all
void loop()
{
        ReefAngel.ActinicLights( Port1 | Port3 );  // actinicLight power
        ReefAngel.DayLights( Port2 | Port4 ); // daylight power

   // …
}

When you use the | (bitwise OR operation), you are telling the code to take the value of Port1 and combine it with Port3. That will not give you what you are wanting. That will give an entirely different Port to be toggled on/off.
So, to get Port1 and Port3 to operate on the same schedule and to get Port2 and Port4 to operate on their schedule, you will need to do this:
Code: Select all
ReefAngel.ActinicLights(Port1);
ReefAngel.ActinicLights(Port3);
ReefAngel.DayLights(Port2);
ReefAngel.DayLights(Port4);

You need a separate line for each of the ports and cannot combine them into the same line, otherwise it will not work.


You removed the code that Lee provided for you that was setting things correctly. You went back to hard coding your values.
This is what he gave you:
Code: Select all
    ReefAngel.PWM.Channel0PWMParabola(); // Set Channel0 based on Parabola and Memory values
    ReefAngel.PWM.Channel1PWMParabola(); // Set Channel1 based on Parabola and Memory values
    ////// Place your custom code below here
    sun.CheckAndUpdate(); // Calculate today's Sunrise / Sunset
    DaylightPWMValue=ReefAngel.PWM.GetChannelValueRaw(1); // Get the current value of channel 1
    CheckCloud(); // Apply cloud routine
    ReefAngel.PWM.SetChannelRaw(1,DaylightPWMValue); // Override Channel 1 with the result from the Cloud operation

this is what you are using:
Code: Select all
        ReefAngel.PWM.Channel0PWMParabola();
        ReefAngel.PWM.Channel1PWMParabola();
        ReefAngel.PWM.Channel3PWMParabola();
        ReefAngel.PWM.Channel4PWMParabola();
        ////// Place your custom code below here
        sun.CheckAndUpdate(); // Calculate today's Sunrise / Sunset
        DaylightPWMValue=PWMSlopeHighRes(10,30,22,0,0,30,240,0);
        CheckCloud();
        ReefAngel.PWM.SetChannelRaw(1,DaylightPWMValue);
        ////// Place your custom code above here

In this code, you are only using channels 0, 1, 3, 4. You are then forcing in code the value for DaylightPWMValue by using the PWMSlopeHighRes function.
Lastly, you are overriding your PWM channel 1 with the output from the CheckCloud function.

So, I’m not exactly sure what you are trying to do with your code. Based on your code, when you use the ChannelXPWMParabola() function, that will set the PWM channel X based on the parameters stored in memory for the Parabola function. After you do that, you are calling the sun functions and then the check cloud function and only using that output on PWM Channel 1.

SUMMARY:
You have lots of things going on. Since you are having issues, it is best to go back to the basics.
  • Let’s get the relays function properly with my suggestions above (separate out the relays to their own lines).
  • Then, lets remove the sun and checkcloud function calls and let the PWMParabola do its job and set the values.
Once we know those channels are functioning properly, then we can proceed onward with using the sun and checkcloud functions and get them to be used on the proper channels. I have not used the checkcloud function so I cannot answer much based on that or tell you how it works. I probably could figure it out, but I do not have the time and others can do this much faster than me.

Posts: 214
Joined: Sat Oct 10, 2015 9:17 pm
PostPosted: Sun Jan 24, 2016 11:42 am
Ok yea I don't know y I codes the relays in same area like that just thought maybe would work lol.
Image

Posts: 214
Joined: Sat Oct 10, 2015 9:17 pm
PostPosted: Sun Jan 24, 2016 12:43 pm
here is a new code i just now did lll go from this
Code: Select all
#include <ReefAngel_Features.h>
#include <Globals.h>
#include <RA_Wifi.h>
#include <Wire.h>
#include <OneWire.h>
#include <Time.h>
#include <DS1307RTC.h>
#include <InternalEEPROM.h>
#include <RA_NokiaLCD.h>
#include <RA_ATO.h>
#include <RA_Joystick.h>
#include <LED.h>
#include <RA_TempSensor.h>
#include <Relay.h>
#include <RA_PWM.h>
#include <Timer.h>
#include <Memory.h>
#include <InternalEEPROM.h>
#include <RA_Colors.h>
#include <RA_CustomColors.h>
#include <Salinity.h>
#include <RF.h>
#include <IO.h>
#include <ORP.h>
#include <AI.h>
#include <PH.h>
#include <WaterLevel.h>
#include <Humidity.h>
#include <DCPump.h>
#include <PAR.h>
#include <ReefAngel.h>

////// Place global variable code below here


////// Place global variable code above here


void setup()
{
    // This must be the first line
    ReefAngel.Init();  //Initialize controller
    ReefAngel.Use2014Screen();  // Let's use 2014 Screen
    // Ports toggled in Feeding Mode
    ReefAngel.FeedingModePorts = Port5Bit | Port6Bit | Port7Bit;
    // Ports toggled in Water Change Mode
    ReefAngel.WaterChangePorts = Port5Bit | Port6Bit | Port7Bit | Port8Bit;
    // Ports toggled when Lights On / Off menu entry selected
    ReefAngel.LightsOnPorts = Port1Bit | Port2Bit | Port3Bit | Port4Bit;
    // Ports turned off when Overheat temperature exceeded
    ReefAngel.OverheatShutoffPorts = Port5Bit;
    // Use T1 probe as temperature and overheat functions
    ReefAngel.TempProbe = T1_PROBE;
    ReefAngel.OverheatProbe = T1_PROBE;

    // Feeeding and Water Change mode speed
    ReefAngel.DCPump.FeedingSpeed=0;
    ReefAngel.DCPump.WaterChangeSpeed=0;


    // Ports that are always on
    ReefAngel.Relay.On( Port7 ); // Return Pump
   
    ////// Place additional initialization code below here
   

    ////// Place additional initialization code above here
}

void loop()
{
    ReefAngel.ActinicLights( Port1 ); // Left Actinic Light power
    ReefAngel.DayLights( Port2 ); // Left Day Light power
    ReefAngel.ActinicLights( Port3 ); // Right Actinic Light power
    ReefAngel.DayLights( Port4 ); // Right Day Light power
    ReefAngel.StandardHeater( Port5 ); // Heater
    ReefAngel.SingleATOLow( Port6 ); // Auto top off
    ReefAngel.Relay.Set(Port8, ReefAngel.HighATO.IsActive()); // Skimmer
    ReefAngel.PWM.Channel0PWMParabola(); // Left Actinic Light 0-10v
    ReefAngel.PWM.Channel1PWMParabola(); // Left Day Light 0-10v
    ReefAngel.PWM.Channel2PWMParabola(); // Right Actinic Light 0-10v
    ReefAngel.PWM.Channel3PWMParabola(); // Right Day Light 0-10v
    ReefAngel.DCPump.UseMemory = true;
    ReefAngel.DCPump.DaylightChannel = None;
    ReefAngel.DCPump.ActinicChannel = None;
    ReefAngel.DCPump.ExpansionChannel[0] = None;
    ReefAngel.DCPump.ExpansionChannel[1] = None;
    ReefAngel.DCPump.ExpansionChannel[2] = None;
    ReefAngel.DCPump.ExpansionChannel[3] = None;
    ReefAngel.DCPump.ExpansionChannel[4] = Sync; // Left Jebao RW4
    ReefAngel.DCPump.ExpansionChannel[5] = AntiSync; // Right Jebao RW4
    ////// Place your custom code below here
   

    ////// Place your custom code above here

    // This should always be the last line
    ReefAngel.Portal( "troylong45" );
    ReefAngel.DDNS( "1" ); // Your DDNS is troylong45-1.myreefangel.com
    ReefAngel.ShowInterface();
}

Image

Posts: 214
Joined: Sat Oct 10, 2015 9:17 pm
PostPosted: Mon Jan 25, 2016 6:34 pm
i need storm and geo location added and want the daylight and blue channel to storm but i want a 30min off set for the geo location sunrise in the relays and dimming ramping so i would like eveything normal in cloud and geo location beside relay 3 to have a 30 min delay from when relay 1 comes on and relay 4 to have 30 min delay from when relay 2 comes on and 30 mins after it goes off. and same goes for the dimming expansion so i would like a 30min delay from channel 2 and 0 and 30 min delay between 3 and 1
Image
PreviousNext

Return to Requests

Who is online

Users browsing this forum: No registered users and 3 guests

cron