Coding Pwm module.

abhi_123 · Post by **abhi_123** » Sun May 20, 2012 10:34 am

Will check it with multimeter & update you. Btw the channels which are assigned with fans are working as well as their status is also updating on the portal.

abhi_123 · Post by **abhi_123** » Mon May 21, 2012 7:19 am

Have checked the channel with the help of multimeter.

reading is 3.9 on all channel at 3:00 p.m. local time & 1.1 at 5:00 p.m.

rimai · Post by **rimai** » Mon May 21, 2012 8:42 am

Looks like it is working.
Are the drivers not turning on?

abhi_123 · Post by **abhi_123** » Mon May 21, 2012 9:00 am

havnt attached any drivers yet. they are on their way will be reaching me this week.

rimai · Post by **rimai** » Mon May 21, 2012 9:08 am

Ahh.
So, everything seems to be working if the voltage is changing.
But, this conversation actually gave me new ideas and I think we can make it so the parabola code can still be kept in the main code, so you can see the values on the Portal and we can override them in the PWM module when it's time for lightning.
Let me put something together.

abhi_123 · Post by **abhi_123** » Mon May 21, 2012 9:51 am

Robert you are the man buddy. One noob question can't we make modules to communicate with the head unit so as to show the value on portal or any way to make them communicate directly with portal?

rimai · Post by **rimai** » Mon May 21, 2012 8:16 pm

I think this should do it:

Code: Select all

#include <Wire.h>
#include <OneWire.h>
#include <Time.h>
#include <DS1307RTC.h>
#include "Globals.h"
#include "ReefAngel_Features.h"
#include <RA_Colors.h>
#include <RA_CustomColors.h>
#include <Wire.h>
#include <avr/wdt.h>


byte PWMports[] ={
  3,5,6,9,10,11};
byte ChannelValue[] = {
  0,0,0,0,0,0};

byte cmdnum=255;
byte datanum=255;
void setup()
{
  Serial.begin(57600);
  Wire.begin(8);
  Wire.onReceive(receiveEvent);
  randomSeed(analogRead(0));
  pinMode(3,OUTPUT);
  pinMode(5,OUTPUT);
  pinMode(6,OUTPUT);
  pinMode(9,OUTPUT);
  pinMode(10,OUTPUT);
  pinMode(11,OUTPUT);
  wdt_enable(WDTO_1S);
  setSyncProvider(RTC.get); // the function to get the time from the RTC
  setSyncInterval(SECS_PER_HOUR); // Changed to sync every hour.
  now();
}

void loop()
{
  wdt_reset();
  //Serial.println(ChannelValue[0],DEC);
  if (cmdnum!=255)
  {
    ProcessCMD(cmdnum,datanum);    
    cmdnum=255;
    datanum=255;
  }
  CheckCloud();
  for (int a=0;a<6;a++)
  {
    analogWrite(PWMports[a],ChannelValue[a]);
  }
}

void receiveEvent(int howMany) {
  wdt_reset();
  if (howMany==5)
  {
    byte cmd1, cmd2, cmd3, cmd4, cmd5;
    cmd1=Wire.read();
    cmd2=Wire.read();
    cmd3=Wire.read();
    cmd4=Wire.read();
    cmd5=Wire.read();
    if (cmd1=='$' && cmd2=='$' && cmd3=='$')
    {
      cmdnum=cmd4;
      datanum=cmd5;
      //Serial.println(cmd4,DEC);
      //Serial.println(cmd5,DEC);
    }
  }
  else
  {
    for (int a=0;a<howMany;a++)
    {
      Wire.read();
    }
  }  
}

void ProcessCMD(byte cmd, byte data)
{
  wdt_reset();
  // Individual Channel
  if (cmd>=0 && cmd<=5)
  {
    ChannelValue[cmd]=data;
  }
}

void CheckCloud()
{

  // ------------------------------------------------------------
  // Change the values below to customize your cloud/storm effect

  // Frequency in days based on the day of the month - number 2 means every 2 days, for example (day 2,4,6 etc)
  // For testing purposes, you can use 1 and cause the cloud to occur everyday
#define Clouds_Every_X_Days 1 

  // Percentage chance of a cloud happening today
  // For testing purposes, you can use 100 and cause the cloud to have 100% chance of happening
#define Cloud_Chance_per_Day 100

  // Minimum number of minutes for cloud duration.  Don't use max duration of less than 6
#define Min_Cloud_Duration 7

  // Maximum number of minutes for the cloud duration. Don't use max duration of more than 255
#define Max_Cloud_Duration 15

  // Minimum number of clouds that can happen per day
#define Min_Clouds_per_Day 3

  // Maximum number of clouds that can happen per day
#define Max_Clouds_per_Day 5

  // Only start the cloud effect after this setting
  // In this example, start could after 11:30am
#define Start_Cloud_After NumMins(11,30)

  // Always end the cloud effect before this setting
  // In this example, end could before 8:00pm
#define End_Cloud_Before NumMins(18,30)

  // Percentage chance of a lightning happen for every cloud
  // For testing purposes, you can use 100 and cause the lightning to have 100% chance of happening
#define Lightning_Change_per_Cloud 100

  // Channels used by the actinic LEDs on the PWM Expansion module
  // These channels will not be dimmed when the cloud effect is triggered
  // Number is a binary form. B001100 means channel 2 and 3 are used for actinics
#define Actinic_Channels B000100

  // Channels used by the daylight LEDs on the PWM Expansion module
  // These channels will be used for the spike when lightning effect is triggered
  // Number is a binary form. B000011 means channel 0 and 1 are used for daylights
#define Daylight_Channels B001011

  // Note: Make sure to choose correct values that will work within your PWMSLope settings.
  // For example, in our case, we could have a max of 5 clouds per day and they could last for 50 minutes.
  // Which could mean 250 minutes of clouds. We need to make sure the PWMSlope can accomodate 250 minutes of effects or unforseen resul could happen.
    // Also, make sure that you can fit double those minutes between Start_Cloud_After and End_Cloud_Before.
  // In our example, we have 510 minutes between Start_Cloud_After and End_Cloud_Before, so double the 250 minutes (or 500 minutes) can fit in that 510 minutes window.
    // It's a tight fit, but it did.

    //#define printdebug // Uncomment this for debug print on Serial Monitor window
  #define forcecloudcalculation // Uncomment this to force the cloud calculation to happen in the boot process. 


    // Change the values above to customize your cloud/storm effect
  // ------------------------------------------------------------
  // Do not change anything below here

  static byte cloudchance=255;
  static byte cloudduration=0;
  static int cloudstart=0;
  static byte numclouds=0;
  static byte lightningchance=0;
  static byte cloudindex=0;
  static byte lightningstatus=0;
  static int LastNumMins=0;
  // Every day at midnight, we check for chance of cloud happening today
  if (hour()==0 && minute()==0 && second()==0) cloudchance=255;

#ifdef forcecloudcalculation
    if (cloudchance==255)
#else
    if (hour()==0 && minute()==0 && second()==1 && cloudchance==255) 
#endif
    {
      //Pick a random number between 0 and 99
      cloudchance=random(100); 
      // if picked number is greater than Cloud_Chance_per_Day, we will not have clouds today
      if (cloudchance>Cloud_Chance_per_Day) cloudchance=0;
      // Check if today is day for clouds. 
      if ((day()%Clouds_Every_X_Days)!=0) cloudchance=0; 
      // If we have cloud today
      if (cloudchance)
      {
        // pick a random number for number of clouds between Min_Clouds_per_Day and Max_Clouds_per_Day
        numclouds=random(Min_Clouds_per_Day,Max_Clouds_per_Day);
        // pick the time that the first cloud will start
        // the range is calculated between Start_Cloud_After and the even distribuition of clouds on this day. 
        cloudstart=random(Start_Cloud_After,Start_Cloud_After+((End_Cloud_Before-Start_Cloud_After)/(numclouds*2)));
        // pick a random number for the cloud duration of first cloud.
        cloudduration=random(Min_Cloud_Duration,Max_Cloud_Duration);
        //Pick a random number between 0 and 99
        lightningchance=random(100);
        // if picked number is greater than Lightning_Change_per_Cloud, we will not have lightning today
        if (lightningchance>Lightning_Change_per_Cloud) lightningchance=0;
      }
    }
  // Now that we have all the parameters for the cloud, let's create the effect

  if (cloudchance)
  {
    //is it time for cloud yet?
    if (NumMins(hour(),minute())>=cloudstart && NumMins(hour(),minute())<(cloudstart+cloudduration))
    {
      // let's go through all channels to pick which ones will be dimmed
      for (int a=0;a<6;a++)
      {
        if (bitRead(Actinic_Channels,a)==0)
        {
          // this will slope down the channel from the current PWM to 0 within 3minutes.
          // then it will stay at 0 for the duration of the cycle
          // and finally slope up from 0 to PWM value within 3 minutes
          // it is basically an inversed slope
          ChannelValue[a]=ReversePWMSlope(cloudstart,cloudstart+cloudduration,ChannelValue[a],0,180);
        }
      }
      if (lightningchance && (NumMins(hour(),minute())==(cloudstart+(cloudduration/2))) && second()<5) 
      {
        for (int b=0;b<6;b++)
        {
          if (bitRead(Daylight_Channels,b)==1)
          {
            if (random(100)<20) lightningstatus=1; 
            else lightningstatus=0;
            if (lightningstatus) ChannelValue[b]=100; 
            else ChannelValue[b]=0;
            //delay(10);
          }
          else
          {
            ChannelValue[b]=0;
          }
        }
      }
    }
    if (NumMins(hour(),minute())>(cloudstart+cloudduration))
    {
      cloudindex++;
      if (cloudindex < numclouds)
      {
        cloudstart=random(Start_Cloud_After+(((End_Cloud_Before-Start_Cloud_After)/(numclouds*2))*cloudindex*2),(Start_Cloud_After+(((End_Cloud_Before-Start_Cloud_After)/(numclouds*2))*cloudindex*2))+((End_Cloud_Before-Start_Cloud_After)/(numclouds*2)));
        // pick a random number for the cloud duration of first cloud.
        cloudduration=random(Min_Cloud_Duration,Max_Cloud_Duration);
        //Pick a random number between 0 and 99
        lightningchance=random(100);
        // if picked number is greater than Lightning_Change_per_Cloud, we will not have lightning today
        if (lightningchance>Lightning_Change_per_Cloud) lightningchance=0;
      }
    }
  }
  
//  if (LastNumMins!=NumMins(hour(),minute()))
//  {
//    LastNumMins=NumMins(hour(),minute());
//    ReefAngel.LCD.Clear(255,0,120,132,132);
//    ReefAngel.LCD.DrawText(0,255,5,120,"C");
//    ReefAngel.LCD.DrawText(0,255,11,120,"00:00");
//    ReefAngel.LCD.DrawText(0,255,45,120,"L");
//    ReefAngel.LCD.DrawText(0,255,51,120,"00:00");
//    if (cloudchance && (NumMins(hour(),minute())<cloudstart))
//    {
//      int x=0;
//      if ((cloudstart/60)>=10) x=11; else x=17;
//      ReefAngel.LCD.DrawText(0,255,x,120,(cloudstart/60));
//      if ((cloudstart%60)>=10) x=29; else x=35;
//      ReefAngel.LCD.DrawText(0,255,x,120,(cloudstart%60));
//    }
//    ReefAngel.LCD.DrawText(0,255,90,120,cloudduration);
//    if (lightningchance) 
//    {
//      int x=0;
//      if (((cloudstart+(cloudduration/2))/60)>=10) x=51; else x=57;
//      ReefAngel.LCD.DrawText(0,255,x,120,((cloudstart+(cloudduration/2))/60));
//      if (((cloudstart+(cloudduration/2))%60)>=10) x=69; else x=75;
//      ReefAngel.LCD.DrawText(0,255,x,120,((cloudstart+(cloudduration/2))%60));
//    }
//  }   
}

byte ReversePWMSlope(long cstart,long cend,byte PWMStart,byte PWMEnd, byte clength)
{
  long n=elapsedSecsToday(now());
  cstart*=60;
  cend*=60;
  if (n<cstart) return PWMStart;
  if (n>=cstart && n<=(cstart+clength)) return map(n,cstart,cstart+clength,PWMStart,PWMEnd);
  if (n>(cstart+clength) && n<(cend-clength)) return PWMEnd;
  if (n>=(cend-clength) && n<=cend) return map(n,cend-clength,cend,PWMEnd,PWMStart);
  if (n>cend) return PWMStart;
}

abhi_123 · Post by **abhi_123** » Mon May 21, 2012 8:50 pm

If m not wrong this code is using slope whereas the one which is uploaded in the module is using parabola. Should i update that code with this one?

rimai · Post by **rimai** » Mon May 21, 2012 9:20 pm

I'm sorry...

Forgot to explain.
This code will override the settings coming from your main code when it is time for cloud/lightning.
Simply place the parabola for channels 0-3 back into your code.

abhi_123 · Post by **abhi_123** » Mon May 21, 2012 10:15 pm

So i have to place parabola setting on my head unit code & lightning code in my pwm module?

rimai · Post by **rimai** » Mon May 21, 2012 10:16 pm

abhi_123 · Post by **abhi_123** » Tue May 22, 2012 4:04 am

One small issue roberto. I want to keep all codes associated with my lighting inside the module only as i don't have enough memory space left in my head unit.

rimai · Post by **rimai** » Tue May 22, 2012 7:21 am

You have memory for the sunrise/sunset effect just fine.
What you don't have space is for the lightning code, which I moved to the module.

abhi_123 · Post by **abhi_123** » Tue May 22, 2012 8:04 am

Should i enter this in my head unit code

ReefAngel.PWM.SetChannel(0,PWMParabola(9,0,17,0,10,90,0));
  ReefAngel.PWM.SetChannel(1,PWMParabola(9,0,16,30,20,95,0));
    ReefAngel.PWM.SetChannel(2,PWMParabola(9,0,20,0,0,100,0));
    ReefAngel.PWM.SetChannel(3,PWMParabola(9,0,12,0,25,100,0));

rimai · Post by **rimai** » Tue May 22, 2012 8:06 am

exactly

abhi_123 · Post by **abhi_123** » Tue May 22, 2012 8:38 am

Great. Can we make wavemaker to toggle along with lightning & thunderstorm to givemore natural look?

Do i am becoming greedy.lol

rimai · Post by **rimai** » Tue May 22, 2012 8:45 am

Let's get the other stuff done first.
You still need to test to see if it worked

abhi_123 · Post by **abhi_123** » Sun May 27, 2012 12:12 pm

Hi,

I havn't saw any cloud or lightning feature yet with my lights.

rimai · Post by **rimai** » Sun May 27, 2012 2:02 pm

Did you get your leds hooked up already?

abhi_123 · Post by **abhi_123** » Sun May 27, 2012 8:01 pm

rimai · Post by **rimai** » Sun May 27, 2012 8:45 pm

Nice. Is the Portal updating all right?

abhi_123 · Post by **abhi_123** » Sun May 27, 2012 9:10 pm

Yep. No prob with the portal now. The only prob is that i am not getting features of led lighting like sunrise sunset as per calender, cloud, thounderstorm etc etc.

abhi_123 · Post by **abhi_123** » Mon May 28, 2012 10:20 am

Bump.

rimai · Post by **rimai** » Mon May 28, 2012 2:42 pm

I can't test it now, but try this:
PWM code:

Code: Select all

#include <Wire.h>
#include <OneWire.h>
#include <Time.h>
#include <DS1307RTC.h>
#include "Globals.h"
#include "ReefAngel_Features.h"
#include <RA_Colors.h>
#include <RA_CustomColors.h>
#include <Wire.h>
#include <avr/wdt.h>

   byte cloudchance=255;
   byte cloudduration=0;
   int cloudstart=0;
   byte numclouds=0;
   byte lightningchance=0;
   byte cloudindex=0;
   byte lightningstatus=0;
   int LastNumMins=0;
  
byte PWMports[] ={
  3,5,6,9,10,11};
byte ChannelValue[] = {
  0,0,0,0,0,0};

byte SeasonsVar[]={
  0,0,0,0,0,0};

byte cmdnum=255;
byte datanum=255;
void setup()
{
  Serial.begin(57600);
  Wire.begin(8);
  Wire.onReceive(receiveEvent);
  Wire.onRequest(requestEvent);
  randomSeed(analogRead(0));
  pinMode(3,OUTPUT);
  pinMode(5,OUTPUT);
  pinMode(6,OUTPUT);
  pinMode(9,OUTPUT);
  pinMode(10,OUTPUT);
  pinMode(11,OUTPUT);
  wdt_enable(WDTO_1S);
  setSyncProvider(RTC.get); // the function to get the time from the RTC
  setSyncInterval(SECS_PER_HOUR); // Changed to sync every hour.
  now();
}

void loop()
{
  wdt_reset();
  //Serial.println(ChannelValue[0],DEC);
  if (cmdnum!=255)
  {
    ProcessCMD(cmdnum,datanum);    
    cmdnum=255;
    datanum=255;
  }
  CheckCloud();
  for (int a=0;a<6;a++)
  {
    analogWrite(PWMports[a],ChannelValue[a]);
  }
}

void requestEvent() {
  SeasonsVar[0]=cloudstart/60;
  SeasonsVar[1]=cloudstart%60;
  SeasonsVar[2]=(cloudstart+(cloudduration/2))/60;
  SeasonsVar[3]=(cloudstart+(cloudduration/2))%60;
  SeasonsVar[4]=cloudchance;
  SeasonsVar[5]=lightningchance;
  Wire.write(SeasonsVar,6);
}

void receiveEvent(int howMany) {
  wdt_reset();
  if (howMany==5)
  {
    byte cmd1, cmd2, cmd3, cmd4, cmd5;
    cmd1=Wire.read();
    cmd2=Wire.read();
    cmd3=Wire.read();
    cmd4=Wire.read();
    cmd5=Wire.read();
    if (cmd1=='$' && cmd2=='$' && cmd3=='$')
    {
      cmdnum=cmd4;
      datanum=cmd5;
      //Serial.println(cmd4,DEC);
      //Serial.println(cmd5,DEC);
    }
  }
  else
  {
    for (int a=0;a<howMany;a++)
    {
      Wire.read();
    }
  }  
}

void ProcessCMD(byte cmd, byte data)
{
  wdt_reset();
  // Individual Channel
  if (cmd>=0 && cmd<=5)
  {
    ChannelValue[cmd]=data;
  }
}

void CheckCloud()
{

  // ------------------------------------------------------------
  // Change the values below to customize your cloud/storm effect

  // Frequency in days based on the day of the month - number 2 means every 2 days, for example (day 2,4,6 etc)
  // For testing purposes, you can use 1 and cause the cloud to occur everyday
#define Clouds_Every_X_Days 1 

  // Percentage chance of a cloud happening today
  // For testing purposes, you can use 100 and cause the cloud to have 100% chance of happening
#define Cloud_Chance_per_Day 100

  // Minimum number of minutes for cloud duration.  Don't use max duration of less than 6
#define Min_Cloud_Duration 7

  // Maximum number of minutes for the cloud duration. Don't use max duration of more than 255
#define Max_Cloud_Duration 15

  // Minimum number of clouds that can happen per day
#define Min_Clouds_per_Day 3

  // Maximum number of clouds that can happen per day
#define Max_Clouds_per_Day 5

  // Only start the cloud effect after this setting
  // In this example, start could after 11:30am
#define Start_Cloud_After NumMins(11,30)

  // Always end the cloud effect before this setting
  // In this example, end could before 8:00pm
#define End_Cloud_Before NumMins(18,30)

  // Percentage chance of a lightning happen for every cloud
  // For testing purposes, you can use 100 and cause the lightning to have 100% chance of happening
#define Lightning_Change_per_Cloud 100

  // Channels used by the actinic LEDs on the PWM Expansion module
  // These channels will not be dimmed when the cloud effect is triggered
  // Number is a binary form. B001100 means channel 2 and 3 are used for actinics
#define Actinic_Channels B000100

  // Channels used by the daylight LEDs on the PWM Expansion module
  // These channels will be used for the spike when lightning effect is triggered
  // Number is a binary form. B000011 means channel 0 and 1 are used for daylights
#define Daylight_Channels B001011

  // Note: Make sure to choose correct values that will work within your PWMSLope settings.
  // For example, in our case, we could have a max of 5 clouds per day and they could last for 50 minutes.
  // Which could mean 250 minutes of clouds. We need to make sure the PWMSlope can accomodate 250 minutes of effects or unforseen resul could happen.
    // Also, make sure that you can fit double those minutes between Start_Cloud_After and End_Cloud_Before.
  // In our example, we have 510 minutes between Start_Cloud_After and End_Cloud_Before, so double the 250 minutes (or 500 minutes) can fit in that 510 minutes window.
    // It's a tight fit, but it did.

    //#define printdebug // Uncomment this for debug print on Serial Monitor window
  #define forcecloudcalculation // Uncomment this to force the cloud calculation to happen in the boot process. 


    // Change the values above to customize your cloud/storm effect
  // ------------------------------------------------------------
  // Do not change anything below here

  // Every day at midnight, we check for chance of cloud happening today
  if (hour()==0 && minute()==0 && second()==0) cloudchance=255;

#ifdef forcecloudcalculation
    if (cloudchance==255)
#else
    if (hour()==0 && minute()==0 && second()==1 && cloudchance==255) 
#endif
    {
      //Pick a random number between 0 and 99
      cloudchance=random(100); 
      // if picked number is greater than Cloud_Chance_per_Day, we will not have clouds today
      if (cloudchance>Cloud_Chance_per_Day) cloudchance=0;
      // Check if today is day for clouds. 
      if ((day()%Clouds_Every_X_Days)!=0) cloudchance=0; 
      // If we have cloud today
      if (cloudchance)
      {
        // pick a random number for number of clouds between Min_Clouds_per_Day and Max_Clouds_per_Day
        numclouds=random(Min_Clouds_per_Day,Max_Clouds_per_Day);
        // pick the time that the first cloud will start
        // the range is calculated between Start_Cloud_After and the even distribuition of clouds on this day. 
        cloudstart=random(Start_Cloud_After,Start_Cloud_After+((End_Cloud_Before-Start_Cloud_After)/(numclouds*2)));
        // pick a random number for the cloud duration of first cloud.
        cloudduration=random(Min_Cloud_Duration,Max_Cloud_Duration);
        //Pick a random number between 0 and 99
        lightningchance=random(100);
        // if picked number is greater than Lightning_Change_per_Cloud, we will not have lightning today
        if (lightningchance>Lightning_Change_per_Cloud) lightningchance=0;
      }
    }
  // Now that we have all the parameters for the cloud, let's create the effect

  if (cloudchance)
  {
    //is it time for cloud yet?
    if (NumMins(hour(),minute())>=cloudstart && NumMins(hour(),minute())<(cloudstart+cloudduration))
    {
      // let's go through all channels to pick which ones will be dimmed
      for (int a=0;a<6;a++)
      {
        if (bitRead(Actinic_Channels,a)==0)
        {
          // this will slope down the channel from the current PWM to 0 within 3minutes.
          // then it will stay at 0 for the duration of the cycle
          // and finally slope up from 0 to PWM value within 3 minutes
          // it is basically an inversed slope
          ChannelValue[a]=ReversePWMSlope(cloudstart,cloudstart+cloudduration,ChannelValue[a],0,180);
        }
      }
      if (lightningchance && (NumMins(hour(),minute())==(cloudstart+(cloudduration/2))) && second()<5) 
      {
        for (int b=0;b<6;b++)
        {
          if (bitRead(Daylight_Channels,b)==1)
          {
            if (random(100)<20) lightningstatus=1; 
            else lightningstatus=0;
            if (lightningstatus) ChannelValue[b]=100; 
            else ChannelValue[b]=0;
            //delay(10);
          }
          else
          {
            ChannelValue[b]=0;
          }
        }
      }
    }
    if (NumMins(hour(),minute())>(cloudstart+cloudduration))
    {
      cloudindex++;
      if (cloudindex < numclouds)
      {
        cloudstart=random(Start_Cloud_After+(((End_Cloud_Before-Start_Cloud_After)/(numclouds*2))*cloudindex*2),(Start_Cloud_After+(((End_Cloud_Before-Start_Cloud_After)/(numclouds*2))*cloudindex*2))+((End_Cloud_Before-Start_Cloud_After)/(numclouds*2)));
        // pick a random number for the cloud duration of first cloud.
        cloudduration=random(Min_Cloud_Duration,Max_Cloud_Duration);
        //Pick a random number between 0 and 99
        lightningchance=random(100);
        // if picked number is greater than Lightning_Change_per_Cloud, we will not have lightning today
        if (lightningchance>Lightning_Change_per_Cloud) lightningchance=0;
      }
    }
  }
  
//  if (LastNumMins!=NumMins(hour(),minute()))
//  {
//    LastNumMins=NumMins(hour(),minute());
//    ReefAngel.LCD.Clear(255,0,120,132,132);
//    ReefAngel.LCD.DrawText(0,255,5,120,"C");
//    ReefAngel.LCD.DrawText(0,255,11,120,"00:00");
//    ReefAngel.LCD.DrawText(0,255,45,120,"L");
//    ReefAngel.LCD.DrawText(0,255,51,120,"00:00");
//    if (cloudchance && (NumMins(hour(),minute())<cloudstart))
//    {
//      int x=0;
//      if ((cloudstart/60)>=10) x=11; else x=17;
//      ReefAngel.LCD.DrawText(0,255,x,120,(cloudstart/60));
//      if ((cloudstart%60)>=10) x=29; else x=35;
//      ReefAngel.LCD.DrawText(0,255,x,120,(cloudstart%60));
//    }
//    ReefAngel.LCD.DrawText(0,255,90,120,cloudduration);
//    if (lightningchance) 
//    {
//      int x=0;
//      if (((cloudstart+(cloudduration/2))/60)>=10) x=51; else x=57;
//      ReefAngel.LCD.DrawText(0,255,x,120,((cloudstart+(cloudduration/2))/60));
//      if (((cloudstart+(cloudduration/2))%60)>=10) x=69; else x=75;
//      ReefAngel.LCD.DrawText(0,255,x,120,((cloudstart+(cloudduration/2))%60));
//    }
//  }   
}

byte ReversePWMSlope(long cstart,long cend,byte PWMStart,byte PWMEnd, byte clength)
{
  long n=elapsedSecsToday(now());
  cstart*=60;
  cend*=60;
  if (n<cstart) return PWMStart;
  if (n>=cstart && n<=(cstart+clength)) return map(n,cstart,cstart+clength,PWMStart,PWMEnd);
  if (n>(cstart+clength) && n<(cend-clength)) return PWMEnd;
  if (n>=(cend-clength) && n<=cend) return map(n,cend-clength,cend,PWMEnd,PWMStart);
  if (n>cend) return PWMStart;
}

rimai · Post by **rimai** » Mon May 28, 2012 2:59 pm

On your main code, add this above setup():

Code: Select all

byte SeasonsVar[]={
  0,0,0,0,0,0};
int LastNumMins=0;

This to loop():

Code: Select all

  Wire.requestFrom(8,6);
  for (int a=0;a<6;a++)
  {
    if (Wire.available()) SeasonsVar[a]=Wire.read();
  }
  if (LastNumMins!=NumMins(hour(),minute()))
  {
    LastNumMins=NumMins(hour(),minute());
    ReefAngel.LCD.Clear(255,0,120,132,132);
    ReefAngel.LCD.DrawText(0,255,5,120,"C");
    ReefAngel.LCD.DrawText(0,255,11,120,"00:00");
    ReefAngel.LCD.DrawText(0,255,45,120,"L");
    ReefAngel.LCD.DrawText(0,255,51,120,"00:00");
    if (SeasonsVar[4])
    {
      int x=0;
      if (SeasonsVar[0]>=10) x=11; else x=17;
      ReefAngel.LCD.DrawText(0,255,x,120,SeasonsVar[0]);
      if (SeasonsVar[1]>=10) x=29; else x=35;
      ReefAngel.LCD.DrawText(0,255,x,120,SeasonsVar[1]);
    }
    if (SeasonsVar[5]) 
    {
      int x=0;
      if (SeasonsVar[3]>=10) x=51; else x=57;
      ReefAngel.LCD.DrawText(0,255,x,120,SeasonsVar[3]);
      if (SeasonsVar[4]>=10) x=69; else x=75;
      ReefAngel.LCD.DrawText(0,255,x,120,SeasonsVar[4]);
    }
  }

abhi_123 · Post by **abhi_123** » Tue May 29, 2012 5:17 am

well do i need to delete the parabola setting before putting this inside the loop?

rimai · Post by **rimai** » Tue May 29, 2012 7:47 am

No, what this is supposed to do is draw the time that the next cloud will happen.
It should draw right below the clock.

abhi_123 · Post by **abhi_123** » Tue May 29, 2012 8:29 am

Alright. So should i put this in custom code below the parabola?

rimai · Post by **rimai** » Tue May 29, 2012 8:38 am

That works.

abhi_123 · Post by **abhi_123** » Tue May 29, 2012 9:22 am

loaded the code. its displaying C16:51 & L56:31. What does it means?

Reef Angel Forum

Coding Pwm module.

Re: Coding Pwm module.

Re: Coding Pwm module.

Re: Coding Pwm module.

Re: Coding Pwm module.

Re: Coding Pwm module.

Re: Coding Pwm module.

Re: Coding Pwm module.

Re: Coding Pwm module.

Re: Coding Pwm module.

Re: Coding Pwm module.

Re: Coding Pwm module.

Re: Coding Pwm module.

Re: Coding Pwm module.

Re: Coding Pwm module.

Re: Coding Pwm module.

Re: Coding Pwm module.

Re: Coding Pwm module.

Re: Coding Pwm module.

Re: Coding Pwm module.

Re: Coding Pwm module.

Re: Coding Pwm module.

Re: Coding Pwm module.

Re: Coding Pwm module.

Re: Coding Pwm module.

Re: Coding Pwm module.

Re: Coding Pwm module.

Re: Coding Pwm module.

Re: Coding Pwm module.

Re: Coding Pwm module.

Re: Coding Pwm module.

Login • Register