Reef Angel Forum

Code: Select all

/**
 * I2CScanner.pde -- I2C bus scanner for Arduino
 *
 * 2009, Tod E. Kurt, http://todbot.com/blog/
 *
 */

#include "Wire.h"
extern "C" { 
#include "utility/twi.h"  // from Wire library, so we can do bus scanning
}

// Scan the I2C bus between addresses from_addr and to_addr.
// On each address, call the callback function with the address and result.
// If result==0, address was found, otherwise, address wasn't found
// (can use result to potentially get other status on the I2C bus, see twi.c)
// Assumes Wire.begin() has already been called
void scanI2CBus(byte from_addr, byte to_addr, 
void(*callback)(byte address, byte result) ) 
{
  byte rc;
  byte data = 0; // not used, just an address to feed to twi_writeTo()
  for( byte addr = from_addr; addr <= to_addr; addr++ ) {
    rc = twi_writeTo(addr, &data, 0, 1, true);
    callback( addr, rc );
  }
}

// Called when address is found in scanI2CBus()
// Feel free to change this as needed
// (like adding I2C comm code to figure out what kind of I2C device is there)
void scanFunc( byte addr, byte result ) {
  Serial.print("addr: ");
  Serial.print(addr,HEX);
  Serial.print( (result==0) ? " found!":"       ");
  Serial.print( (addr%4) ? "\t":"\n");
}

#define sbi(port,bitnum)		port |= _BV(bitnum)
#define cbi(port,bitnum)		port &= ~(_BV(bitnum))

#define i2cMux  0x70

#define i2cMuxEnable  43

byte start_address = 1;
byte end_address = 128;

byte muxpresent=0;
// standard Arduino setup()
void setup()
{
  Wire.begin();
  pinMode(7,OUTPUT);
  Serial.begin(57600);
  DDRH|=(1<<2); // Port PH2 output (Exp Bus Power)
  cbi(PORTH,2); // Turn on exp bus power
  pinMode(i2cMuxEnable,OUTPUT);
  digitalWrite(i2cMuxEnable,LOW);
  delay(1000);
  digitalWrite(i2cMuxEnable,HIGH);
  delay(100);
  Wire.beginTransmission(i2cMux);
  Wire.write(0xf);
  muxpresent=Wire.endTransmission();
  delay(100);
  
  if(muxpresent!=0)
  {
    Serial.println(muxpresent);
    Serial.println("I2C Mux not found");
  }
  else
  {
    Wire.beginTransmission(i2cMux);
    Wire.requestFrom(i2cMux, 1);
    delay(100);
    if (Wire.available())
    {
      byte channels=Wire.read();
      Serial.println(channels);
      if (channels==0xf)
        Serial.println("All channels active");
      else
        Serial.println("Error setting channels");
    }
    else
    {
      Serial.println("No response from I2C Mux");
    }
    Wire.endTransmission();
    
    Serial.println("I2CScanner ready!");
  
    Serial.print("starting scanning of I2C bus from ");
    Serial.print(start_address,DEC);
    Serial.print(" to ");
    Serial.print(end_address,DEC);
    Serial.println("...");
  
    // start the scan, will call "scanFunc()" on result from each address
    scanI2CBus( start_address, end_address, scanFunc );
  
    Serial.println("\ndone");
  }
}

// standard Arduino loop()
void loop() 
{
  // Nothing to do here, so we'll just blink the built-in LED
  digitalWrite(7,HIGH);
  delay(300);
  digitalWrite(7,LOW);
  delay(300);
}

Code: Select all

#define I2CPWM_PCA9685		0x40
#define I2CPWM_16CH_PCA9685		0x41