Reef Angel Forum

Posted: **Sun Jul 12, 2015 4:20 pm**

Thanks Colin. The only thing dirty is that it depends on 100% chance of clouds. If it's not a cloudy day I won't be able to trigger. But this is good... better than anything else I've seen. I'm looking forward to testing it!

Posted: **Mon Jul 13, 2015 6:34 am**

Ok, so here's my report back. I had a few issues and some warnings just in case other's decide to follow suit. I know of only one person impacted though (AlanM...)

I realized just now you're writing all these portal variables.. well I so happen to have one that if I put my alk reading in, it will calculate how much alk and start dosing it. Now, I caught this quickly enough, but I probably dosed a 150ml or so into the tank. Don't feel bad, it's essentially a softie tank, all my SPS died a while ago, just hope the stylo and spongodes that made it through can handle it. Water change is happening this morning regardless.

Now back to the code. I need to do some more testing, which I'll take care of shortly, but my lights essentially do nothing (I didn't see them dim, but I wasn't watching the controller either...) Then the lights go off and I think the lightning kicks in shortly after. There were a few effects that were cool, some that were going on/off too fast. Part of the problem is the RA turns my ports off if the dimming is less than 1%. I'm going to try the effect with the bottom at 2% and let's see this way the relay's not in the way. I aslo did some tweaks because in a cloud you're only going to get one lightning sequence at 5 seconds. I upped it to 10 and made it happen every minute after a 3rd of the way through. Anyway a little ways after that, my whites came back on in sequence which was perfect (thought they went off simultaneously).

I'm going to upload my fixes and tweaks and try again once my lighting comes back on. Will report back soon.

Posted: **Mon Jul 13, 2015 8:03 am**

The hardest part is getting it to work on other folks hardware, since I can't test every configuration. I basically lost interest in the slow mode after getting the fast drivers.

Sorry about the alk. Hope it doesn't hurt anything.

--Colin

Posted: **Mon Jul 13, 2015 11:59 am**

Ok. everything is actually working good... I'm happy with the longer lightning strike. I also broke the Slow stuff into a separate function so I could call it separately while a different relay is on. So I have one state that triggers the cloud and another state that triggers just lightning every minute

I then enhanced the slow strike a bit by separating out my two channels so there's a chance for both to light and a slight chance for left and right separately. The effect is pretty cool. I also added a HighRes ReversePWMSlope, not that it was needed, but since we're dealing with a HighRes variable it was easy enough to do. I separated out the Drawing functions to another function so I had to make the variables global. If I can make this more OO then those would go away, I'm hoping they annoy me enough to do the work.

Anyway, here's what I left off with. I've been toying with increasing my actinic channel during a cloud or lightning, I left that commented out for now.

Code: Select all

// ------------------------------------------------------------
// Do not change anything below here

static byte cloudchance=255;
static byte cloudduration=0;
static int cloudstart=0;
static byte numclouds=0;
static byte lightningchance=0;
static byte cloudindex=0;
static byte lightningstatus=0;
static byte lightningMode=0;
static boolean chooseLightning=true;

void CheckCloud()
{

  // ------------------------------------------------------------
  // Change the values below to customize your cloud/storm effect

  // Frequency in days based on the day of the month - number 2 means every 2 days, for example (day 2,4,6 etc)
  // For testing purposes, you can use 1 and cause the cloud to occur everyday
#define Clouds_Every_X_Days 1 

  // Percentage chance of a cloud happening today
  // For testing purposes, you can use 100 and cause the cloud to have 100% chance of happening
#define Cloud_Chance_per_Day 100

  // Minimum number of minutes for cloud duration.  Don't use min duration of less than 6
#define Min_Cloud_Duration 10

  // Maximum number of minutes for the cloud duration. Don't use max duration of more than 255
#define Max_Cloud_Duration 20

  // Minimum number of clouds that can happen per day
#define Min_Clouds_per_Day 1

  // Maximum number of clouds that can happen per day
#define Max_Clouds_per_Day 4

  // Only start the cloud effect after this setting
  // In this example, start cloud after noon
#define Start_Cloud_After NumMins(12,00)

  // Always end the cloud effect before this setting
  // In this example, end cloud before 9:00pm
#define End_Cloud_Before NumMins(23,00)

  // Percentage chance of a lightning happen for every cloud
  // For testing purposes, you can use 100 and cause the lightning to have 100% chance of happening
#define Lightning_Change_per_Cloud 100

  // Note: Make sure to choose correct values that will work within your PWMSLope settings.
  // For example, in our case, we could have a max of 5 clouds per day and they could last for 50 minutes.
  // Which could mean 250 minutes of clouds. We need to make sure the PWMSlope can accomodate 250 minutes 
  // of effects or unforseen result could happen.
  // Also, make sure that you can fit double those minutes between Start_Cloud_After and End_Cloud_Before.
  // In our example, we have 510 minutes between Start_Cloud_After and End_Cloud_Before, so double the
  // 250 minutes (or 500 minutes) can fit in that 510 minutes window.
  // It's a tight fit, but it did.

  //#define printdebug // Uncomment this for debug print on Serial Monitor window
#define forcecloudcalculation // Uncomment this to force the cloud calculation to happen in the boot process. 

  // Add Random Lightning modes
#define Calm 0    // No lightning
#define Slow 1    // 5 seconds of slow lightning in the middle of a cloud for ELN style (slow response) drivers
#define Fast 2    // 5 seconds of fast lightning in the middle of a cloud for LDD style (fast response) drivers
#define Mega 3    // Lightning throughout the cloud, higher chance as it gets darker
#define Mega2 4   // Like Mega, but with more lightning
  // Set which modes you want to use
  // Example:  { Calm, Fast, Mega, Mega2 } to randomize all four modes.  
  // { Mega2 } for just Mega2.  { Mega, Mega, Fast} for Mega and Fast, with twice the chance of Mega.
  byte LightningModes[] = {Slow};

  // Change the values above to customize your cloud/storm effect

  static time_t DelayCounter=millis();    // Variable for lightning timing.  
  static int DelayTime=random(1000);      // Variable for lightning timimg.

  // Every day at midnight, we check for chance of cloud happening today
  if (hour()==0 && minute()==0 && second()==0) cloudchance=255;

#ifdef forcecloudcalculation
  if (cloudchance==255)
#else
    if (hour()==0 && minute()==0 && second()==1 && cloudchance==255) 
#endif
    {
      randomSeed(millis());    // Seed the random number generator
      //Pick a random number between 0 and 99
      cloudchance=random(100); 
      // if picked number is greater than Cloud_Chance_per_Day, we will not have clouds today
      if (cloudchance>Cloud_Chance_per_Day) cloudchance=0;
      // Check if today is day for clouds. 
      if ((day()%Clouds_Every_X_Days)!=0) cloudchance=0; 
      // If we have cloud today
      if (cloudchance)
      {
        // pick a random number for number of clouds between Min_Clouds_per_Day and Max_Clouds_per_Day
        numclouds=random(Min_Clouds_per_Day,Max_Clouds_per_Day);
        // pick the time that the first cloud will start
        // the range is calculated between Start_Cloud_After and the even distribuition of clouds on this day. 
        cloudstart=random(Start_Cloud_After,Start_Cloud_After+((End_Cloud_Before-Start_Cloud_After)/(numclouds*2)));
        // pick a random number for the cloud duration of first cloud.
        cloudduration=random(Min_Cloud_Duration,Max_Cloud_Duration);
        //Pick a random number between 0 and 99
        lightningchance=random(100);
        // if picked number is greater than Lightning_Change_per_Cloud, we will not have lightning today
        if (lightningchance>Lightning_Change_per_Cloud) lightningchance=0; 
      }
    }
  // Now that we have all the parameters for the cloud, let's create the effect


  if (cloudchance)
  {
    if (ReefAngel.Relay.isMaskOn(LED_STORM))      // Change this to whatever port you want to use as a trigger.
    {
      cloudstart = NumMins(hour(), minute());
      ReefAngel.Relay.Auto(LED_STORM);    // Here, too.
    }
    //is it time for cloud yet?
    if (NumMins(hour(),minute())>=cloudstart && NumMins(hour(),minute())<(cloudstart+cloudduration))
    {
      // Increase Blue channel first for better effect and to compensate for drop in Whites
      //ActinicPWMValue1=ReversePWMSlopeHighRes(cloudstart,cloudstart+cloudduration,ActinicPWMValue1,ActinicPWMValue1+DaylightPWMValue0,180);
      //ActinicPWMValue3=ReversePWMSlopeHighRes(cloudstart,cloudstart+cloudduration,ActinicPWMValue3,ActinicPWMValue3+DaylightPWMValue2,180);
      
      DaylightPWMValue0=ReversePWMSlopeHighRes(cloudstart,cloudstart+cloudduration,DaylightPWMValue0,0,180);
      DaylightPWMValue2=ReversePWMSlopeHighRes(cloudstart,cloudstart+cloudduration,DaylightPWMValue2,0,180);
      if (chooseLightning) 
      { 
        lightningMode=LightningModes[random(100)%sizeof(LightningModes)]; 
        chooseLightning=false; 
      } 
      switch (lightningMode) 
      {
      case Calm:
        break;
      case Mega:
        // Lightning chance from beginning of cloud through the end.  Chance increases with darkness of cloud.
        if (lightningchance && random(ReversePWMSlope(cloudstart,cloudstart+cloudduration,100,0,180))<1 && (millis()-DelayCounter)>DelayTime)
        {
          // Send the trigger 
          Strike();
          DelayCounter=millis();    // If we just had a round of flashes, then lets put in a longer delay
          DelayTime=random(1000);   // of up to a second for dramatic effect before we do another round. 
        }
        break;
      case Mega2:
        // Higher lightning chance from beginning of cloud through the end.  Chance increases with darkness of cloud.
        if (lightningchance && random(ReversePWMSlope(cloudstart,cloudstart+cloudduration,100,0,180))<2)
        {
          Strike();
        }
        break;
      case Fast:
        // 5 seconds of lightning in the middle of the cloud
        if (lightningchance && (NumMins(hour(),minute())==(cloudstart+(cloudduration/2))) && second()<5 && (millis()-DelayCounter)>DelayTime)
        {
          Strike();

          DelayCounter=millis();    // If we just had a round of flashes, then lets put in a longer delay
          DelayTime=random(1000);   // of up to a second for dramatic effect before we do another round. 
        }
        break;
      case Slow:
        // Slow lightning for 5 seconds in the middle of the cloud.  Suitable for slower ELN style drivers
        if (lightningchance && (NumMins(hour(),minute())>=(cloudstart+(cloudduration/3))) && second()<10) 
        {
          SlowStrike();
        }
        break;
      default:
        break;
      }
    } 
    else 
    {
      chooseLightning=true; // Reset the flag to choose a new lightning type
    }

    if (NumMins(hour(),minute())>(cloudstart+cloudduration))
    {
      cloudindex++;
      if (cloudindex < numclouds)
      {
        cloudstart=random(Start_Cloud_After+(((End_Cloud_Before-Start_Cloud_After)/(numclouds*2))*cloudindex*2),(Start_Cloud_After+(((End_Cloud_Before-Start_Cloud_After)/(numclouds*2))*cloudindex*2))+((End_Cloud_Before-Start_Cloud_After)/(numclouds*2)));
        // pick a random number for the cloud duration of first cloud.
        cloudduration=random(Min_Cloud_Duration,Max_Cloud_Duration);
        //Pick a random number between 0 and 99
        lightningchance=random(100);
        // if picked number is greater than Lightning_Change_per_Cloud, we will not have lightning today
        if (lightningchance>Lightning_Change_per_Cloud) lightningchance=0;
      }
    }  
  }
  
  // Cloud ON option - Clouds every minute
  if (ReefAngel.Relay.isMaskOff(LED_STORM) && now()%60<10) 
  {
    SlowStrike();
  }
}

void SlowStrike() 
{
    int r = random(100);
    if (r<20) lightningstatus=1; 
    else lightningstatus=0;
    if (lightningstatus)
    {
      // Let's separate left and right both.
      if (r<13  ) {
        DaylightPWMValue0=4095; 
        DaylightPWMValue2=4095;
      } else if (r<16) {
        DaylightPWMValue0=4095;
        DaylightPWMValue2=100;
      } else {
        DaylightPWMValue0=100;
        DaylightPWMValue2=4095;
      }
    }
    else 
    {
      DaylightPWMValue0=100;
      DaylightPWMValue2=100;
    }
    delay(1);
}  

void DrawClouds(int x, int y) 
{
    // Write the times of the next cloud, next lightning, and cloud duration to the screen and into some customvars for the Portal.
    ReefAngel.LCD.DrawText(0,255,x,y,"C"); x+=6;
    ReefAngel.LCD.DrawText(0,255,x,y,"00:00"); x+=34;
    ReefAngel.LCD.DrawText(0,255,x,y,"L"); x+=6;
    ReefAngel.LCD.DrawText(0,255,x,y,"00:00"); x=5; 
    if (cloudchance && (NumMins(hour(),minute())<cloudstart))
    {
      int x=0;
      if ((cloudstart/60)>=10) x=11; 
      else x=17;
      ReefAngel.LCD.DrawText(0,255,x,y,(cloudstart/60));
      //ReefAngel.CustomVar[3]=cloudstart/60; // Write the hour of the next cloud to custom variable for Portal reporting
      if ((cloudstart%60)>=10) x=29; 
      else x=35;
      ReefAngel.LCD.DrawText(0,255,x,y,(cloudstart%60));
      //ReefAngel.CustomVar[4]=cloudstart%60; // Write the minute of the next cloud to custom variable for Portal reporting

    }
    ReefAngel.LCD.DrawText(0,255,x+85,y,cloudduration);
    //ReefAngel.CustomVar[7]=(cloudduration);    // Put the duration of the next cloud in a custom var for the portal
    if (lightningchance) 
    {
      int x=0;
      if (((cloudstart+(cloudduration/3))/60)>=10) x=51; 
      else x=57;
      ReefAngel.LCD.DrawText(0,255,x,y,((cloudstart+(cloudduration/3))/60));
      //ReefAngel.CustomVar[5]=(cloudstart+(cloudduration/2))/60;    // Write the hour of the next lightning to a custom variable for the Portal
      if (((cloudstart+(cloudduration/3))%60)>=10) x=69; 
      else x=75;
        ReefAngel.LCD.DrawText(0,255,x,y,((cloudstart+(cloudduration/3))%60)); // Write the minute of the next lightning to a custom variable for the Portal
        //ReefAngel.CustomVar[6]=(cloudstart+(cloudduration/2))%60;
    }
}

void Strike()
{
  int a=random(1,5);    // Pick a number of consecutive flashes from 1 to 4.  
  for (int i=0; i<a; i++)
  {
    // Flash on
    int newdata=4095;
    Wire.beginTransmission(0x40);      // Address of the dimming expansion module
    Wire.write(0x8+(4*0));             // 0x8 is channel 0, 0x12 is channel 1, etc.  This is channel 0.
    Wire.write(newdata&0xff);          // Send the data 8 bits at a time.  This sends the LSB
    Wire.write(newdata>>8);            // This sends the MSB
    Wire.endTransmission();
    
    Wire.beginTransmission(0x40);      // Address of the dimming expansion module
    Wire.write(0x8+(4*2));             // 0x8 is channel 0, 0x12 is channel 1, etc.  This is channel 2.
    Wire.write(newdata&0xff);          // Send the data 8 bits at a time.  This sends the LSB
    Wire.write(newdata>>8);            // This sends the MSB
    Wire.endTransmission();
    
    int randy=random(20,80);    // Random number for a delay
    if (randy>71) randy=((randy-70)/2)*100;    // Small chance of a longer delay
    delay(randy);                // Wait from 20 to 69 ms, or 100-400 ms
    
    // Flash off.  Return to baseline.
    newdata=ReefAngel.PWM.GetChannelValueRaw(0);   // Use the channel number you're flashing here
    Wire.beginTransmission(0x40);    // Same as above
    Wire.write(0x8+(4*0));
    Wire.write(newdata&0xff);
    Wire.write(newdata>>8);
    Wire.endTransmission();
    
    newdata=ReefAngel.PWM.GetChannelValueRaw(2);   // Use the channel number you're flashing here
    Wire.beginTransmission(0x40);    // Same as above
    Wire.write(0x8+(4*2));
    Wire.write(newdata&0xff);
    Wire.write(newdata>>8);
    Wire.endTransmission();
    
    delay(random(30,50));                // Wait from 30 to 49 ms 
    wdt_reset();    // Reset watchdog timer to avoid re-boots
  }
}

byte ReversePWMSlope(long cstart,long cend,byte PWMStart,byte PWMEnd, byte clength)
{
  long n=elapsedSecsToday(now());
  cstart*=60;
  cend*=60;
  if (n<cstart) return PWMStart;
  if (n>=cstart && n<=(cstart+clength)) return map(n,cstart,cstart+clength,PWMStart,PWMEnd);
  if (n>(cstart+clength) && n<(cend-clength)) return PWMEnd;
  if (n>=(cend-clength) && n<=cend) return map(n,cend-clength,cend,PWMEnd,PWMStart);
  if (n>cend) return (int) PWMStart;
}

int ReversePWMSlopeHighRes(long cstart,long cend,int PWMStart,int PWMEnd, byte clength)
{
  long n=elapsedSecsToday(now());
  cstart*=60;
  cend*=60;
  if (n<cstart) return PWMStart;
  if (n>=cstart && n<=(cstart+clength)) return map(n,cstart,cstart+clength,PWMStart,PWMEnd);
  if (n>(cstart+clength) && n<(cend-clength)) return PWMEnd;
  if (n>=(cend-clength) && n<=cend) return map(n,cend-clength,cend,PWMEnd,PWMStart);
  if (n>cend) return (int) PWMStart;
}

Posted: **Mon Jul 13, 2015 12:01 pm**

As far as the alk, don't worry, I think I'll be fine. At least my pH alarm caught it. I spiked to 8.6. I would have gotten to it sooner too if I wasn't also testing new code since I thought the alert was from a few of the power cycles. Glad I took a closer look!

Posted: **Mon Jul 13, 2015 12:13 pm**

God I so want to get this working, but I need to get my light straightened out and working properly first.

At first my channel 3 (the 2nd Daylight) wasn't dimming so I opened the light up over the weekend and some of the wire slipped out of the connection so I re-did everything and it just made it worse.

Now none of the channels dim and my moonlight are not functioning properly. Staying full on day and night.

This code does not seem to be working or I have a bad connection somewhere.

Code: Select all

  if ( hour()>=13 && hour()<21 )
  ReefAngel.PWM.SetChannel( 5, 0 );
  else
  ReefAngel.PWM.SetChannel( 5, PWMSlope(21,0,13,0,0,MoonPhase() ,60,0) );

I need to get some time and un-mod the lights, get the moonlights working again and start from scratch,

Posted: **Mon Jul 13, 2015 1:01 pm**

Lee were you testing your lights around 12:20 today?

I took a look at your Reeftronics specs to see how your lights dim and there was a spike at 12:20pm

It looks funny.

Posted: **Mon Jul 13, 2015 1:14 pm**

What your seeing is my moonlights. They do a parabola from Moon rise to moon set and they go from 100-0 and 0-100 to fill in the 0-10% that my regular lights can't do. The spikes you see are morning and night

Overall though I've been testing my lights all day. I now have a bunch of presets I can use as well as on-demand clouds on-demand lightning

Posted: **Mon Jul 13, 2015 1:35 pm**

lnevo wrote:Ok. everything is actually working good... I'm happy with the longer lightning strike. I also broke the Slow stuff into a separate function so I could call it separately while a different relay is on. So I have one state that triggers the cloud and another state that triggers just lightning every minute I then enhanced the slow strike a bit by separating out my two channels so there's a chance for both to light and a slight chance for left and right separately. The effect is pretty cool. I also added a HighRes ReversePWMSlope, not that it was needed, but since we're dealing with a HighRes variable it was easy enough to do. I separated out the Drawing functions to another function so I had to make the variables global. If I can make this more OO then those would go away, I'm hoping they annoy me enough to do the work.

I've been considering breaking out my lights to left and right channels (they're 1 channel for both sides right now) to enchance the lightning effect, similar to what you did. I have a week off coming up so I just might do that.

Posted: **Mon Jul 13, 2015 1:59 pm**

Here, this might convince you.

http://youtu.be/Ajs5kDfPlzk

Posted: **Mon Jul 13, 2015 2:02 pm**

The music sucks, but it looks nice.

Posted: **Mon Jul 13, 2015 2:06 pm**

It was stock. Needed something that matched the mood.

Posted: **Mon Jul 13, 2015 2:08 pm**

2 strange requests if it's not to much trouble.
1st the ability to add a thunder clap SFX.
2nd possible lightning strike at night when the lights are off or at 0.

You can tell me no and I won't be offended.

Posted: **Mon Jul 13, 2015 2:20 pm**

I've tested with blues off. I don't see why it wouldn't work with all lights off. Yes, I'm sorely missing sound effects. Where has that code gone...

Posted: **Tue Jul 14, 2015 3:14 am**

For sound effects, just have a neighborhood kid stand by the tank and say 'pew pew pew' when the lightning goes off.

--Colin

Posted: **Thu Jul 16, 2015 4:48 pm**

Stole the ReversePWMSlopeHighRes function and split my whites into left and right channels. Here's the result.

http://www.youtube.com/watch?v=ZoMFDrJqGgg

Posted: **Fri Jul 17, 2015 8:18 pm**

It looks awesome Colin. I think I need to do something where I do more frequent but shorter clouds. I also think I need to get my blue channel involved as well. I wish I could swap my drivers for something better. Love my lights though and now that I have some effects, it's awesome. Btw, I have to also say that having a set of presets is awesome. I can now in one click select any ration whites to blues. The cool thing is I run that before I run the cloud function, so I can see the cloud/lightning or lightning effect on any temp combo.

Posted: **Fri Jul 17, 2015 8:46 pm**

Here's what I'm currently getting ready to test. I've added the blues, but not sure my function will work. I'm also brightning the blues when the lightning strikes because my whites need to stay on for the cloud duration. I lowered that from 10 seconds to 8 and made it recur every 45 seconds instead of every 60. We'll see how it does.

Code: Select all


void CheckCloud()
{


  // Set which modes you want to use
  // Example:  { Calm, Fast, Mega, Mega2 } to randomize all four modes.  
  // { Mega2 } for just Mega2.  { Mega, Mega, Fast} for Mega and Fast, with twice the chance of Mega.
  byte LightningModes[] = {Slow};

  // Change the values above to customize your cloud/storm effect

  static time_t DelayCounter=millis();    // Variable for lightning timing.  
  static int DelayTime=random(1000);      // Variable for lightning timimg.

  // Every day at midnight, we check for chance of cloud happening today
  if (hour()==0 && minute()==0 && second()==0) cloudchance=255;

#ifdef forcecloudcalculation
  if (cloudchance==255)
#else
    if (hour()==0 && minute()==0 && second()==1 && cloudchance==255) 
#endif
    {
      randomSeed(millis());    // Seed the random number generator
      //Pick a random number between 0 and 99
      cloudchance=random(100); 
      // if picked number is greater than Cloud_Chance_per_Day, we will not have clouds today
      if (cloudchance>Cloud_Chance_per_Day) cloudchance=0;
      // Check if today is day for clouds. 
      if ((day()%Clouds_Every_X_Days)!=0) cloudchance=0; 
      // If we have cloud today
      if (cloudchance)
      {
        // pick a random number for number of clouds between Min_Clouds_per_Day and Max_Clouds_per_Day
        numclouds=random(Min_Clouds_per_Day,Max_Clouds_per_Day);
        // pick the time that the first cloud will start
        // the range is calculated between Start_Cloud_After and the even distribuition of clouds on this day. 
        cloudstart=random(Start_Cloud_After,Start_Cloud_After+((End_Cloud_Before-Start_Cloud_After)/(numclouds*2)));
        // pick a random number for the cloud duration of first cloud.
        cloudduration=random(Min_Cloud_Duration,Max_Cloud_Duration);
        //Pick a random number between 0 and 99
        lightningchance=random(100);
        // if picked number is greater than Lightning_Chance_per_Cloud, we will not have lightning today
        if (lightningchance>Lightning_Chance_per_Cloud) lightningchance=0; 
      }
    }
  // Now that we have all the parameters for the cloud, let's create the effect


  if (cloudchance)
  {
    if (ReefAngel.Relay.isMaskOff(LED_STORM))      // Change this to whatever port you want to use as a trigger.
    {
      cloudstart = NumMins(hour(), minute());
      ReefAngel.Relay.Auto(LED_STORM);    // Here, too.
    }
    //is it time for cloud yet?
    if (NumMins(hour(),minute())>=cloudstart && NumMins(hour(),minute())<(cloudstart+cloudduration))
    {
      // Increase Blue channel first for better effect and to compensate for drop in Whites
      ActinicPWMValue1=ReversePWMSlopeHighRes(cloudstart,cloudstart+cloudduration,ActinicPWMValue1,ActinicPWMValue1+DaylightPWMValue0,180);
      ActinicPWMValue3=ReversePWMSlopeHighRes(cloudstart,cloudstart+cloudduration,ActinicPWMValue3,ActinicPWMValue3+DaylightPWMValue2,180);
      
      DaylightPWMValue0=ReversePWMSlopeHighRes(cloudstart,cloudstart+cloudduration,DaylightPWMValue0,0,180);
      DaylightPWMValue2=ReversePWMSlopeHighRes(cloudstart,cloudstart+cloudduration,DaylightPWMValue2,0,180);
      if (chooseLightning) 
      { 
        lightningMode=LightningModes[random(100)%sizeof(LightningModes)]; 
        chooseLightning=false; 
      } 
      switch (lightningMode) 
      {
      case Calm:
        break;
      case Mega:
        // Lightning chance from beginning of cloud through the end.  Chance increases with darkness of cloud.
        if (lightningchance && random(ReversePWMSlope(cloudstart,cloudstart+cloudduration,100,0,180))<1 && (millis()-DelayCounter)>DelayTime)
        {
          // Send the trigger 
          Strike();
          DelayCounter=millis();    // If we just had a round of flashes, then lets put in a longer delay
          DelayTime=random(1000);   // of up to a second for dramatic effect before we do another round. 
        }
        break;
      case Mega2:
        // Higher lightning chance from beginning of cloud through the end.  Chance increases with darkness of cloud.
        if (lightningchance && random(ReversePWMSlope(cloudstart,cloudstart+cloudduration,100,0,180))<2)
        {
          Strike();
        }
        break;
      case Fast:
        // 5 seconds of lightning in the middle of the cloud
        if (lightningchance && (NumMins(hour(),minute())==(cloudstart+(cloudduration/2))) && second()<5 && (millis()-DelayCounter)>DelayTime)
        {
          Strike();

          DelayCounter=millis();    // If we just had a round of flashes, then lets put in a longer delay
          DelayTime=random(1000);   // of up to a second for dramatic effect before we do another round. 
        }
        break;
      case Slow:
        // Slow lightning for 5 seconds in the middle of the cloud.  Suitable for slower ELN style drivers
        if (lightningchance && second()%40<8) 
        {
          SlowStrike();
        }
        break;
      default:
        break;
      }
    } 
    else 
    {
      chooseLightning=true; // Reset the flag to choose a new lightning type
    }

    if (NumMins(hour(),minute())>(cloudstart+cloudduration))
    {
      cloudindex++;
      if (cloudindex < numclouds)
      {
        cloudstart=random(Start_Cloud_After+(((End_Cloud_Before-Start_Cloud_After)/(numclouds*2))*cloudindex*2),(Start_Cloud_After+(((End_Cloud_Before-Start_Cloud_After)/(numclouds*2))*cloudindex*2))+((End_Cloud_Before-Start_Cloud_After)/(numclouds*2)));
        // pick a random number for the cloud duration of first cloud.
        cloudduration=random(Min_Cloud_Duration,Max_Cloud_Duration);
        //Pick a random number between 0 and 99
        lightningchance=random(100);
        // if picked number is greater than Lightning_Chance_per_Cloud, we will not have lightning today
        if (lightningchance>Lightning_Chance_per_Cloud) lightningchance=0;
      }
    }  
  }
  
  // Cloud ON option - Clouds every minute
  if (ReefAngel.Relay.isMaskOn(LED_STORM) && now()%60<10) 
  {
    SlowStrike();
  }
}

void SlowStrike() 
{
    int r = random(100);
    if (r<20) lightningstatus=1; 
    else lightningstatus=0;
    if (lightningstatus)
    {
      // Let's separate left and right both.
      if (r<14) {
        DaylightPWMValue0=4095; 
        DaylightPWMValue2=4095;
        ActinicPWMValue1=4095; 
        ActinicPWMValue3=4095;
      } else if (r<17) {
        DaylightPWMValue0=100;
        DaylightPWMValue2=4095;
        ActinicPWMValue3=4095;
      } else {
        DaylightPWMValue0=4095;
        ActinicPWMValue1=4095; 
        DaylightPWMValue2=100;
      }
    }
    else 
    {
      DaylightPWMValue0=100;
      DaylightPWMValue2=100;
    }
    delay(1);
}  

void DrawClouds(int x, int y) 
{
    // Write the times of the next cloud, next lightning, and cloud duration to the screen and into some customvars for the Portal.
    ReefAngel.LCD.DrawText(0,255,x,y,"C"); x+=6;
    ReefAngel.LCD.DrawText(0,255,x,y,"00:00"); x+=34;
    ReefAngel.LCD.DrawText(0,255,x,y,"L"); x+=6;
    ReefAngel.LCD.DrawText(0,255,x,y,"00:00"); x=5; 
    if (cloudchance && (NumMins(hour(),minute())<cloudstart))
    {
      int x=0;
      if ((cloudstart/60)>=10) x=11; 
      else x=17;
      ReefAngel.LCD.DrawText(0,255,x,y,(cloudstart/60));
      //ReefAngel.CustomVar[3]=cloudstart/60; // Write the hour of the next cloud to custom variable for Portal reporting
      if ((cloudstart%60)>=10) x=29; 
      else x=35;
      ReefAngel.LCD.DrawText(0,255,x,y,(cloudstart%60));
      //ReefAngel.CustomVar[4]=cloudstart%60; // Write the minute of the next cloud to custom variable for Portal reporting

    }
    ReefAngel.LCD.DrawText(0,255,x+85,y,cloudduration);
    //ReefAngel.CustomVar[7]=(cloudduration);    // Put the duration of the next cloud in a custom var for the portal
    if (lightningchance) 
    {
      int x=0;
      if (((cloudstart+(cloudduration/3))/60)>=10) x=51; 
      else x=57;
      ReefAngel.LCD.DrawText(0,255,x,y,((cloudstart+(cloudduration/3))/60));
      //ReefAngel.CustomVar[5]=(cloudstart+(cloudduration/2))/60;    // Write the hour of the next lightning to a custom variable for the Portal
      if (((cloudstart+(cloudduration/3))%60)>=10) x=69; 
      else x=75;
        ReefAngel.LCD.DrawText(0,255,x,y,((cloudstart+(cloudduration/3))%60)); // Write the minute of the next lightning to a custom variable for the Portal
        //ReefAngel.CustomVar[6]=(cloudstart+(cloudduration/2))%60;
    }
}

void Strike()
{
  int a=random(1,5);    // Pick a number of consecutive flashes from 1 to 4.  
  for (int i=0; i<a; i++)
  {
    // Flash on
    int newdata=4095;
    Wire.beginTransmission(0x40);      // Address of the dimming expansion module
    Wire.write(0x8+(4*0));             // 0x8 is channel 0, 0x12 is channel 1, etc.  This is channel 0.
    Wire.write(newdata&0xff);          // Send the data 8 bits at a time.  This sends the LSB
    Wire.write(newdata>>8);            // This sends the MSB
    Wire.endTransmission();
    
    Wire.beginTransmission(0x40);      // Address of the dimming expansion module
    Wire.write(0x8+(4*2));             // 0x8 is channel 0, 0x12 is channel 1, etc.  This is channel 2.
    Wire.write(newdata&0xff);          // Send the data 8 bits at a time.  This sends the LSB
    Wire.write(newdata>>8);            // This sends the MSB
    Wire.endTransmission();
    
    int randy=random(20,80);    // Random number for a delay
    if (randy>71) randy=((randy-70)/2)*100;    // Small chance of a longer delay
    delay(randy);                // Wait from 20 to 69 ms, or 100-400 ms
    
    // Flash off.  Return to baseline.
    newdata=ReefAngel.PWM.GetChannelValueRaw(0);   // Use the channel number you're flashing here
    Wire.beginTransmission(0x40);    // Same as above
    Wire.write(0x8+(4*0));
    Wire.write(newdata&0xff);
    Wire.write(newdata>>8);
    Wire.endTransmission();
    
    newdata=ReefAngel.PWM.GetChannelValueRaw(2);   // Use the channel number you're flashing here
    Wire.beginTransmission(0x40);    // Same as above
    Wire.write(0x8+(4*2));
    Wire.write(newdata&0xff);
    Wire.write(newdata>>8);
    Wire.endTransmission();
    
    delay(random(30,50));                // Wait from 30 to 49 ms 
    wdt_reset();    // Reset watchdog timer to avoid re-boots
  }
}

byte ReversePWMSlope(long cstart,long cend,byte PWMStart,byte PWMEnd, byte clength)
{
  long n=elapsedSecsToday(now());
  cstart*=60;
  cend*=60;
  if (n<cstart) return PWMStart;
  if (n>=cstart && n<=(cstart+clength)) return map(n,cstart,cstart+clength,PWMStart,PWMEnd);
  if (n>(cstart+clength) && n<(cend-clength)) return PWMEnd;
  if (n>=(cend-clength) && n<=cend) return map(n,cend-clength,cend,PWMEnd,PWMStart);
  if (n>cend) return (int) PWMStart;
}

int ReversePWMSlopeHighRes(long cstart,long cend,int PWMStart,int PWMEnd, byte clength)
{
  long n=elapsedSecsToday(now());
  cstart*=60;
  cend*=60;
  if (n<cstart) return PWMStart;
  if (n>=cstart && n<=(cstart+clength)) return map(n,cstart,cstart+clength,PWMStart,PWMEnd);
  if (n>(cstart+clength) && n<(cend-clength)) return PWMEnd;
  if (n>=(cend-clength) && n<=cend) return map(n,cend-clength,cend,PWMEnd,PWMStart);
  if (n>cend) return (int) PWMStart;
}

Posted: **Sun Jul 19, 2015 9:11 am**

lnevo wrote:As far as the alk, don't worry, I think I'll be fine. At least my pH alarm caught it. I spiked to 8.6. I would have gotten to it sooner too if I wasn't also testing new code since I thought the alert was from a few of the power cycles. Glad I took a closer look!

Sacohen wrote:2 strange requests if it's not to much trouble.
1st the ability to add a thunder clap SFX.
2nd possible lightning strike at night when the lights are off or at 0.

You can tell me no and I won't be offended.

Adding thunder sfx would be an awesome addition to the lightning. Maybe adding some rain as well with a small pump from the overflow to some rain shower heads. Like this one
https://www.amazon.com/gp/aw/d/B000PUHV ... OXUXL&vs=1

Sent from my Nexus 6 using Tapatalk

Posted: **Sun Aug 09, 2015 5:45 pm**

Not sure if this is the right thing to do or not.

This is my loop code

Code: Select all

void loop()
{
    ReefAngel.StandardHeater( Port2 );
if ( ReefAngel.Params.Temp[T1_PROBE] < (InternalMemory.HeaterTempOn_read() - 10)) { ReefAngel.Relay.On(Port3); };
if ( ReefAngel.Params.Temp[T1_PROBE] > (InternalMemory.HeaterTempOff_read() - 5)) { ReefAngel.Relay.Off(Port3); };
    ReefAngel.SingleATOLow( Port5 );
    ReefAngel.StandardLights( Port7,18,0,10,0 );
    ReefAngel.DayLights( Box1_Port1 );
    ReefAngel.Relay.Set( Box1_Port2, !ReefAngel.Relay.Status( Box1_Port1 ) );
    ReefAngel.PWM.DaylightPWMSlope();
    ReefAngel.PWM.ActinicPWMSlope();
    ReefAngel.Relay.Set(Port8, now()%21600<10800);

Where do i put this:

Code: Select all

    DaylightPWMValue=PWMSlopeHighRes(10,30,22,0,0,85,60,0);
     CheckCloud();
     ReefAngel.PWM.SetChannelRaw(1,DaylightPWMValue);

in place of ReefAngel.PWM.DaylightPWMSlope();

And should the last part go in here?

Code: Select all

   ////// Place your custom code below here
    [color=#BF0000]XXXXXX[/color]

    ////// Place your custom code above here

    // This should always be the last line

I am adding the dimming expansion if the post office can ever manage to get it delivered. Does this distinguish which channel on the dimming expansion i am using? I figured i would use channel 0 for my whites and 1 for my blues but not sure how this is telling which to do what? Am i missing something?

Posted: **Sun Aug 09, 2015 6:10 pm**

Also i second being able to have some lightning at night.

Posted: **Sun Aug 09, 2015 6:13 pm**

I searched all over the forums and couldn't find the code for the SFX.

Posted: **Sun Aug 09, 2015 6:14 pm**

MDB1029 wrote:Not sure if this is the right thing to do or not.

This is my loop code

Code: Select all

void loop()
{
    ReefAngel.StandardHeater( Port2 );
if ( ReefAngel.Params.Temp[T1_PROBE] < (InternalMemory.HeaterTempOn_read() - 10)) { ReefAngel.Relay.On(Port3); };
if ( ReefAngel.Params.Temp[T1_PROBE] > (InternalMemory.HeaterTempOff_read() - 5)) { ReefAngel.Relay.Off(Port3); };
    ReefAngel.SingleATOLow( Port5 );
    ReefAngel.StandardLights( Port7,18,0,10,0 );
    ReefAngel.DayLights( Box1_Port1 );
    ReefAngel.Relay.Set( Box1_Port2, !ReefAngel.Relay.Status( Box1_Port1 ) );
    ReefAngel.PWM.DaylightPWMSlope();
    ReefAngel.PWM.ActinicPWMSlope();
    ReefAngel.Relay.Set(Port8, now()%21600<10800);

Where do i put this:

Code: Select all

    DaylightPWMValue=PWMSlopeHighRes(10,30,22,0,0,85,60,0);
     CheckCloud();
     ReefAngel.PWM.SetChannelRaw(1,DaylightPWMValue);

in place of ReefAngel.PWM.DaylightPWMSlope();

Yes, but change it to ReefAngel.PWM.SetChannelRaw(0,DaylightPWMValue); if your whites are on channel 0.

And should the last part go in here?

Code: Select all

   ////// Place your custom code below here
    [color=#BF0000]XXXXXX[/color]

    ////// Place your custom code above here

    // This should always be the last line

Nope, past that. Put it at the very end, past everything else.

--Colin

Posted: **Sun Aug 09, 2015 6:16 pm**

Steve,

Here you go.

http://forum.reefangel.com/viewtopic.php?f=4&t=584

Posted: **Sun Aug 09, 2015 6:24 pm**

I knew about The Talking Reef thread, but I seem to remember another one that dealt with thunder specifically.

Posted: **Sun Aug 09, 2015 6:25 pm**

I'm still working our some issues with my dimming, before I add the lighting.

Posted: **Mon Aug 10, 2015 12:12 am**

cosmith71 wrote:
MDB1029 wrote:Not sure if this is the right thing to do or not.

This is my loop code
Code: Select all
void loop()
{
    ReefAngel.StandardHeater( Port2 );
if ( ReefAngel.Params.Temp[T1_PROBE] < (InternalMemory.HeaterTempOn_read() - 10)) { ReefAngel.Relay.On(Port3); };
if ( ReefAngel.Params.Temp[T1_PROBE] > (InternalMemory.HeaterTempOff_read() - 5)) { ReefAngel.Relay.Off(Port3); };
    ReefAngel.SingleATOLow( Port5 );
    ReefAngel.StandardLights( Port7,18,0,10,0 );
    ReefAngel.DayLights( Box1_Port1 );
    ReefAngel.Relay.Set( Box1_Port2, !ReefAngel.Relay.Status( Box1_Port1 ) );
    ReefAngel.PWM.DaylightPWMSlope();
    ReefAngel.PWM.ActinicPWMSlope();
    ReefAngel.Relay.Set(Port8, now()%21600<10800);
Where do i put this:
Code: Select all
    DaylightPWMValue=PWMSlopeHighRes(10,30,22,0,0,85,60,0);
     CheckCloud();
     ReefAngel.PWM.SetChannelRaw(1,DaylightPWMValue);
in place of ReefAngel.PWM.DaylightPWMSlope();
Yes, but change it to ReefAngel.PWM.SetChannelRaw(0,DaylightPWMValue); if your whites are on channel 0.
And should the last part go in here?
Code: Select all
   ////// Place your custom code below here
    [color=#BF0000]XXXXXX[/color]

    ////// Place your custom code above here

    // This should always be the last line
Nope, past that. Put it at the very end, past everything else.

--Colin

So after this?

Code: Select all

// This should always be the last line
    ReefAngel.Portal( "MDB1029" );
    ReefAngel.DDNS( "Reef" ); // Your DDNS is MDB1029-Reef.myreefangel.com
    ReefAngel.ShowInterface();
}

Posted: **Mon Aug 10, 2015 3:04 am**

Posted: **Fri Aug 28, 2015 11:14 am**

So I added this and my blues stopped working.

Code: Select all

    void CheckCloud()
    {
      // ------------------------------------------------------------
      // Change the values below to customize your cloud/storm effect

      // Frequency in days based on the day of the month - number 2 means every 2 days, for example (day 2,4,6 etc)
      // For testing purposes, you can use 1 and cause the cloud to occur everyday
    #define Clouds_Every_X_Days 1

      // Percentage chance of a cloud happening today
      // For testing purposes, you can use 100 and cause the cloud to have 100% chance of happening
    #define Cloud_Chance_per_Day 100

      // Minimum number of minutes for cloud duration.  Don't use max duration of less than 6
    #define Min_Cloud_Duration 7

      // Maximum number of minutes for the cloud duration. Don't use max duration of more than 255
    #define Max_Cloud_Duration 7

      // Minimum number of clouds that can happen per day
    #define Min_Clouds_per_Day 1

      // Maximum number of clouds that can happen per day
    #define Max_Clouds_per_Day 2

      // Only start the cloud effect after this setting
      // In this example, start cloud after noon
    #define Start_Cloud_After NumMins(12,00)

      // Always end the cloud effect before this setting
      // In this example, end cloud before 9:00pm
    #define End_Cloud_Before NumMins(21,00)

      // Percentage chance of a lightning happen for every cloud
      // For testing purposes, you can use 100 and cause the lightning to have 100% chance of happening
    #define Lightning_Change_per_Cloud 100

      // Note: Make sure to choose correct values that will work within your PWMSLope settings.
      // For example, in our case, we could have a max of 5 clouds per day and they could last for 50 minutes.
      // Which could mean 250 minutes of clouds. We need to make sure the PWMSlope can accomodate 250 minutes
      // of effects or unforseen result could happen.
      // Also, make sure that you can fit double those minutes between Start_Cloud_After and End_Cloud_Before.
      // In our example, we have 510 minutes between Start_Cloud_After and End_Cloud_Before, so double the
      // 250 minutes (or 500 minutes) can fit in that 510 minutes window.
      // It's a tight fit, but it did.

      //#define printdebug // Uncomment this for debug print on Serial Monitor window
    #define forcecloudcalculation // Uncomment this to force the cloud calculation to happen in the boot process.

      // Add Random Lightning modes
    #define Calm 0    // No lightning
    #define Slow 1    // 5 seconds of slow lightning in the middle of a cloud for ELN style (slow response) drivers
    #define Fast 2    // 5 seconds of fast lightning in the middle of a cloud for LDD style (fast response) drivers
    #define Mega 3    // Lightning throughout the cloud, higher chance as it gets darker
    #define Mega2 4   // Like Mega, but with more lightning
      // Set which modes you want to use
      // Example:  { Calm, Fast, Mega, Mega2 } to randomize all four modes. 
      // { Mega2 } for just Mega2.  { Mega, Mega, Fast} for Mega and Fast, with twice the chance of Mega.
      byte LightningModes[] = {Mega2,Mega,Mega};

      // Change the values above to customize your cloud/storm effect
      // ------------------------------------------------------------
      // Do not change anything below here

      static byte cloudchance=255;
      static byte cloudduration=0;
      static int cloudstart=0;
      static byte numclouds=0;
      static byte lightningchance=0;
      static byte cloudindex=0;
      static byte lightningstatus=0;
      static int LastNumMins=0;
      static byte lightningMode=0;
      static boolean chooseLightning=true;

      static time_t DelayCounter=millis();    // Variable for lightning timing. 
      static int DelayTime=random(1000);      // Variable for lightning timimg.

      // Every day at midnight, we check for chance of cloud happening today
      if (hour()==0 && minute()==0 && second()==0) cloudchance=255;

    #ifdef forcecloudcalculation
      if (cloudchance==255)
    #else
        if (hour()==0 && minute()==0 && second()==1 && cloudchance==255)
    #endif
        {
          randomSeed(millis());    // Seed the random number generator
          //Pick a random number between 0 and 99
          cloudchance=random(100);
          // if picked number is greater than Cloud_Chance_per_Day, we will not have clouds today
          if (cloudchance>Cloud_Chance_per_Day) cloudchance=0;
          // Check if today is day for clouds.
          if ((day()%Clouds_Every_X_Days)!=0) cloudchance=0;
          // If we have cloud today
          if (cloudchance)
          {
            // pick a random number for number of clouds between Min_Clouds_per_Day and Max_Clouds_per_Day
            numclouds=random(Min_Clouds_per_Day,Max_Clouds_per_Day);
            // pick the time that the first cloud will start
            // the range is calculated between Start_Cloud_After and the even distribuition of clouds on this day.
            cloudstart=random(Start_Cloud_After,Start_Cloud_After+((End_Cloud_Before-Start_Cloud_After)/(numclouds*2)));
            // pick a random number for the cloud duration of first cloud.
            cloudduration=random(Min_Cloud_Duration,Max_Cloud_Duration);
            //Pick a random number between 0 and 99
            lightningchance=random(100);
            // if picked number is greater than Lightning_Change_per_Cloud, we will not have lightning today
            if (lightningchance>Lightning_Change_per_Cloud) lightningchance=0;
          }
        }
      // Now that we have all the parameters for the cloud, let's create the effect


      if (cloudchance)
      {
        //is it time for cloud yet?
        if (NumMins(hour(),minute())>=cloudstart && NumMins(hour(),minute())<(cloudstart+cloudduration))
        {
          DaylightPWMValue=ReversePWMSlope(cloudstart,cloudstart+cloudduration,DaylightPWMValue/40.95,0,180)*40.95;
          if (chooseLightning)
          {
            lightningMode=LightningModes[random(100)%sizeof(LightningModes)];
            chooseLightning=false;
          }
          switch (lightningMode)
          {
          case Calm:
            break;
          case Mega:
            // Lightning chance from beginning of cloud through the end.  Chance increases with darkness of cloud.
            if (lightningchance && random(ReversePWMSlope(cloudstart,cloudstart+cloudduration,100,0,180))<1 && (millis()-DelayCounter)>DelayTime)
            {
              // Send the trigger
              Strike();
              DelayCounter=millis();    // If we just had a round of flashes, then lets put in a longer delay
              DelayTime=random(1000);   // of up to a second for dramatic effect before we do another round.
            }
            break;
          case Mega2:
            // Higher lightning chance from beginning of cloud through the end.  Chance increases with darkness of cloud.
            if (lightningchance && random(ReversePWMSlope(cloudstart,cloudstart+cloudduration,100,0,180))<2)
            {
              Strike();
            }
            break;
          case Fast:
            // 5 seconds of lightning in the middle of the cloud
            if (lightningchance && (NumMins(hour(),minute())==(cloudstart+(cloudduration/2))) && second()<5 && (millis()-DelayCounter)>DelayTime)
            {
              Strike();

              DelayCounter=millis();    // If we just had a round of flashes, then lets put in a longer delay
              DelayTime=random(1000);   // of up to a second for dramatic effect before we do another round.
            }
            break;
          case Slow:
            // Slow lightning for 5 seconds in the middle of the cloud.  Suitable for slower ELN style drivers
            if (lightningchance && (NumMins(hour(),minute())==(cloudstart+(cloudduration/2))) && second()<5)
            {
              if (random(100)<20) lightningstatus=1;
              else lightningstatus=0;
              if (lightningstatus)
              {
                DaylightPWMValue=4095;
              }
              else
              {
                DaylightPWMValue=0;
              }
              delay(1);
            }
            break;
          default:
            break;
          }
        }
        else
        {
          chooseLightning=true; // Reset the flag to choose a new lightning type
        }

        if (NumMins(hour(),minute())>(cloudstart+cloudduration))
        {
          cloudindex++;
          if (cloudindex < numclouds)
          {
            cloudstart=random(Start_Cloud_After+(((End_Cloud_Before-Start_Cloud_After)/(numclouds*2))*cloudindex*2),(Start_Cloud_After+(((End_Cloud_Before-Start_Cloud_After)/(numclouds*2))*cloudindex*2))+((End_Cloud_Before-Start_Cloud_After)/(numclouds*2)));
            // pick a random number for the cloud duration of first cloud.
            cloudduration=random(Min_Cloud_Duration,Max_Cloud_Duration);
            //Pick a random number between 0 and 99
            lightningchance=random(100);
            // if picked number is greater than Lightning_Change_per_Cloud, we will not have lightning today
            if (lightningchance>Lightning_Change_per_Cloud) lightningchance=0;
          }
        }
      }

      // Write the times of the next cloud, next lightning, and cloud duration to the screen and into some customvars for the Portal.
      if (LastNumMins!=NumMins(hour(),minute()))
      {
        LastNumMins=NumMins(hour(),minute());
        /*ReefAngel.LCD.Clear(255,0,120,132,132);
         ReefAngel.LCD.DrawText(0,255,5,120,"C");
         ReefAngel.LCD.DrawText(0,255,11,120,"00:00");
         ReefAngel.LCD.DrawText(0,255,45,120,"L");
         ReefAngel.LCD.DrawText(0,255,51,120,"00:00"); */
        if (cloudchance && (NumMins(hour(),minute())<cloudstart))
        {
          int x=0;
          if ((cloudstart/60)>=10) x=11;
          else x=17;
          //ReefAngel.LCD.DrawText(0,255,x,120,(cloudstart/60));
          ReefAngel.CustomVar[3]=cloudstart/60; // Write the hour of the next cloud to custom variable for Portal reporting
          if ((cloudstart%60)>=10) x=29;
          else x=35;
          //ReefAngel.LCD.DrawText(0,255,x,120,(cloudstart%60));
          ReefAngel.CustomVar[4]=cloudstart%60; // Write the minute of the next cloud to custom variable for Portal reporting

        }
        //ReefAngel.LCD.DrawText(0,255,90,120,cloudduration);
        ReefAngel.CustomVar[7]=(cloudduration);    // Put the duration of the next cloud in a custom var for the portal
        if (lightningchance)
        {
          int x=0;
          if (((cloudstart+(cloudduration/2))/60)>=10) x=51;
          else x=57;
          //ReefAngel.LCD.DrawText(0,255,x,120,((cloudstart+(cloudduration/2))/60));
          ReefAngel.CustomVar[5]=(cloudstart+(cloudduration/2))/60;    // Write the hour of the next lightning to a custom variable for the Portal
          if (((cloudstart+(cloudduration/2))%60)>=10) x=69;
          else x=75;
          //ReefAngel.LCD.DrawText(0,255,x,120,((cloudstart+(cloudduration/2))%60)); // Write the minute of the next lightning to a custom variable for the Portal
            ReefAngel.CustomVar[6]=(cloudstart+(cloudduration/2))%60;
        }
      }   
    }

    void Strike()
    {
      int a=random(1,5);    // Pick a number of consecutive flashes from 1 to 4. 
      for (int i=0; i<a; i++)
      {
        // Flash on
        int newdata=4095;
        Wire.beginTransmission(0x40);      // Address of the dimming expansion module
        Wire.write(0x8+(4*1));             // 0x8 is channel 0, 0x12 is channel 1, etc.  I'm using channel 1.
        Wire.write(newdata&0xff);          // Send the data 8 bits at a time.  This sends the LSB
        Wire.write(newdata>>8);            // This sends the MSB
        Wire.endTransmission();
       
        int randy=random(20,80);    // Random number for a delay
        if (randy>71) randy=((randy-70)/2)*100;    // Small chance of a longer delay
        delay(randy);                // Wait from 20 to 69 ms, or 100-400 ms
       
        // Flash off.  Return to baseline.
        newdata=ReefAngel.PWM.GetChannelValueRaw(1);   // Use the channel number you're flashing here
        Wire.beginTransmission(0x40);    // Same as above
        Wire.write(0x8+(4*1));
        Wire.write(newdata&0xff);
        Wire.write(newdata>>8);
        Wire.endTransmission();
       
        delay(random(30,50));                // Wait from 30 to 49 ms
        wdt_reset();    // Reset watchdog timer to avoid re-boots
      }
    }

    byte ReversePWMSlope(long cstart,long cend,byte PWMStart,byte PWMEnd, byte clength)
    {
      long n=elapsedSecsToday(now());
      cstart*=60;
      cend*=60;
      if (n<cstart) return PWMStart;
      if (n>=cstart && n<=(cstart+clength)) return map(n,cstart,cstart+clength,PWMStart,PWMEnd);
      if (n>(cstart+clength) && n<(cend-clength)) return PWMEnd;
      if (n>=(cend-clength) && n<=cend) return map(n,cend-clength,cend,PWMEnd,PWMStart);
      if (n>cend) return (int) PWMStart;
    }

Any suggestions? Both white and blue were working before adding this code. White channel 0 Blue channel 1. I tried to change to the highres slope for the blue channel as well, Did I not do it correctly? Also can you look at the daylight setting and tell me if i changed it to channel 0 correctly?

Posted: **Fri Aug 28, 2015 11:57 am**

So on the portal it was showing channel 1 at 204% and the voltage being put out at the dimming expansion was 0.35v when the white channel was at 1.6v. I looked at the diodes themselves and they were on just extremely low and couldn't tell without seeing them. I have them set at 30% through the app right now.

On another note, how can i tell if the cloud and lightning is working?

Reef Angel Forum

Cloud and Lightning Code for Dimming Expansion

Re: Cloud and Lightning Code for Dimming Expansion

Re: Cloud and Lightning Code for Dimming Expansion

Re: Cloud and Lightning Code for Dimming Expansion

Re: Cloud and Lightning Code for Dimming Expansion

Re: Cloud and Lightning Code for Dimming Expansion

Re: Cloud and Lightning Code for Dimming Expansion

Re: Cloud and Lightning Code for Dimming Expansion

Re: Cloud and Lightning Code for Dimming Expansion

Re: Cloud and Lightning Code for Dimming Expansion

Re: Cloud and Lightning Code for Dimming Expansion

Re: Cloud and Lightning Code for Dimming Expansion

Re: Cloud and Lightning Code for Dimming Expansion

Re: Cloud and Lightning Code for Dimming Expansion

Re: Cloud and Lightning Code for Dimming Expansion

Re: Cloud and Lightning Code for Dimming Expansion

Re: Cloud and Lightning Code for Dimming Expansion

Re: Cloud and Lightning Code for Dimming Expansion

Re: Cloud and Lightning Code for Dimming Expansion

Re: Cloud and Lightning Code for Dimming Expansion

Re: Cloud and Lightning Code for Dimming Expansion

Re: Cloud and Lightning Code for Dimming Expansion

Re: Cloud and Lightning Code for Dimming Expansion

Re: Cloud and Lightning Code for Dimming Expansion

Re: Cloud and Lightning Code for Dimming Expansion

Re: Cloud and Lightning Code for Dimming Expansion

Re: Cloud and Lightning Code for Dimming Expansion

Re: Cloud and Lightning Code for Dimming Expansion

Re: Cloud and Lightning Code for Dimming Expansion

Re: Cloud and Lightning Code for Dimming Expansion

Re: Cloud and Lightning Code for Dimming Expansion