Reef Angel Forum

Posted: **Mon Apr 02, 2012 11:49 am**

I want my ato to check tank the tank water level every hour and then if the tank is low and there is water in the ATO reservoir to then turn on until the tank is at correct level. I want to have a failsafe timer to turn ato off and lock it out if on for over a certain time. Finally, i want to be able to clear the failsafe from the controller or client suite. I think the code has most of it other than the checking every hour instead of continuously check. Also I am not sure of the line to add to a custom menu to put the relay back to auto.

here is the code i found in another thread that should do most of it

Code: Select all

void setup()
{
  ReefAngel.Init(); 
  ReefAngel.Timer[1].SetInterval(2);
}

void loop()
{
  ReefAngel.ShowInterface();
  if (ReefAngel.HighATO.IsActive() && ReefAngel.LowATO.IsActive())
  {
    ReefAngel.Relay.On(Port1);
    ReefAngel.Timer[1].Start();
  }
  if (!ReefAngel.HighATO.IsActive() && !ReefAngel.LowATO.IsActive())
  {
    ReefAngel.Relay.Off(Port1);
    ReefAngel.Timer[1].ForceTrigger();
  }
  if (bitRead(ReefAngel.Relay.RelayData,Port1-1) && ReefAngel.Timer[1].IsTriggered())
  {
    bitClear(ReefAngel.Relay.RelayMaskOff,Port1-1);
  }
}

Posted: **Mon Apr 02, 2012 1:00 pm**

The singleato function does all that already.

Code: Select all

ReefAngel.SingleATO(bool bLow, byte ATORelay, byte byteTimeout, byte byteHrInterval);

You can use like this:

Code: Select all

ReefAngel.SingleATO(true, Port1, 60, 1);

The above code will use ATO Low as input port, and Port1 as controlling Port with 60 seconds timeout and it will only run once in every 1 hour.

Posted: **Mon Apr 02, 2012 2:18 pm**

would this code placed in loop work correctly? Idea is that it will check to make sure ATO resevoir has water, then run the single low ato code.

Code: Select all

if (ReefAngel.HighATO.IsActive())
  {
	ReefAngel.SingleATO(true, Port1, 60, 1);
  }

Posted: **Mon Apr 02, 2012 2:21 pm**

Yeah!!

Posted: **Mon Apr 16, 2012 3:11 pm**

well i tried this out today and for some reason the ato pump is stuck on the on position. even after 10 sec it never kicked off. the low ato float is even off, but the pump is still on. any ideas?

full code:

Code: Select all

// Autogenerated file by RAGen (v1.2.1.158), (03/28/2012 22:23)
// RA_032812_2223.ino
//
// This version designed for v0.9.0 or later

/* The following features are enabled for this File: 
#define DisplayLEDPWM
#define wifi
#define CUSTOM_MENU
#define CUSTOM_MENU_ENTRIES 9
*/


#include <ReefAngel_Features.h>
#include <Globals.h>
#include <RA_Wifi.h>
#include <Wire.h>
#include <OneWire.h>
#include <Time.h>
#include <DS1307RTC.h>
#include <InternalEEPROM.h>
#include <RA_NokiaLCD.h>
#include <RA_ATO.h>
#include <RA_Joystick.h>
#include <LED.h>
#include <RA_TempSensor.h>
#include <Relay.h>
#include <RA_PWM.h>
#include <Timer.h>
#include <Memory.h>
#include <ReefAngel.h>

byte ActinicPWMValue=0;
byte DaylightPWMValue=0;
boolean ForceCloud=false;
boolean Actinicauto=true;
boolean Daylightauto=true;
boolean Fullactinic=false;

#include <avr/pgmspace.h>
prog_char menu1_label[] PROGMEM = "Force Storm";
prog_char menu2_label[] PROGMEM = "Actinic";
prog_char menu3_label[] PROGMEM = "Daylight";
prog_char menu4_label[] PROGMEM = "Feeding";
prog_char menu5_label[] PROGMEM = "Water Change";
prog_char menu6_label[] PROGMEM = "ATO Clear";
prog_char menu7_label[] PROGMEM = "Overheat Clear";
prog_char menu8_label[] PROGMEM = "pH Calibration";
prog_char menu9_label[] PROGMEM = "Full Actinic";
PROGMEM const char *menu_items[] = {
menu1_label, menu2_label, menu3_label, menu4_label, menu5_label, menu6_label, menu7_label, menu8_label, menu9_label  };

void MenuEntry1()
{
ForceCloud=true;
ReefAngel.DisplayedMenu=RETURN_MAIN_MODE;
}
void MenuEntry2()
{
      if (Actinicauto)
      {
      ActinicPWMValue=0;
      Actinicauto=false;
      }
      else
      {
      ActinicPWMValue+=10;
      if (ActinicPWMValue>100)
         {
          Actinicauto=true;
          ActinicPWMValue=0;
         }
      }
ReefAngel.DisplayedMenu=RETURN_MAIN_MODE;
}

void MenuEntry3()
{
      if (Daylightauto)
      {
      DaylightPWMValue=0;
      Daylightauto=false;
      }
      else
      {
      DaylightPWMValue+=10;
      if (DaylightPWMValue>100)
         {
          Daylightauto=true;
          DaylightPWMValue=0;
         }
      }
ReefAngel.DisplayedMenu=RETURN_MAIN_MODE;
}
void MenuEntry4()
{
ReefAngel.FeedingModeStart();
}
void MenuEntry5()
{
ReefAngel.WaterChangeModeStart();
}
void MenuEntry6()
{
ReefAngel.ATOClear();
ReefAngel.DisplayMenuEntry("Clear ATO Timeout");
}
void MenuEntry7()
{
ReefAngel.OverheatClear();
ReefAngel.DisplayMenuEntry("Clear Overheat");
}
void MenuEntry8()
{
ReefAngel.SetupCalibratePH();
ReefAngel.DisplayedMenu = ALT_SCREEN_MODE;
}
void MenuEntry9()
{
  if (Fullactinic)
    {
       Daylightauto=true;
       Actinicauto=true;
       Fullactinic=false;
    }
  else
    {
      DaylightPWMValue=0;
      Daylightauto=false;
      ActinicPWMValue=100;
      Actinicauto=false;
      Fullactinic=true;
    }
ReefAngel.DisplayedMenu=RETURN_MAIN_MODE;
}
void setup()
{
    ReefAngel.Init();  //Initialize controller
    ReefAngel.InitMenu(pgm_read_word(&(menu_items[0])),SIZE(menu_items));
    ReefAngel.OverheatShutoffPorts = Port7Bit;
    // Ports that are always on
    ReefAngel.Relay.On(Port5);
    ReefAngel.Relay.On(Port6);
    ReefAngel.Relay.On(Port8);    
}

void loop()
{
    // Specific functions
  //  ReefAngel.SingleATOLow(Port1);
    ReefAngel.StandardLights(Port2);
    ReefAngel.MHLights(Port3);
    ReefAngel.StandardLights(Port4);
    ReefAngel.StandardHeater(Port7);

if ((Actinicauto) && (Daylightauto))
  {
// Calculate your regular sunrise/sunset PWM value
    ActinicPWMValue=PWMSlope(10,00,22,15,0,70,120,ActinicPWMValue);
    DaylightPWMValue=PWMSlope(10,00,22,15,0,40,180,DaylightPWMValue);
    CheckCloud();    
  } 
    ReefAngel.PWM.SetActinic(ActinicPWMValue);
    ReefAngel.PWM.SetDaylight(DaylightPWMValue);

    if (ReefAngel.HighATO.IsActive())
      {
       ReefAngel.SingleATO(true, Port1, 10, 1);
      } 
      
  ReefAngel.ShowInterface();  
}


//*********************************************************************************************************************************
// Random Cloud/Thunderstorm effects function
void CheckCloud()
{

  // ------------------------------------------------------------
  // Change the values below to customize your cloud/storm effect

  // Frequency in days based on the day of the month - number 2 means every 2 days, for example (day 2,4,6 etc)
  // For testing purposes, you can use 1 and cause the cloud to occur everyday
#define Clouds_Every_X_Days 3 

  // Percentage chance of a cloud happening today
  // For testing purposes, you can use 100 and cause the cloud to have 100% chance of happening
#define Cloud_Chance_per_Day 50

  // Minimum number of minutes for cloud duration.  Don't use max duration of less than 6
#define Min_Cloud_Duration 7

  // Maximum number of minutes for the cloud duration. Don't use max duration of more than 255
#define Max_Cloud_Duration 15

  // Minimum number of clouds that can happen per day
#define Min_Clouds_per_Day 3

  // Maximum number of clouds that can happen per day
#define Max_Clouds_per_Day 5

  // Only start the cloud effect after this setting
  // In this example, start could after 11:30am
#define Start_Cloud_After NumMins(11,30)

  // Always end the cloud effect before this setting
  // In this example, end could before 8:00pm
#define End_Cloud_Before NumMins(19,30)

  // Percentage chance of a lightning happen for every cloud
  // For testing purposes, you can use 100 and cause the lightning to have 100% chance of happening
#define Lightning_Change_per_Cloud 50

  // Note: Make sure to choose correct values that will work within your PWMSLope settings.
  // For example, in our case, we could have a max of 5 clouds per day and they could last for 50 minutes.
  // Which could mean 250 minutes of clouds. We need to make sure the PWMSlope can accomodate 250 minutes of effects or unforseen resul could happen.
    // Also, make sure that you can fit double those minutes between Start_Cloud_After and End_Cloud_Before.
  // In our example, we have 510 minutes between Start_Cloud_After and End_Cloud_Before, so double the 250 minutes (or 500 minutes) can fit in that 510 minutes window.
    // It's a tight fit, but it did.

    //#define printdebug // Uncomment this for debug print on Serial Monitor window
  #define forcecloudcalculation // Uncomment this to force the cloud calculation to happen in the boot process. 


  // Change the values above to customize your cloud/storm effect
  // ------------------------------------------------------------
  // Do not change anything below here

  static byte cloudchance=255;
  static byte cloudduration=0;
  static int cloudstart=0;
  static byte numclouds=0;
  static byte lightningchance=0;
  static byte cloudindex=0;
  static byte lightningstatus=0;
  static int LastNumMins=0;
  // Every day at midnight, we check for chance of cloud happening today
  if (hour()==0 && minute()==0 && second()==0) cloudchance=255;

#ifdef forcecloudcalculation
    if (cloudchance==255)
#else
    if (hour()==0 && minute()==0 && second()==1 && cloudchance==255) 
#endif
    {
      //Pick a random number between 0 and 99
      cloudchance=random(100); 
      // if picked number is greater than Cloud_Chance_per_Day, we will not have clouds today
      if (cloudchance>Cloud_Chance_per_Day) cloudchance=0;
      // Check if today is day for clouds. 
      if ((day()%Clouds_Every_X_Days)!=0) cloudchance=0; 
      // If we have cloud today
      if (cloudchance)
      {
        // pick a random number for number of clouds between Min_Clouds_per_Day and Max_Clouds_per_Day
        numclouds=random(Min_Clouds_per_Day,Max_Clouds_per_Day);
        // pick the time that the first cloud will start
        // the range is calculated between Start_Cloud_After and the even distribuition of clouds on this day. 
        cloudstart=random(Start_Cloud_After,Start_Cloud_After+((End_Cloud_Before-Start_Cloud_After)/(numclouds*2)));
        // pick a random number for the cloud duration of first cloud.
        cloudduration=random(Min_Cloud_Duration,Max_Cloud_Duration);
        //Pick a random number between 0 and 99
        lightningchance=random(100);
        // if picked number is greater than Lightning_Change_per_Cloud, we will not have lightning today
        if (lightningchance>Lightning_Change_per_Cloud) lightningchance=0;
      }
    }
  // Now that we have all the parameters for the cloud, let's create the effect

    if (ForceCloud)
    {
    ForceCloud=false;
    cloudchance=1;
    cloudduration=10;
    lightningchance=1;
    cloudstart=NumMins(hour(),minute())+1;
    }


  if (cloudchance)
  {
    //is it time for cloud yet?
    if (NumMins(hour(),minute())>=cloudstart && NumMins(hour(),minute())<(cloudstart+cloudduration))
    {
      DaylightPWMValue=ReversePWMSlope(cloudstart,cloudstart+cloudduration,DaylightPWMValue,0,180);
      if (lightningchance && (NumMins(hour(),minute())==(cloudstart+(cloudduration/2))) && second()<5) 
      {
        if (random(100)<20) lightningstatus=1; 
        else lightningstatus=0;
        if (lightningstatus)
        {
          DaylightPWMValue=100; 
        //  ActinicPWMValue=100;
        }
        else 
        {
          DaylightPWMValue=0;
       //   ActinicPWMValue=0;
        }
        delay(1);
      }
    }
    if (NumMins(hour(),minute())>(cloudstart+cloudduration))
    {
      cloudindex++;
      if (cloudindex < numclouds)
      {
        cloudstart=random(Start_Cloud_After+(((End_Cloud_Before-Start_Cloud_After)/(numclouds*2))*cloudindex*2),(Start_Cloud_After+(((End_Cloud_Before-Start_Cloud_After)/(numclouds*2))*cloudindex*2))+((End_Cloud_Before-Start_Cloud_After)/(numclouds*2)));
        // pick a random number for the cloud duration of first cloud.
        cloudduration=random(Min_Cloud_Duration,Max_Cloud_Duration);
        //Pick a random number between 0 and 99
        lightningchance=random(100);
        // if picked number is greater than Lightning_Change_per_Cloud, we will not have lightning today
        if (lightningchance>Lightning_Change_per_Cloud) lightningchance=0;
      }
    }
  }
  
  if (LastNumMins!=NumMins(hour(),minute()))
  {
    LastNumMins=NumMins(hour(),minute());
    ReefAngel.LCD.Clear(255,0,120,132,132);
    ReefAngel.LCD.DrawText(0,255,5,120,"C");
    ReefAngel.LCD.DrawText(0,255,11,120,"00:00");
    ReefAngel.LCD.DrawText(0,255,45,120,"L");
    ReefAngel.LCD.DrawText(0,255,51,120,"00:00");
    if (cloudchance && (NumMins(hour(),minute())<cloudstart))
    {
      int x=0;
      if ((cloudstart/60)>=10) x=11; else x=17;
      ReefAngel.LCD.DrawText(0,255,x,120,(cloudstart/60));
      if ((cloudstart%60)>=10) x=29; else x=35;
      ReefAngel.LCD.DrawText(0,255,x,120,(cloudstart%60));
    }
    ReefAngel.LCD.DrawText(0,255,90,120,cloudduration);
    if (lightningchance) 
    {
      int x=0;
      if (((cloudstart+(cloudduration/2))/60)>=10) x=51; else x=57;
      ReefAngel.LCD.DrawText(0,255,x,120,((cloudstart+(cloudduration/2))/60));
      if (((cloudstart+(cloudduration/2))%60)>=10) x=69; else x=75;
      ReefAngel.LCD.DrawText(0,255,x,120,((cloudstart+(cloudduration/2))%60));
    }
  }   
}

byte ReversePWMSlope(long cstart,long cend,byte PWMStart,byte PWMEnd, byte clength)
{
  long n=elapsedSecsToday(now());
  cstart*=60;
  cend*=60;
  if (n<cstart) return PWMStart;
  if (n>=cstart && n<=(cstart+clength)) return map(n,cstart,cstart+clength,PWMStart,PWMEnd);
  if (n>(cstart+clength) && n<(cend-clength)) return PWMEnd;
  if (n>=(cend-clength) && n<=cend) return map(n,cend-clength,cend,PWMEnd,PWMStart);
  if (n>cend) return PWMStart;
}

Posted: **Mon Apr 16, 2012 3:42 pm**

I think the if statement is causing the issue.
Try this instead:

Code: Select all

    ReefAngel.SingleATO(true, Port1, 10, 1);
    if (!ReefAngel.HighATO.IsActive()) ReefAngel.Relay.Off(Port1);

Reef Angel Forum

ato help

ato help

Re: ato help

Re: ato help

Re: ato help

Re: ato help

Re: ato help